Risultati da 1 a 8 di 8

Discussione: [Domanda]multipli cognomi da colonna a riga senza perdere il nome



  1. #1
    L'avatar di gaso
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    High Wycombe
    Età
    28
    Messaggi
    4
    Versione Office
    2016
    Likes ricevuti
    0
    Likes dati
    0

    [Domanda]multipli cognomi da colonna a riga senza perdere il nome

    Salve,
    Mi chiamo Marco e sono un Novizio di Excel.
    (ho scritto nome e cognomi per rendere l idea non mi veniva niente in mente di piu semplice)
    Ho un piccolo problema che spieghero' in maniera semplice

    ho due colonne
    A , B
    X01, A1
    X02, B1
    X02, B2
    X01, A2
    X02, B3
    X01, A3
    X03, C1
    X04, D1

    vorrei riordinarle portando singolarmente ogni valore della colonna A con Tutti i valori della colonna B su una sola Linea
    cosa intendo:

    X01, A1;A2;A3
    X02, B1;B2;B3
    X03, C1
    X04, D1

    l'unica cosa che conosco di excel e non tanto bene e' il Cerca Verticale, e pensavo che utilizzarlo con qualche variante potrebbe funzionare, ma non conosco le varianti o altri comandi, potreste aiutarmi?
    Spero proprio di si, grazie in anticipo


    ps: ho provato ad editare il titolo dato che mi sono dimenticato di completarlo ma non mi e' possibile
    Ultima modifica fatta da:Canapone; 05/07/17 alle 16:24

  2. #2

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7161
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2065
    Likes dati
    1301
    Ciao,
    se ho ben capito la domanda vuoi aggregare i dati da due colonne in una sola riga.

    Poniamo che i dati siano nel range B6:B13 e C6:C16 e vogliamo ottenere gli aggregati nella colonna E ed F, ho usato queste formule.

    In E6 da trascinare in basso

    =SE.ERRORE(INDICE($B$6:$B$13;CONFRONTA(0;INDICE(CONTA.SE($B$6:$B$13;"<"&$B$6:$B$13)-MATR.SOMMA.PRODOTTO(CONTA.SE($B$6:$B$13;E$5:E5)););0));"")

    In F6 da trascinare in basso

    =ANNULLA.SPAZI(SE.ERRORE(INDICE($C$6:$C$13;AGGREGA(15;6;RIF.RIGA($A$6:$A$13)-5/($B$6:$B$13=E6);1));"")&" "&SE.ERRORE(INDICE($C$6:$C$13;AGGREGA(15;6;RIF.RIGA($A$6:$A$13)-5/($B$6:$B$13=E6);2));"")&" "&SE.ERRORE(INDICE($C$6:$C$13;AGGREGA(15;6;RIF.RIGA($A$6:$A$13)-5/($B$6:$B$13=E6);3));"")&" "&SE.ERRORE(INDICE($C$6:$C$13;AGGREGA(15;6;RIF.RIGA($A$6:$A$13)-5/($B$6:$B$13=E6);4));""))

    Se invece vuoi separare i risultati basta separare le formule
    Allego file esempio 1 e 2.
    File Allegati File Allegati
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  3. I seguenti utenti hanno dato un "Like"


  4. #3
    L'avatar di gaso
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    High Wycombe
    Età
    28
    Messaggi
    4
    Versione Office
    2016
    Likes ricevuti
    0
    Likes dati
    0
    ora provo, il fatto che il mio Excel sia inglese, credo mi dara qualche problema ti aggiorno

    grazie mille!!!
    Ultima modifica fatta da:Canapone; 05/07/17 alle 16:25

  5. #4

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7161
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2065
    Likes dati
    1301
    In inglese le formule dovrebbero essere così:

    =IFERROR(INDEX($B$6:$B$13,MATCH(0,INDEX(COUNTIF($B$6:$B$13,"<"&$B$6:$B$13)-SUMPRODUCT(COUNTIF($B$6:$B$13,E$5:E5)),),0)),"")


    =TRIM(IFERROR(INDEX($C$6:$C$13,AGGREGATE(15,6,ROW($A$6:$A$13)-5/($B$6:$B$13=E6),1)),"")&" "& IFERROR (INDEX($C$6:$C$13, AGGREGATE (15,6,ROW($A$6:$A$13)-5/($B$6:$B$13=E6),2)),"")&" "& IFERROR (INDEX($C$6:$C$13, AGGREGATE (15,6,ROW($A$6:$A$13)-5/($B$6:$B$13=E6),3)),"")&" "& IFERROR(INDEX($C$6:$C$13, AGGREGATE (15,6,ROW($A$6:$A$13)-5/($B$6:$B$13=E6),4)),""))
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  6. #5
    L'avatar di gaso
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    High Wycombe
    Età
    28
    Messaggi
    4
    Versione Office
    2016
    Likes ricevuti
    0
    Likes dati
    0
    Sei un santo!
    Grazie mille, funziona alla perfezione, ora lo studio e cerco di capirci qualcosa, ma e' difficilissimo!
    Ultima modifica fatta da:Canapone; 05/07/17 alle 16:25

  7. #6
    L'avatar di gaso
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    High Wycombe
    Età
    28
    Messaggi
    4
    Versione Office
    2016
    Likes ricevuti
    0
    Likes dati
    0
    grazie anche per la traduzione comunque ha funzionato anche quella in italiano, me l'ha tradotta automaticamente.
    Ultima modifica fatta da:Canapone; 05/07/17 alle 16:25

  8. #7
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Ciao a tutti , sono da cellulare, una piccola informazione che potrebbe essere utile, se hai la versione in inglese e apri il file che ha postato ges, automaticamente dovresti avere le formule in inglese, tutto qua. Ciao a tutti auguroni

  9. #8

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7161
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2065
    Likes dati
    1301
    Citazione Originariamente Scritto da gaso Visualizza Messaggio
    SEI UN SANTO! :D Grazie mille, funziona alla perfezione, ora lo studio e cerco di capirci qualcosa, ma e' difficilissimo! (finger crossed)
    Non esageriamo! :90:

    Allora vedo di darti una mano a capire le formule.

    Partiamo da questa

    =ANNULLA.SPAZI(SE.ERRORE(INDICE($C$6:$C$13;AGGREGA(15;6;RIF.RIGA($A$6:$A$13)-5/($B$6:$B$13=E6);1));"")&" "&SE.ERRORE(INDICE($C$6:$C$13;AGGREGA(15;6;RIF.RIGA($A$6:$A$13)-5/($B$6:$B$13=E6);2));"")&" "&SE.ERRORE(INDICE($C$6:$C$13;AGGREGA(15;6;RIF.RIGA($A$6:$A$13)-5/($B$6:$B$13=E6);3));"")&" "&SE.ERRORE(INDICE($C$6:$C$13;AGGREGA(15;6;RIF.RIGA($A$6:$A$13)-5/($B$6:$B$13=E6);4));""))

    Tralasciamo ANNULLA.SPAZI che è una formula di prudenza nel caso ci siano degli spazi nelle celle interessate che li annulla appunto.
    Tralasciamo anche SE.ERRORE che è una formula che si attiva in caso di errore e qui si è scelto di lasciare la cella vuota.

    La formula è l’unione di 4 formule (4 perché tante sono le condizioni da verificare (X01,X02;X03;X04) potevano esser di più o di meno in base al numero delle condizioni.

    La formula singola è dunque

    INDICE($C$6:$C$13;AGGREGA(15;6;RIF.RIGA($A$6:$A$13)-5/($B$6:$B$13=E6);1))

    Con questa formula stiamo chiedendo con INDICE di tenere conto della matrice $C$6:$C$13 dove sono i dati da scegliere.

    I dati saranno scelti in base alla riga trovata con

    AGGREGA(15;6;RIF.RIGA($A$6:$A$13)-5/($B$6:$B$13=E6);1)

    In pratica si usa la formula aggrega per trovare la riga dell’indice, usando questo escamotage.

    15 la funzione PICCOLO (così troviamo prima A1, poi A2 e quindi A3) se si vuole invertire l’ordine basta scegliere GRANDE (14)
    6 il prodotto e come matrice la prima parte RIF.RIGA($A$6:$A$13) è stato scelto A6:a13 ma poteva benissimo essere scelto B6:B13 o altra area dello stesso range

    Il – 5 serve a togliere le righe sopra vuote perché siamo partiti a scrivere i dati e le formule dalla riga sei, se questi ultimi erano posizionati nella riga 5 bastava scrivere – 4; se erano posizionati nella riga 1 si può omettere questa sottrazione

    Il risultato di questa prima parte (1) diviso l’altra parte /($B$6:$B$13=E6), da VERO quendo la condizione si verifica e quindi se la condizione è vera la divisione 1

    Infine 1 il k questo potrebbe essere sostituito per creare una formula unica da trascinare in basso e a destra con RIF.COLONNA(A1)

    Spero di aver chiarito e di non aver creato altra confusione, se serve spiegazione sull'altra formula posso eventualmente in serata.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  10. I seguenti utenti hanno dato un "Like"


Discussioni Simili

  1. [Risolto] Copia foglio su file diversi senza perdere formattazione
    Di giampi nel forum Domande su Excel in generale
    Risposte: 7
    Ultimo Messaggio: 06/03/17, 00:11
  2. L'indice dei fogli di lavoro, come aggiornarlo senza perdere i dati
    Di ProgrammD69 nel forum Domande su Excel VBA e MACRO
    Risposte: 25
    Ultimo Messaggio: 25/01/17, 22:19
  3. Scrivere nella cella senza perdere la formula
    Di carega83 nel forum Domande su Excel in generale
    Risposte: 10
    Ultimo Messaggio: 16/03/16, 22:35
  4. Domanda su estrazione righe di una colonna
    Di bolomanonbolo nel forum Domande su Excel in generale
    Risposte: 4
    Ultimo Messaggio: 14/01/16, 12:15
  5. Domanda su estrazione dati da una colonna
    Di bolomanonbolo nel forum Domande su Excel in generale
    Risposte: 4
    Ultimo Messaggio: 13/01/16, 17:17

Tag per Questa Discussione

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •