Risultati da 1 a 14 di 14

Discussione: Lista unica dinamica con criteri



  1. #1
    L'avatar di Maxy
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Friuli Venezia Giulia
    Età
    44
    Messaggi
    39
    Versione Office
    2007
    Likes ricevuti
    2
    Likes dati
    7

    Lista unica dinamica con criteri

    Ciao a tutti, ho ancora bisogno del vostro aiuto.

    Dunque, io ho un elenco variabile di persone, che ogni mese lavora in una zona e vende una certa quantità di merce. Tutti questi dati li ho raccolti in una tabella.

    Io vorrei, in un altra tabella, visualizzare i venditori raggruppandoli per un determinato mese e per una determinata zona. Credo di aver bisogno di una formula che mi crei una lista unica dinamica. Ho tentato di usare adattando una formula creata e pubblicata da Gerardo (che saluto) in un video di Excel in pillole ma senza risultati. A seguito la formula e in allegato un file di esempio.

    Grazie tutti.

    =SE(RIGHE(K$13:K13)>$N$3;"";INDICE($A$3:$A$100;PICCOLO(SE(FREQUENZA(SE($A$3:$A$100<>"";CONFRONTA($A$3:$A$100;$A$3:$A$100;0));RIF.RIGA($A$3:$A$100)-RIF.RIGA($A$3)+1);RIF.RIGA($A$3:$A$100)-RIF.RIGA($A$3)+1);RIGHE(K$13:K13))))

  2. #2
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1665
    Versione Office
    2010 PC
    Likes ricevuti
    892
    Likes dati
    184
    ciao
    in K3:
    =SE.ERRORE(INDICE(A$3:A$22;CONFRONTA(0;INDICE(CONTA.SE($K$2:$K2;$A$3:$A$22)+($B$3:$B$22<>$I$2)+($C$3:$C$22<>$I$3););0));"")
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  3. I seguenti 2 utenti hanno dato un "Like" a ninai per questo post:


  4. #3
    L'avatar di Maxy
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Friuli Venezia Giulia
    Età
    44
    Messaggi
    39
    Versione Office
    2007
    Likes ricevuti
    2
    Likes dati
    7
    Grazie ninai, appena mi è possibile provarla ti faccio sapere. Grazie mille intanto per la tua attenzione. Ciao

  5. #4

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Ciao a tutti,
    visto che comunque i nomi non si ripetono....un'alternativa (matriciale, quindi da confermare con CTRL+MAIUSC+INVIO)....

    Cella K3:

    =SE.ERRORE(INDICE($A$3:$A$22;PICCOLO(SE((($C$3:$C$22=$I$3)*($B$3:$B$22=$I$2))>0;(RIF.RIGA($A$3:$A$22)-2);"");RIF.RIGA(A1)));"")

    cella L3:

    =SE(K3="";"";SOMMA.PIÙ.SE($D$3:$D$22;$A$3:$A$22;K3;$B$3:$B$22;$I$2;$C$3:$C$22;$I$3))

    da copiare entrambe le celle verso il basso.

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  6. I seguenti 2 utenti hanno dato un "Like" a cromagno per questo post:


  7. #5
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1665
    Versione Office
    2010 PC
    Likes ricevuti
    892
    Likes dati
    184
    Citazione Originariamente Scritto da cromagno Visualizza Messaggio
    visto che comunque i nomi non si ripetono...
    ciao cromagno,
    Hai ragione!!
    non ci avevo fatto caso che i nomi, con i criteri assegnati, erano univoci. Mi sono fatto influenzare dal titolo e dalla spiegazione che parlava di "lista unica", intendendola per univoca.

    scusa cromagno se mi permetto ma per deformazione da "abbreviatore", tolgo qualche carattere alla tua:
    =SE.ERRORE(INDICE($A$3:$A$22;PICCOLO(SE(($C$3:$C$22=$I$3)*($B$3:$B$22=$I$2);RIF.RIGA($A$3:$A$22)-2);RIF.RIGA(A1)));"")
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  8. #6

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Citazione Originariamente Scritto da ninai Visualizza Messaggio
    ciao cromagno,
    Hai ragione!!
    non ci avevo fatto caso che i nomi, con i criteri assegnati, erano univoci. Mi sono fatto influenzare dal titolo e dalla spiegazione che parlava di "lista unica", intendendola per univoca.
    Ciao ninai,
    potrebbe anche essere solo una coincidenza e che nel file originale ci siano svariati nomi ripetuti... quindi propendo per la tua formula :246:

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  9. #7
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Ciao a tutti,
    Scusate la mia assenza ma il lavoro ha sempre la precedenza
    Quando si tratta di liste uniche/univoche con criteri e analisi dei dati io non posso mancare, (anche se mi inchino ai nomi eccellenti che sono in questa discussione), comunque visto che Maxy è più familiare alla formula con il FREQUENZA (Video EP 64) io ho trovato la mia soluzione molto simile a quanto visto nel video a cui fa riferimento MAXY
    Maxy nella formula vedrai la parte in rosso che ho modificato rispetto alla tua formula.

    in K3 formula matriciale da confermare con i tasti CTRL+SHIFT+ENTER


    =SE(RIGHE($K$3:K3)>$N$3;"";INDICE($A$3:$A$22;PICCOLO(SE(FREQUENZA(SE($A$3:$A$22<>"";SE($B$3:$B$22=$I$2;SE($C$3:$C$22=$I$3;CONFRONTA($A$3:$A$22;$A$3:$A$22;0))));RIF.RIGA($A$3:$A$22)-RIF.RIGA($A$3)+1);RIF.RIGA($A$3:$A$22)-RIF.RIGA($A$3)+1);RIGHE($K$3:K3))))


    Anche in L3 ho fatto una forula per analizzare dati con più criteri

    =SOMMA.PIÙ.SE($D$3:$D$22;$B$3:$B$22;$I$2;$C$3:$C$22;$I$3;$A$3:$A$22;K3)

    A
    B
    C
    D
    E
    F
    G
    H
    I
    J
    K
    L
    M
    N
    2
    Nome Mese Zona Vendite Mese di riferimento Novembre Nome Vendite Conta unici
    3
    Mario ottobre A
    15
    Zona di riferimento C Vittorio
    26
    2
    4
    Osvaldo ottobre B
    49
    Aldo
    9
    5
    Claudio ottobre C
    5
    0
    6
    Vittorio ottobre A
    83
    0
    7
    Aldo ottobre A
    6
    0
    8
    Giovanni ottobre C
    48
    0
    9
    Giacomo ottobre C
    2
    10
    Antonio novembre B
    5
    11
    Osvaldo novembre A
    6
    12
    Claudio novembre A
    48
    13
    Vittorio novembre C
    26
    14
    Aldo novembre C
    9
    15
    Giovanni novembre B
    6
    16
    Giacomo novembre B
    55
    17
    Osvaldo dicembre A
    22
    18
    Claudio dicembre A
    9
    19
    Vittorio dicembre C
    3
    20
    Aldo dicembre B
    30
    21
    Giovanni dicembre B
    57
    22
    Giacomo dicembre A
    82


    Ciao a tutti

  10. I seguenti utenti hanno dato un "Like"


  11. #8
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1075
    Versione Office
    2010 su Win
    Likes ricevuti
    598
    Likes dati
    202
    Ciao a tutti,

    condivido un'alternativa valida solo nel caso in cui i nomi associati ai mesi ed alle zone siano univoci.

    Sto mettendo alla prova in questi giorni l'accoppiata SUBTOTALE(...SCARTO

    Per Excel 2007

    =SE.ERRORE(INDICE($A$3:$A$22;PICCOLO(SE(INDICE(SUBTOTALE(3;SCARTO($B$3;;;RIF.RIGA($3:$22)-1))*($B$3:$B$22=$I$2)*($C$3:$C$22=$I$3);)<>0;RIF.RIGA($3:$22)-2);RIGHE($A$1:$A1)));"")

    in forma matriciale.

    Per Excel 2010 si può abbandonare la forma matriciale usando AGGREGA.

    =SE.ERRORE(INDICE($A$3:$A$22;AGGREGA(15;6;RIF.RIGA($3:$22)-2/(INDICE(SUBTOTALE(3;SCARTO($B$3;;;RIF.RIGA($3:$22)-1))*($B$3:$B$22=$I$2)*($C$3:$C$22=$I$3);)<>0);RIGHE($A$1:$A1)));"")


    Non so se siano soluzioni efficienti.

    Leggo spesso in rete di non abusare delle funzioni volatili (SCARTO ed INDIRETTO su tutte), quando non necessarie.

    Un saluto agli amici del Forum.

  12. I seguenti 2 utenti hanno dato un "Like" a Canapone per questo post:


  13. #9
    L'avatar di mb63
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Torino
    Età
    54
    Messaggi
    484
    Versione Office
    2007/10/13 w10
    Likes ricevuti
    18
    Likes dati
    94
    forse ho interpretato male io la richiesta, ma non si può utilizzare una tabella pivot

    http://www.filedropper.com/listaunic...concriterimb63

    :260:

  14. #10
    L'avatar di Maxy
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Friuli Venezia Giulia
    Età
    44
    Messaggi
    39
    Versione Office
    2007
    Likes ricevuti
    2
    Likes dati
    7
    Grazie a tutti per la vostra attenzione. Siete davvero STREPITOSI.

    Ho provato tutte le formule proposte. Quelle che non riportano mai dei errori e si adattano perfettamente alle mie esigenze sono quelle in #5 e #7. C'è solo una curiosità, quella di ninai a volte inverte i dati. Tipo se nella colonna di riferimento l'ordine dei nomi è Aldo-Giovanni-Giacomo, l'ordine creato dalla formula è Aldo-Giacomo-Giovanni. Comunque il risultato è ottimo in entrambe.

    Ho visto che avete corretto anche la formula nella colonna L. In effetti la funzione CERCA.VER (buttata la senza pensarci) non può funzionare, in quanto si fermerebbe sempre e comunque al primo riferimento trovato e mi restituirebbe sempre lo stesso valore... attentissimi a tutto.

    Se posso chiedere:

    @gerardo
    Io alla tua formula avevo provato ad inserire la funzione E. Sotto in rosso la mia prova. Ovviamente la formula non ha funzionato. Questo perché è sbagliata la sintassi o la funzione E non può essere usata in formule matriciali?

    =SE(RIGHE($K$3:K3)>$N$3;"";INDICE($A$3:$A$22;PICCOLO(SE(FREQUENZA(SE(E($A$3:$A$22<>"";$B$3:$B$22=$I$2;$C$3:$C$22=$I$3);CONFRONTA($A$3:$A$22;$A$3:$A$22;0));RIF.RIGA($A$3:$A$22)-RIF.RIGA($A$3)+1);RIF.RIGA($A$3:$A$22)-RIF.RIGA($A$3)+1);RIGHE($K$3:K3))))

    @ninai/cromagno
    nella vostra formula nella funzione SE usate il *, potreste spigarmi come interagisce?

    =SE.ERRORE(INDICE($A$3:$A$22;PICCOLO(SE(($C$3:$C$22=$I$3)*($B$3:$B$22=$I$2);RIF.RIGA($A$3:$A$22)-2);RIF.RIGA(A1)));"")

    Grazie a tutti.

  15. #11
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1075
    Versione Office
    2010 su Win
    Likes ricevuti
    598
    Likes dati
    202
    Ciao,

    ti giro il file con le formule condivise: a me sembrano equivalenti a parte l'ordine con il quale presentano i nomi.

    Fai attenzione ad adattare i riferimenti del conta.se nella formula (#2) di Ninai.

    Non ho messo quella per Excel 2010


    L'asterisco * serve a concatenare le due due condizioni che filtrano i risultati da far leggere a PICCOLO. Equivale a E(prima condizione;seconda condizione)


    Saluti

  16. #12
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Ciao Maxy tu mi scrivi:
    @Gerardo
    Io alla tua formula avevo provato ad inserire la funzione E. Sotto in rosso la mia prova. Ovviamente la formula non ha funzionato. Questo perché è sbagliata la sintassi o la funzione E non può essere usata in formule matriciali?
    Maxy mi fa piacere che la formula che ho fatto non ti dà errori, tuttavia nella tu domanda c'è già la risposta, nel senso che la funzione E in una matrice ti restituisce un solo VERO o un solo FALSO mentre qui ne hai bisogno uno per ogni riga.
    Un'altro approccio alla mia formula potrebbe essere la formula che vedi qui sotto , che usa la moltiplicazione in sostituzione dell' operatore logico E (AND Criteria)
    ed in parte questa soluzione risponde alla domanda che hai fatto a cromagno/ninai


    =SE(RIGHE($K$3:K3)>$N$3;"";INDICE($A$3:$A$22;PICCOLO(SE(FREQUENZA(SE(($A$3:$A$22<>"")*($B$3:$B$22=$I$2)*($C$3:$C$22=$I$3);CONFRONTA($A$3:$A$22;$A$3:$A$22;0));RIF.RIGA($A$3:$A$22)-RIF.RIGA($A$3)+1);RIF.RIGA($A$3:$A$22)-RIF.RIGA($A$3)+1);RIGHE($K$3:K3))))

    A disposizione
    Ciao

  17. #13
    L'avatar di Maxy
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Friuli Venezia Giulia
    Età
    44
    Messaggi
    39
    Versione Office
    2007
    Likes ricevuti
    2
    Likes dati
    7
    Citazione Originariamente Scritto da Canapone Visualizza Messaggio
    Ciao,

    ti giro il file con le formule condivise: a me sembrano equivalenti a parte l'ordine con il quale presentano i nomi.

    Saluti
    Si hai ragione, tutte le formule funzionano perfettamente. Anche l'ordine è identico. Grazie per avermelo fatto notare. Probabilmente avendo la tabella originale di 500 righe ed essendo sfalsata dalla tabella di prova che vi ho allegato, non sono stato attento ai riferimenti. Scusatemi. Un complimenti a tutti quindi!:255:


    Grazie anche per la spiegazione del *. Deduco che la funzione E all'interno di una matrice non funzioni ma si può in alternativa usare *.

    Ciao

  18. #14
    L'avatar di Maxy
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Friuli Venezia Giulia
    Età
    44
    Messaggi
    39
    Versione Office
    2007
    Likes ricevuti
    2
    Likes dati
    7
    Grazia anche a te Gerardo della precisazione, ho letto la tua spiegazione solo ora. L'avevo intuito dalla risposta di Canapone.

    Un grazie a tutti.

Discussioni Simili

  1. [Risolto] problema con lista unica dinamica
    Di federicocasa nel forum Domande su Excel in generale
    Risposte: 16
    Ultimo Messaggio: Ieri, 20:09
  2. Lista Unica Dinamica da piu fogli
    Di robynud nel forum Domande su Excel in generale
    Risposte: 23
    Ultimo Messaggio: 04/03/16, 19:59
  3. Creare una lista unica con dati su piu colonne (celle vuote)
    Di Gerardo Zuccalà nel forum Domande su Excel in generale
    Risposte: 12
    Ultimo Messaggio: 13/10/15, 12:47
  4. Lista univoca dinamica
    Di Toketta nel forum Domande su Excel in generale
    Risposte: 17
    Ultimo Messaggio: 04/09/15, 18:42
  5. Lista unica incrociata
    Di Gerardo Zuccalà nel forum Domande su Excel in generale
    Risposte: 11
    Ultimo Messaggio: 07/08/15, 18:36

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •