Risultati da 1 a 25 di 25

Discussione: Conteggio articolo in spazio di tempo



  1. #1
    L'avatar di Maxy
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Friuli Venezia Giulia
    Età
    44
    Messaggi
    39
    Versione Office
    2007
    Likes ricevuti
    2
    Likes dati
    7

    Conteggio articolo in spazio di tempo

    Ciao a tutti

    Seguo sempre con attenzione il forum, e ogni volta mi sorprendo come riuscite a trovare la soluzione. Siete forti.

    In ogni caso eccomi a proporvi il mio problema:
    Nella colonna B ho una sequenza di articoli alternata da una data di uscita. Quindi nella riga 2 articolo, riga 3 data della sua uscita; riga 4 articolo, riga 5 la sua data di uscita; ecc.

    Nella cella cella H6 vorrei mettere un numero di mesi, diciamo 6. Nella cella F6 avrei bisogno di una formula che mi cercasse nei 6 mesi (H6) precedenti ad oggi, quale articolo è uscito più spesso. Nella cella G3 un'altra che mi indicasse quanti di questi articoli è uscito.

    Grazie a tutti

  2. #2
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Ciao Maxy bentornato in forumexcel.it
    Se per te non è un problema io metterei l'intervallo di refiremneto come se fosse un data-base con campi e records che tra l'altro è il miglior modo perr sfruttare le funzioni convenzionale di excel.
    Ovviamnte con excel niente è impossibile ma se si può scegliere la strada più semplice io lo consiglio

    la mia idea:
    Fammi sapere!


    B
    C
    1
    Prodotto data
    2
    Televisione
    18/10/2014
    3
    Radio
    25/12/2014
    4
    Forno
    01/02/2015
    5
    Frigo
    02/02/2015
    6
    Televisione
    15/05/2015
    7
    Forno
    18/05/2015
    8
    Televisione
    25/06/2015
    9
    Frigo
    11/08/2015
    10
    Televisione
    30/09/2015
    11
    Radio
    30/10/2015
    12
    Televisione
    15/11/2015

  3. #3
    L'avatar di Maxy
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Friuli Venezia Giulia
    Età
    44
    Messaggi
    39
    Versione Office
    2007
    Likes ricevuti
    2
    Likes dati
    7
    Grazie Gerardo, purtroppo no, non mi è possibile cambiare l'impostazione della tabella. Immaginavo ci fossero delle complicazioni.

  4. #4
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1664
    Versione Office
    2010 PC
    Likes ricevuti
    892
    Likes dati
    184
    ciao
    con questa struttura di dati è un po ostico, qualcosa ho fatto ma è troppo delicata e da migliorare e verificare :
    in F3:
    =INDICE(B2:B23;MODA(SE(B3:B24>DATA(ANNO(ADESSO());MESE(ADESSO())-$H$3;GIORNO(ADESSO()));CONFRONTA(B2:B23;B2:B23;0))))
    matriciale, confermare con CTRL+MAIUSCOLO+INVIO
    in G3:
    =MATR.SOMMA.PRODOTTO((B2:B23=D13)*(B3:B24>DATA(ANNO(ADESSO());MESE(ADESSO())-$H$3;GIORNO(ADESSO()))))

    vi deve essere almeno un articolo presente 2 volte.
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  5. #5
    L'avatar di GiuseppeMN
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Mantova
    Messaggi
    864
    Versione Office
    2000 - 2013
    Likes ricevuti
    285
    Likes dati
    160
    Buona sera, Maxy;
    nel caso in cui il numero degli Articoli sia una quantità ragionevole, si potrebbe provare con VBA.



    A disposizione.

    Buona serata.

    Giuseppe

    Edit: Leggo solo ora la Proposta di @ ninai (che saluto); mi scuso per la sovrapposizione.
    Windows XP Excel 2000 - Windows 10 Excel 2013

  6. #6
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Ciao a tutti
    Sono qui che ci provo da 2 ore poi faccio un refresh... e chi mi trovo??? Ninai con la sua risposta.. incredibile!!
    Fortunatamente con excel non c'è mai una sola soluzione...

    in F3:da confermare con i tasti CTRL+SHIFT+ENTER

    =INDICE(B2:B25;MODA(SE(B2:B25<>"";CONFRONTA(B2:B25;B2:B25;0))))

    in G3:
    =MATR.SOMMA.PRODOTTO((B3:B23>OGGI()-(30*H3))*(B2:B22=F3))

    Ciao ninai sei un grande!!

    Maxy facci sapere!


  7. #7
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Citazione Originariamente Scritto da GiuseppeMN Visualizza Messaggio
    Buona sera, Maxy;
    nel caso in cui il numero degli Articoli sia una quantità ragionevole, si potrebbe provare con VBA.



    A disposizione.

    Buona serata.

    Giuseppe

    Edit: Leggo solo ora la Proposta di @ ninai (che saluto); mi scuso per la sovrapposizione.
    Ciao Giuseppe
    Sono proprio curioso di vedere una soluzione con il VBA
    Ciao a tutti

  8. #8
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1664
    Versione Office
    2010 PC
    Likes ricevuti
    892
    Likes dati
    184
    Gerardo, potrei sbagliare ma ho la sensazione che le tue diano qualche problema:
    la prima, considera i nomi anche al di fuori dalle date ammesse dal criterio dei mesi antecedenti.
    l'altra , effettua il conteggio anticipando 30 giorni non considando corretamente i mesi di 31 e/o 28 giorni

    Un saluto affettuoso a Giuseppe, che non leggevo da un pezzo
    il VBA , credo sia più indicato in questi casi.
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  9. #9
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    @Ninai
    Sta volta ho trovato un baco nella tua formula hahahah:274:
    infatti la tua formula in F3 fallisce quando c'è qualche cella vuota, ovviamnete rimane inteso che a maxy potrebbe non interessare che ci siano delle celle vuote

    =INDICE(B2:B23;MODA(SE(B3:B24>DATA(ANNO(ADESSO());MESE(ADESSO())-$H$3;GIORNO(ADESSO()));CONFRONTA(B2:B23;B2:B23;0)))

  10. #10
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Citazione Originariamente Scritto da ninai Visualizza Messaggio
    Gerardo, potrei sbagliare ma ho la sensazione che le tue diano qualche problema:
    la prima, considera i nomi anche al di fuori dalle date ammesse dal criterio dei mesi antecedenti.
    l'altra , effettua il conteggio anticipando 30 giorni non considando corretamente i mesi di 31 e/o 28 giorni
    Certo ho fatto un calcolo veloce, calcolando che ogni mese è più o meno 30 giorni moltiplicato per 6 =180 giorni
    ma adesso rubo quel pezzettino di formula che che hai fatto tu con la funzione DATA
    Ovviamente cercherò di inserirlo nella mia formula

    EDIT
    Eccola

    =MATR.SOMMA.PRODOTTO((B3:B23>DATA(ANNO(ADESSO());MESE(ADESSO())-$H$3;GIORNO(ADESSO())))*(B2:B22=F3))

  11. #11
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1664
    Versione Office
    2010 PC
    Likes ricevuti
    892
    Likes dati
    184
    Citazione Originariamente Scritto da Gerardo Zuccalà Visualizza Messaggio
    @Ninai
    sta volta ho trovato un baco nella tua formula hahahah:274:
    Bene, spera che sia "da seta" :188:

    non dovrebbero esserci articoli senza una data, comunque credo basti aggiungere la tua condizione, B2:B23<>"", alla mia formula :
    =INDICE(B2:B23;MODA(SE(B3:B24>DATA(ANNO(ADESSO());MESE(ADESSO())-$H$3;GIORNO(ADESSO()));SE(B2:B23<>"";CONFRONTA(B2:B23;B2:B23;0)))))
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  12. I seguenti utenti hanno dato un "Like"


  13. #12
    L'avatar di Maxy
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Friuli Venezia Giulia
    Età
    44
    Messaggi
    39
    Versione Office
    2007
    Likes ricevuti
    2
    Likes dati
    7
    Grazie mille a tutti. Non avevo dubbi che ci sareste riusciti anche questa volta.

    @ninai
    La tua formula in #11 è perfetta. Sei un grande, quasi al primo colpo. Corretta l'aggiunta della condizione testo vuoto, visto che accade. Ma come tu stesso hai scritto non c'è un articolo senza data di uscita, ottima intuizione. Un solo particolare, ho notato che nella rara possibilità che due articoli siano usciti le stesse volte me ne riporta solo uno (ovviamente). Ti chiedo: quello riportato è perchè è in ordine alfabetico, o è il primo che trova dall'elenco? Nel caso, se in F4 rimetto la tua formula posso visualizzare anche il secondo articolo? (Chiaramente aggiungendo altre condizioni).

    @Gerardo
    Con la tua formula in #6 non riesco a far tenere conto dei mesi da considerare. Non so se manca qualcosa o sono io che non riesco ad adattarla.

    @Giuseppe
    Grazie anche della tua alternativa. Fin dove è possibile preferisco le formule al VBA.

    Ancora grazie a tutti.

  14. #13
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    @Maxy
    l'importante che hai risolto
    Tu scrivi:
    Con la tua formula in #6 non riesco a far tenere conto dei mesi da considerare. Non so se manca qualcosa o sono io che non riesco ad adattarla.
    Effettivamente come hai detto tu mancava una condizione nella mia formula, ma questo perchè avevo capito male la domanda credevo che tu volessi sapere (nella prima formula) qual'è l'apparecchio più venduto in generale e poi nella seconda formula quanti pezzi sono stati venduti prima di sei mesi alla data di oggi dell'apparecchio più venduto.
    Sorry!

    Infatti in F3 mancava quel pezzo in rosso che era la condizione che io non pensavo servisse in prima battuta

    =INDICE(B2:B25;MODA(SE(B2:B25<>"";SE(B3:B24>DATA(ANNO(OGGI());MESE(OGGI())-$H$3;GIORNO(OGGI()));CONFRONTA(B2:B25;B2:B25;0)))))

    in fatti in G3 noterai che è perfetta
    =MATR.SOMMA.PRODOTTO((B3:B23>DATA(ANNO(ADESSO());MESE(ADESSO())-$H$3;GIORNO(ADESSO())))*(B2:B22=F3))

    Ciao Maxy
    alla prossima

  15. #14
    L'avatar di Maxy
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Friuli Venezia Giulia
    Età
    44
    Messaggi
    39
    Versione Office
    2007
    Likes ricevuti
    2
    Likes dati
    7
    Grazie Gerardo, in effetti ora funziona perfettamente anche la tua. L'unica cosa che ho notato è che (come nella formula di ninai) se metto come ricerca un mese solo e in quel mese gli articoli sono usciti una volta sola mi da #N/D. è un caso estremo ma mi da fastidio vedere l'errore. Stavo cercando di capire come mai non mi dia un risultato, come nel caso mettendo più mesi e avendo due articoli usciti le stesse volte comunque mi mette qualcosa. Certo posso toglierlo con SE.ERRORE ma prima volevo capire il perché.

    La formula in G3, non ho detto niente, ma è perfetta. Grazie

    Ciao a tutti

  16. #15
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126

    Questa formula è un pò troppo volatile, ci ho messo una piccola toppa (vedi la parte in rosso) potrebbe andarti bene??
    Incolla questa formula in F3 e fammi sapere! ciao

    =INDICE(B2:B25;MODA(SE(B2:B25<>"";SE(B3:B24>DATA(ANNO(OGGI());MESE(OGGI())-$H$3-
    0,000001;GIORNO(OGGI()));SE(B2:B25>0;CONFRONTA(B2:B25;B2:B25;0))))))

  17. #16
    L'avatar di Maxy
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Friuli Venezia Giulia
    Età
    44
    Messaggi
    39
    Versione Office
    2007
    Likes ricevuti
    2
    Likes dati
    7
    Non vedo nessuna differenza. Cioè funziona correttamente come l'altra ad eccezione della condizione precedentemente descritta.

    Credo comunque che il problema comunque sia legato alla funzione MODA che quando non trova nessun valore che si ripete da errore. Quando invece ci sono due valori che si ripetono le stesse volte restituisce il primo.
    Ultima modifica fatta da:Canapone; 08/05/17 alle 21:18

  18. #17
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Citazione Originariamente Scritto da Maxy Visualizza Messaggio
    Non vedo nessuna differenza. Cioè funziona correttamente come l'altra ad eccezione della condizione precedentemente descritta.

    Credo comunque che il problema comunque sia legato alla funzione MODA che quando non trova nessun valore che si ripete da errore. Quando invece ci sono due valori che si ripetono le stesse volte restituisce il primo.
    Si si Ok Max
    ma quest'ultma modifica che ho fatto serviva per risolvere il problema che hai chiesto nel post #14 che non volevi visualizzare #N/D quando il mese scelto è 1
    Tutto qui!

  19. #18
    L'avatar di Maxy
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Friuli Venezia Giulia
    Età
    44
    Messaggi
    39
    Versione Office
    2007
    Likes ricevuti
    2
    Likes dati
    7
    In ogni caso non è un grosso problema.

    Invece, se ho due articoli che hanno lo stesso numero di uscite, posso nella cella F5 rimettere la formula aggiungendo la parte rossa?

    =INDICE(B2:B25;MODA(SE((B2:B25<>"")*(B2:B25<>F3);SE(B3:B24>DATA(ANNO(OGGI());MESE(OGGI())-$H$3-0,000001;GIORNO(OGGI()));SE(B2:B25>0;CONFRONTA(B2:B25;B2:B25;0))))))

    EDIT:Si funziona ora l'ho provata.


    Grazie mille a tutti.

  20. #19
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1664
    Versione Office
    2010 PC
    Likes ricevuti
    892
    Likes dati
    184
    e se i parimeriti sono più di due ??

    per qualunque numero di articoli con la massima frequenza del periodo, in F3:
    =SE.ERRORE(INDICE($B$2:$B$25;MODA(SE(($B$2:$B$25<>"")*(CONTA.SE($F$2:F2;$B$2:$B$25)=0);SE($B$3:$B$24>DATA(ANNO(OGGI());MESE(OGGI())-$H$3-0,000001;GIORNO(OGGI()));SE($B$2:$B$25>0;CONFRONTA($B$2:$B$25;$B$2:$B$25;0))))));"")

    matriciale e trascini in basso
    Ultima modifica fatta da:ninai; 19/12/15 alle 09:09
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  21. #20
    L'avatar di Maxy
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Friuli Venezia Giulia
    Età
    44
    Messaggi
    39
    Versione Office
    2007
    Likes ricevuti
    2
    Likes dati
    7
    Grazie mille a tutti le vostre formule funzionano tutte perfettamente. Grazie.
    :97:

    Un saluto a tutti gli amici del forum
    :999:

  22. #21
    L'avatar di GiuseppeMN
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Mantova
    Messaggi
    864
    Versione Office
    2000 - 2013
    Likes ricevuti
    285
    Likes dati
    160
    Buona giornata a Tutti;
    scusate l'intrusione, ma, mi sarei aspettato che venissero considerati anche gli Articoli:
    - Frigo del 11/08/2015
    - Radio del 30/10/2015
    Questo non avviene; sapreste, cortesemente, dirmi dove sbaglio?


    Grazie dell'attenzione che potrete dedicarmi.

    Buon fine settimana.

    Giuseppe
    Windows XP Excel 2000 - Windows 10 Excel 2013

  23. #22
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    @ Maxy
    Se il data base fosse stato disposto come come un normale DATABASE con "Campi" sulle colonne e "Records" sulle righe il tutto sarebbe stato più facile, in fatti qui ho creato qualcosa con la funzione FREQUENZA alla quale sono particolarmente affezionato
    in questo caso abbiamo 2 formule con un approccio completamente diverso anche se le condizioni sono le stesse (create da ninai)
    però per ottenere ciò ho fatto due formule e il tutto per avere tutto più robusto e stabile ma in particolare per evitare errore #N/D quando il mese era 1 (uno) e sopratutto abbiamo tutti i pari meriti
    (incrociamo le dita) e fammi sapere!


    in H3 i numeri dei mesi

    In D1 questa formula da attivare con i tasti CTRL+SHIFT+ENTER

    =MAX(FREQUENZA(SE($A$2:$A$12<>"";SE($B$2:$B$12>DATA(ANNO(OGGI());MESE(OGGI())-H3;GIORNO(OGGI()));CONFRONTA($A$2:$A$12;$A$2:$A$12;0)));RIF.RIGA($A$2:$A$12)-RIF.RIGA($A$2)+1))

    in D4 questa formula da attivare con i tasti CTRL+SHIFT+ENTER e copiare in basso

    =SE.ERRORE(INDICE($A$2:$A$12;PICCOLO(SE(FREQUENZA(SE($A$2:$A$12<>"";SE($B$2:$B$12>DATA(ANNO(OGGI());MESE(OGGI())-$H$3;GIORNO(OGGI()));CONFRONTA($A$2:$A$12;$A$2:$A$12;0)));RIF.RIGA($A$2:$A$12)-RIF.RIGA($A$2)+1)=$D$1;RIF.RIGA($A$2:$A$12)-RIF.RIGA($A$2)+1);RIGHE($D$4:D4)));"")


    A
    B
    C
    D
    1
    apparecchio data
    4
    2
    Radio
    18/12/2015
    3
    Radio
    25/12/2015
    4
    Televisione
    30/09/2015
    Radio
    5
    Frigo
    02/02/2015
    Televisione
    6
    Televisione
    15/11/2015
    7
    Forno
    18/05/2015
    8
    Televisione
    25/11/2015
    9
    Frigo
    11/08/2015
    10
    Televisione
    30/09/2015
    11
    Radio
    30/10/2015
    12
    Radio
    15/12/2015

  24. #23
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Citazione Originariamente Scritto da GiuseppeMN Visualizza Messaggio
    Buona giornata a Tutti;
    scusate l'intrusione, ma, mi sarei aspettato che venissero considerati anche gli Articoli:
    - Frigo del 11/08/2015
    - Radio del 30/10/2015
    Questo non avviene; sapreste, cortesemente, dirmi dove sbaglio?


    Grazie dell'attenzione che potrete dedicarmi.

    Buon fine settimana.

    Giuseppe
    Ciao Giuseppe
    questo perchè a Maxy interessa sapere quale accessorio è stato più venduto entro un tot di mesi, e non la data di quando sono stati venduti questi accessori...
    Ciao a disposizione

  25. #24
    L'avatar di GiuseppeMN
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Mantova
    Messaggi
    864
    Versione Office
    2000 - 2013
    Likes ricevuti
    285
    Likes dati
    160
    Buona sera, Gerardo;
    hai perfettamente ragione.

    Grazie della Tua Attenzione.

    Buona serata.

    Giuseppe
    Windows XP Excel 2000 - Windows 10 Excel 2013

  26. #25
    L'avatar di Maxy
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Friuli Venezia Giulia
    Età
    44
    Messaggi
    39
    Versione Office
    2007
    Likes ricevuti
    2
    Likes dati
    7
    Ciao a tutti.

    @Gerardo
    Grazie Gerardo per la formula del #22. Purtroppo la mia tabella è configurata diversamente, per un motivo di stampa. Non riesco neppure a provarla, dovrei modificare mille impostazioni. Sono convinto comunque funzioni perfettamente. Sarà certamente utile a qualche amico del forum.

    @Giuseppe
    Inizialmente non avevo capito la tua domanda. Gerardo comunque ti ha risposto correttamente. Grazie anche a te per l'attenzione.

    Ciao a tutti

Discussioni Simili

  1. [Risolto] vba: riferimento cella con spazio (come si traduce lo spazio?)
    Di andreafuri nel forum Domande su Excel VBA e MACRO
    Risposte: 10
    Ultimo Messaggio: 07/12/16, 00:31
  2. Ricerca sconto articolo in base al periodo
    Di Barchetta nel forum Domande su Excel in generale
    Risposte: 14
    Ultimo Messaggio: 28/07/16, 08:02
  3. incasso giornaliero con codici articolo
    Di pinnighi nel forum Domande su Excel in generale
    Risposte: 9
    Ultimo Messaggio: 18/05/16, 18:37
  4. Estrapolazione conteggio dati in intervallo di tempo definito
    Di angi.viola nel forum Domande su Excel in generale
    Risposte: 6
    Ultimo Messaggio: 05/05/16, 12:49
  5. Sommare valori riguardanti uno stesso articolo.
    Di Lucagiuseppe nel forum Domande su Excel in generale
    Risposte: 5
    Ultimo Messaggio: 07/03/16, 01:13

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •