Risultati da 1 a 5 di 5

Discussione: diagramma polare



  1. #1
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31

    diagramma polare

    Buongiorno a tutti,
    devo creare un grafico polare (tipo rosa dei venti) e per far ciò mi occorre che i dati vengano tabellati secondo classi di valori. Ho messo il link con il file. (Per precisare: nel foglio 2 ho una tabella con la prima colonna che indica le date di acquisizione di misure mentre tutte le altre colonne (da B a CI) indicano rispettivamente velocità e direzione acquisite a varie quote)


    https://dl.dropboxusercontent.com/u/...%20polare.xlsx



    Ho creato la tabella1 nel foglio5 in cui devo praticamente contare il numero di casi sulla base di più condizioni ovvero:
    1 condizione: conta se ci sono valori nell’intervallo B4:B809 < di un dato valore inserito in una cella (ovvero se vi sono velocità minori o entro un certo intervallo),
    2 condizione: solo se soddisfatta la prima condizione (quindi solo per quelle velocità) allora conta quante velocità per ogni classe di direzione indicata nelle celle.

    Le formule che ho usato sono:

    =CONTA.PIÙ.SE(Foglio2!$B$4:$B$809;"<="&$C$2;Foglio2!$C$4:$C$809;"<"&B4;Foglio2!$C$4:C810;">="&A4)

    Ho impostato la tabella e le formule…ma qualcosa non funziona e soprattutto vorrei trovare un modo veloce per compilare questa tabella dato che devo crearne 1 per ogni profondità. Quella che ho creato è riferita solo alle colonne B e C del foglio 2 (OVVERO SOLO ALLA PROFONDITA -21 metri).

    Nella Tabella 2 del foglio 5 devo applicare la stessa logica solo che in questo caso va applicata considerando solo le colonne del foglio relative alla velocita (colonna B, D, F, H ecc).
    Ho impostato le mie formule:

    =CONTA.PIÙ.SE(Foglio2!B5:B810;"<="& A26;Foglio2!B5:B810;">"&A25)

    Trascinando la formula viene applicata per tutte le colonne del foglio e io dovrei applicarla praticamente a intervalli di colonne alterne.
    Sto impiegando un sacco di tempo per correggere manualmente le formule per ogni colonna …
    conoscete un modo veloce per ottenere ciò che mi serve ?

    grazie!!
    :277:

  2. #2

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4016
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Ciao,
    adesso sto scappando... ho avuto il tempo di controllare solo la prima formula.
    Ci sono i riferimenti (assoluti,relativi,misti) sbagliati.

    Prova a scrivere questa nella cella C3 del Foglio5 e dopo copiala in basso e a destra:

    =CONTA.PIÙ.SE(Foglio2!$B$4:$B$809;"<="&C$2;Foglio2!$C$4:$C$809;"<"&$B3;Foglio2!$C$4:$C$809;">="&$A3)

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  3. #3

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4016
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Ciao,
    non so come devi sistemare le altre tabelle (oltre "TABELLA 1") quindi nella cella "K1" ho scritto -21 (la profondità).
    Cambiando valore in K1 avrai i risultati per quella profondità.

    La formula da mettere in C3 (per la TABELLA 1):

    =CONTA.PIÙ.SE(INDIRETTO("Foglio2!"&INDIRIZZO(4;CONFRONTA($K$1;Foglio2!$2:$2;0)-1)&":"&INDIRIZZO(809;CONFRONTA($K$1;Foglio2!$2:$2;0)-1));"<="&C$2;INDIRETTO("Foglio2!"&INDIRIZZO(4;CONFRONTA($K$1;Foglio2!$2:$2;0))&":"&INDIRIZZO(809;CONFRONTA($K$1;Foglio2!$2:$2;0)));"<"&$B3;INDIRETTO("Foglio2!"&INDIRIZZO(4;CONFRONTA($K$1;Foglio2!$2:$2;0))&":"&INDIRIZZO(809;CONFRONTA($K$1;Foglio2!$2:$2;0)));">="&$A3)

    Da copiare in basso e a destra.

    Per la seconda tabella.... nella cella B25 scrivi:

    =CONTA.SE(INDIRETTO("Foglio2!"&INDIRIZZO(4;CONFRONTA(B$24;Foglio2!$2:$2;0)-1)&":"&INDIRIZZO(809;CONFRONTA(B$24;Foglio2!$2:$2;0)-1));"<="&$A25)

    e copia in basso e a destra.

    Ti lascio il file in allegato... fai delle verifiche.
    http://dropcanvas.com/u0p85

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  4. I seguenti 2 utenti hanno dato un "Like" a cromagno per questo post:


  5. #4
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31
    grazie!!
    a prima vista credo vada bene, comunque faccio delle verifiche
    :999:

  6. #5
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Ciao a tutti
    Prima di tutto e un grande complimento a Cromagno che usa le funzioni INDIRIZZO e INDIRETTO in maniera egregia, come al solito ci sono tante soluzioni diverse quando ci si vuol fare restituire un intervallo dinamico, io ho trovato una soluzione più elementare e forse più comprensibile per Loretta che saluto e ringrazio per la domanda che ha fatto
    infatti queste sono le mie soluzioni:

    Nella TABELLA1 del foglio5 nella cella in C3 incolla questa formula e trascinala a destra ed in basso

    =CONTA.PIÙ.SE(INDICE(Foglio2!$A$4:$CI$809;;CONFRONTA($K$1;Foglio2!$A$2:$CI$2;0)-1);"<="&C$2;INDICE(Foglio2!$A$4:$CI$809;;CONFRONTA($K$1;Foglio2!$A$2:$CI$2;0));"<"&$B3;INDICE(Foglio2!$A$4:$CI$809;;CONFRONTA($K$1;Foglio2!$A$2:$CI$2;0));">="&$A3)


    Nella tabella2 del Foglio5 nella cella B25 incolla questa formula e trascinala a destra ed in basso
    =CONTA.SE(INDICE(Foglio2!$A$4:$CI$809;;CONFRONTA(B$24;Foglio2!$A$2:$CI$2;0)-1);"<="&$A25)

    Vedi allegato

    https://www.dropbox.com/s/wixg5s36f8n45xt/diagramma%20polare%20Gerardo.xlsx?dl=0

    PS sono sicuro che ci sono altre soluzione e avanti la prossima!!!
    Ciao a tutti ed un cordiale saluti a tutti gli amici del forum

  7. I seguenti utenti hanno dato un "Like"


Discussioni Simili

  1. Diagramma di Gantt su un'unica riga
    Di Matt90 nel forum Domande su Excel in generale
    Risposte: 12
    Ultimo Messaggio: 19/09/17, 13:37
  2. Diagramma di Gantt con ciclo economico
    Di Isa81 nel forum Domande sui Grafici di Excel
    Risposte: 8
    Ultimo Messaggio: 26/10/16, 17:09
  3. Diagramma Gantt con allungamento per weekend
    Di CaesarIII nel forum Domande sui Grafici di Excel
    Risposte: 5
    Ultimo Messaggio: 18/07/16, 11:15
  4. Diagramma di Gannt con errore #VALORE
    Di ieda72 nel forum Domande sui Grafici di Excel
    Risposte: 5
    Ultimo Messaggio: 06/06/16, 16:52
  5. Diagramma di Gannt con errore #VALORE
    Di ieda72 nel forum Domande su Excel in generale
    Risposte: 5
    Ultimo Messaggio: 06/06/16, 16:52

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •