Risultati da 1 a 21 di 21

Discussione: importare txt oltre numero max righe excel



  1. #1
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31

    importare txt oltre numero max righe excel

    Ciao a tutti,
    ho un file txt composto da molte righe (più di quelle che ci sono in un foglio excel) e volevo importarlo in Excel per poi poter analizzare i dati.
    Non riesco ad importare tutto il file txt perchè non ci stà in un solo foglio. Ho provato a rifare l'import, come consigliato dal wizard, indicando da che riga ricominciare ad importare i dati la seconda volta, ma Excel non lo fa. Perchè ???:237:

    C'è qualcuno che può darmi dei suggerimenti?:92:

    grazieee

  2. #2
    L'avatar di zio_tom
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Veneto
    Messaggi
    526
    Versione Office
    2010 - Win10
    Likes ricevuti
    64
    Likes dati
    17
    i limiti di Excel dichiarati da Microsoft sono:
    Dimensioni del foglio di lavoro 1.048.576 righe per 16.384 colonne
    Larghezza della colonna 255 caratteri
    Altezza della riga 409 punti
    Interruzioni di pagina 1.026 in orizzontale e in verticale
    Numero totale di caratteri che una cella può contenere 32.767 caratteri

    non penso che il file di testo superi tali limiti
    quindi forse il file ha qualche problema
    hai provato con il semplice copia incolla???

    PS: magari allega il file txt e si prova

  3. #3
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31
    ciao zio tom,
    ho provato anche con copia- incolla...ma mi dice sempre che i dati non possono essere importati completamente...
    pensavo di importare i dati ad intervalli inserendo di volta in volta la riga da cui importare...ma non so perchè non funziona

    comunque questo è il file...

    http://dropcanvas.com/b2gn1

  4. #4

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Ciao a tutti,
    @Loretta

    Ho scaricato e importato il file di testo in excel (in due colonne).
    In effetti è più lungo di 1048576 righe....... ma solo di 1 riga :258: (il file di testo è di 1048577 righe).

    Comunque, quando fai l'importazione, ti dirà (come hai detto) che non è possibile scaricare tutti i dati. Tu continua ed importa tutto quello che puoi (quindi fino alla riga 1048576).
    Dopo, ti posizioni sulla colonna a fianco, o su un altro foglio (o dove ti viene comodo) e ripeti l'importazione dello stesso file, solo che questa volta nella prima finestra che ti appare della "importazione guidata testo", nel campo con la voce "inizia ad importare alla riga" scriverai 1048577.
    e continui fino alla fine.

    [EDIT]
    Ti conviene eliminare una riga vuota dal file di testo e importare tutto in una sola volta.

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  5. #5
    L'avatar di zio_tom
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Veneto
    Messaggi
    526
    Versione Office
    2010 - Win10
    Likes ricevuti
    64
    Likes dati
    17
    caricato con Notepad++ mi risulta di quasi 29 milioni di righe (il file è di 280MB)
    quindi sarebbe da distribuire su 30 colonne

    c'è qualcosa che non torna!!!!! a cromagno risulta di 1 milione di righe!!!

    la soluzione sarebbe con una procedure VBA di lettura ed importazione testi, in rete ce ne sono molte. Ora non ho tempo per scriverla, ma sicuramente qualche forumista ce l'ha bella e pronta.


    PS: faccio notare che su dropcanvas c'è un piccolo messaggio che avverte che il file scade dopo 3 giorni
    quindi sarebbe da sconsigliarne l'uso nel forum

  6. #6

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Citazione Originariamente Scritto da zio_tom Visualizza Messaggio
    c'è qualcosa che non torna!!!!! a cromagno risulta di 1 milione di righe!!!
    Ciao zio_tom,
    hai ragione tu!
    in effetti controllando le righe con un ciclo VBA mi dà 28988152 righe... non mi so spiegare perchè ieri mi importava solo le righe che ho detto :236:

    Codici pronti purtroppo non ne ho... appena posso provo qualcosa.

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  7. #7
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31
    Ciao cromagno e zio tom,
    a me risultano circa 29 milioni di righe (con blocco note).
    Ho provato ad importare i dati: mi dice che non sono stati importati completamente tutti i dati...così mi sistemo in altra colonna (ho provato anche in un altro foglio) e rifaccio l'importazione partendo dalla riga 1048576.......solo che non li importa fino alle fine del foglio, quindi non importa un altro gruppo di 1048576 dati ma finisce molto prima l'importazione...:92:

    sto sbagliando qualcosa? ad ogni modo procedere importando 29milioni di dati a gruppi di 1048576 è abbastanza lungo...:277:

  8. #8
    L'avatar di zio_tom
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Veneto
    Messaggi
    526
    Versione Office
    2010 - Win10
    Likes ricevuti
    64
    Likes dati
    17
    Questo codice funziona sicuramente con file di medie dimensioni.
    Come si vede ho suddiviso in colonne da 1 milione, con 5 colonne per Foglio, e quindi dovrebbe riempire 6 Fogli.
    Con il file di Loretta i tempi sono lunghi ed a me da problemi di memoria (ed ho 8GB di memoria, con Excel 2010 32bit, ma ho diverse App attivate) e di tempi.
    Si interrompe ogni milione di righe, e quindi se si vuole si sceglie di continuare od uscire, se si vuole andare fino in fondo basta risponder NO alla domanda iniziale
    per il primo milione siamo nell'ordine dei minuti.... poi ho stoppato.
    Penso poi che riempiendosi i tempi si allunghino ulteriormente, saremo sull'ordine di almeno un'ora.

    Codice: 
    Public Sub leggiFileTesto()
        On Error GoTo leggiFileTesto_Error
        Dim i As Integer, flgInt As Boolean
        Dim strLine As String, FullFileName As String
        Dim Riga As Long, Colonna As Long
        
        Select Case MsgBox("Con interruzioni?", vbYesNo Or vbQuestion Or vbDefaultButton1, "")
                 Case vbYes
                        flgInt = True
                 Case vbNo
                        flgInt = False
        End Select
        
        FullFileName = Application.GetOpenFilename("Text Files (*.txt), *.txt")
        
        Application.EnableEvents = False
        
        i = FreeFile
        Open FullFileName For Input As #i
            Riga = 1: Colonna = 1: numSheet = 1
            Do Until EOF(i)
                Line Input #i, strLine
                Sheets(numSheet).Cells(Riga, 1) = strLine
                Riga = Riga + 1
                If Riga > 1000000 Then
                   Riga = 1
                   Colonna = Colonna + 1
                   If Colonna = 6 Then
                      Colonna = 1
                      numSheet = numSheet + 1
                   End If
                   If flgInt Then
                      Select Case MsgBox("Foglio: " & numSheet & Chr(13) & "   Colonna: " & Colonna & Chr(13) & "CONTINUO ??", vbYesNo Or vbExclamation Or vbDefaultButton1, "Messaggio")
                               Case vbNo
                                      Exit Sub
                      End Select
                   End If
                End If
            Loop
        Close #i
       
       Application.EnableEvents = True
       
       On Error GoTo 0
       Exit Sub
    
    leggiFileTesto_Error:
        MsgBox "Errore " & Err.Number & " (" & Err.Description & ") nella procedura 'leggiFileTesto' nel Modulo 'Leggi'"
    End Sub

  9. #9

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Verona Provincia
    Età
    57
    Messaggi
    1017
    Versione Office
    .
    Likes ricevuti
    366
    Likes dati
    0
    Citazione Originariamente Scritto da zio_tom Visualizza Messaggio
    Codice: 
    Public Sub leggiFileTesto()
    .....CUT
                Sheets(numSheet).Cells(Riga, 1) = strLine
    ....CUT
    Solo per far notare che al posto di 1 credo vada Colonna.
    Bye!
    scossa
    scossa's web site
    ___
    Se tu hai una mela, e io ho una mela, e ce le scambiamo, allora tu ed io abbiamo sempre una mela per uno. Ma se tu hai un'idea, ed io ho un'idea, e ce le scambiamo, allora abbiamo entrambi due idee. (George Bernard Shaw)

  10. #10
    L'avatar di zio_tom
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Veneto
    Messaggi
    526
    Versione Office
    2010 - Win10
    Likes ricevuti
    64
    Likes dati
    17

    Post

    un codice un po' più articolato, con informazioni e gestione del processo

    Codice: 
    Public Sub leggiFileTesto()
        On Error GoTo leggiFileTesto_Error
        Dim i As Integer, flgInt As Boolean
        Dim strLine As String, FullFileName As String
        Dim Riga As Long, Colonna As Long, RigheT As Long, rgt As Long, rgtM As Long
        Dim StartTime As Double, EndTime As Double, StopTime As Double, tempoMancante As Double
        
        FullFileName = Application.GetOpenFilename("Text Files (*.txt), *.txt")
        
        Application.EnableEvents = False
        StartTime = Timer
        i = FreeFile
        Open FullFileName For Input As #i
            RigheT = 1
            Do Until EOF(i)
                Line Input #i, strLine
                RigheT = RigheT + 1
            Loop
        Close #i
        EndTime = Timer
        Select Case MsgBox("Numero Righe totali: " & RigheT & Chr(13) & _
                "Tempo di esecuzione in secondi: " & Format$(EndTime - StartTime) & Chr(13) & _
                "Tempo stimato processo: " & Format(CDate(Int((EndTime - StartTime) * 640) / 86400), "hh:mm:ss") & Chr(13) & _
                "Con interruzioni?", vbYesNoCancel + vbQuestion, "Messaggio")
            Case vbYes
                 flgInt = True
            Case vbNo
                 flgInt = False
            Case vbCancel
                 Exit Sub
        End Select
        
        StartTime = Timer
        i = FreeFile
        Open FullFileName For Input As #i
            Riga = 1: Colonna = 1: numSheet = 1
            Do Until EOF(i)
                Line Input #i, strLine
                Sheets(numSheet).Cells(Riga, Colonna) = strLine
                Riga = Riga + 1
                If Riga > 1000000 Then
                   Riga = 1
                   Colonna = Colonna + 1
                   If Colonna = 6 Then
                      Colonna = 1
                      numSheet = numSheet + 1
                   End If
                   If flgInt Then
                      StopTime = Timer
                      rgt = (numSheet - 1) * 5000000 + (Colonna - 1) * 1000000 + Riga  'righe processate
                      rgtM = RigheT - rgt  'righe mancanti
                      tempoMancante = Int((StopTime - StartTime) / rgt * rgtM)
                      Select Case MsgBox("Foglio: " & numSheet & Chr(13) & _
                                         "Colonna: " & Colonna & Chr(13) & _
                                         "Secondi trscorsi: " & Int(StopTime - StartTime) & Chr(13) & _
                                         "Tempo mancante: " & Format(CDate(tempoMancante / 86400), "hh:mm:ss") & Chr(13) & _
                                         "CONTINUO ??", vbYesNo Or vbExclamation Or vbDefaultButton1, "Messaggio")
                      Case vbNo
                           Exit Sub
                      End Select
                   End If
                End If
            Loop
        Close #i
       
        EndTime = Timer
        Application.EnableEvents = True
       
        MsgBox "Numero Righe: " & Riga & Chr(13) & "Tempo di esecuzione: " + Format(CDate((EndTime - StartTime) / 86400), "hh:mm:ss")
       
        On Error GoTo 0
        Exit Sub
    
    leggiFileTesto_Error:
        MsgBox "Errore " & Err.Number & " (" & Err.Description & ") nella procedura 'leggiFileTesto' nel Modulo 'Leggi'"
    End Sub
    le stime danno circa 2 ore e mezza, ma con caselle riempite i tempi dovrebbero salire e creare eventuali problemi di memoria

  11. #11
    L'avatar di zio_tom
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Veneto
    Messaggi
    526
    Versione Office
    2010 - Win10
    Likes ricevuti
    64
    Likes dati
    17
    x Loretta
    hai provato e risolto??
    ulteriormente arricchito ma sostanzialmente il solito
    Codice: 
    Public Sub leggiFileTesto()
        On Error GoTo leggiFileTesto_Error
        Dim i As Integer, k As Integer, flgInt As Boolean, nFogli As Integer, aggFogli As Integer
        Dim strLine As String, FullFileName As String, oldPath As String, myPath As String
        Dim Riga As Long, Colonna As Long, RigheT As Long, rgt As Long, rgtM As Long, n As Long, rgCol As Long, ColFgl As Long
        Dim StartTime As Double, EndTime As Double, StopTime As Double, tempoMancante As Double
        
        rgCol = 1000000  'righe per colonna
        ColFgl = 5      'colonne per foglio
            
        With Application
             oldPath = .DefaultFilePath
             myPath = ThisWorkbook.Path
             .DefaultFilePath = myPath
             ChDrive Left(myPath, 1)
             ChDir myPath
             FullFileName = .GetOpenFilename("Text Files (*.txt), *.txt")
             ChDrive Left(oldPath, 1)
             .DefaultFilePath = oldPath
        End With
        
        Application.EnableEvents = False
          
        Select Case MsgBox("Attivo DisplayStusBar ?", vbYesNoCancel + vbQuestion, "Messaggio")
               Case vbYes
                    Application.DisplayStatusBar = True
                    k = 2170
               Case vbNo
                    Application.DisplayStatusBar = False
                    k = 565
               Case vbCancel
                    GoTo esci
        End Select
        
        StartTime = Timer
        i = FreeFile
        Open FullFileName For Input As #i
            RigheT = 1
            Do Until EOF(i)
                Line Input #i, strLine
                RigheT = RigheT + 1
            Loop
        Close #i
        
        nFogli = Int(RigheT / (ColFgl * rgCol) + 1)
        aggFogli = nFogli - Sheets.Count
        
        If aggFogli > 0 Then
           Select Case MsgBox("Aggiungo " & aggFogli & " fogli mancanti? (o esco)", vbOKCancel + vbQuestion, "Messaggio")
                  Case vbOK
                       For j = 1 To aggFogli
                           ActiveWorkbook.Sheets.Add After:=Worksheets(Worksheets.Count)
                       Next j
                  Case vbCancel
                       GoTo esci
           End Select
        End If
        
        EndTime = Timer
        Select Case MsgBox("Numero Righe totali: " & RigheT & vbCr & _
                           "Numero Fogli: " & nFogli & vbCr & _
                           "Tempo di esecuzione in secondi: " & Format(EndTime - StartTime, "0.00") & vbCr & _
                           "Tempo stimato processo: " & Format(CDate(Int((EndTime - StartTime) * k) / 86400), "hh:mm:ss") & vbCr & _
                           "Con interruzioni?", vbYesNoCancel + vbQuestion, "Messaggio")
               Case vbYes
                    flgInt = True
               Case vbNo
                    flgInt = False
               Case vbCancel
                    GoTo esci
        End Select
        
        StartTime = Timer
        i = FreeFile
        Open FullFileName For Input As #i
            Riga = 1: Colonna = 1: numSheet = 1
            Do Until EOF(i)
                Line Input #i, strLine
                n = n + 1
                Sheets(numSheet).Cells(Riga, Colonna) = strLine
                If k = 2170 Then Application.StatusBar = "Righe Elaborate... " & n
                Riga = Riga + 1
                If Riga > rgCol Then
                   Riga = 1
                   Colonna = Colonna + 1
                   If Colonna > ColFgl Then
                      Colonna = 1
                      numSheet = numSheet + 1
                   End If
                   If flgInt Then
                      StopTime = Timer
                      rgt = (numSheet - 1) * rgCol * ColFgl + (Colonna - 1) * rgCol + (Riga - 1) 'righe processate
                      rgtM = RigheT - rgt  'righe mancanti
                      tempoMancante = Int((StopTime - StartTime) / rgt * rgtM)
                      Select Case MsgBox("Foglio: " & numSheet & vbCr & _
                                         "Colonna: " & Colonna & vbCr & _
                                         "Secondi trascorsi: " & Int(StopTime - StartTime) & vbCr & _
                                         "Righe mancanti: " & rgtM & vbCr & _
                                         "Tempo mancante: " & Format(CDate(tempoMancante / 86400), "hh:mm:ss") & vbCr & _
                                         "CONTINUO ??", vbYesNo + vbExclamation, "Messaggio")
                             Case vbNo
                                  GoTo esci
                      End Select
                   End If
                End If
            Loop
        Close #i
    esci:
        EndTime = Timer
        
        Application.DisplayStatusBar = True
        Application.StatusBar = ""
        
        Application.EnableEvents = True
       
        MsgBox "Numero Righe: " & n & vbCr & "Tempo di esecuzione: " + Format(CDate((EndTime - StartTime) / 86400), "hh:mm:ss")
       
        On Error GoTo 0
        Exit Sub
    
    leggiFileTesto_Error:
        MsgBox "Errore " & Err.Number & " (" & Err.Description & ") nella procedura 'leggiFileTesto' nel Modulo 'Leggi'"
    End Sub

  12. I seguenti utenti hanno dato un "Like"


  13. #12
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31
    ciao zio tom,
    ho provato ad importare e ad un certo punto compare la finestra di errore

    " Errore 9 (indice non incluso nell'intervallo, nella procedura 'leggifiletesto' nel modulo leggi"

    e non continua più..

  14. #13
    L'avatar di zio_tom
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Veneto
    Messaggi
    526
    Versione Office
    2010 - Win10
    Likes ricevuti
    64
    Likes dati
    17
    devi avere almeno 6-7 fogli
    29 milioni righe/ (1 milione di righe x 5 colonne) = 6 fogli
    l'ultima versione che ho postato, crea i fogli mancanti

    fammi sapere

  15. #14
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31
    ciao zio tom,
    sto provando ad importare il mio file txt con il codice che hai creato ma excel si blocca:223:....ho tenuto il pc acceso tutto il giorno e la notte e poi si è bloccato...ho riprovato ma dopo alcune ore si blocca excel :186:e quindi è come se non avessi importato nulla.:251:

    E' possibile modificare il codice importando a "pezzi" il file txt ?
    Ad esempio se il codice mi chiedesse:

    "da quale riga vuoi importare?"... e poi ... "fino a quale riga vuoi importare?"

    in modo tale che inserendo un intervallo di righe riesco ad importare e salvare man mano i vari file senza che il pc rimanga acceso ore e ore e poi si blocchi..:277:

    graziee

    loretta

  16. #15

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Ciao a tutti,
    @Loretta
    mi ero quasi dimenticato di questa discussione :288:

    Avevo fatto diverse prove (soprattutto con codici simili a quelli proposti da zio_tom, che saluto...) ma nessuna soddisfacente perchè si bloccava tutto.
    Il metodo più veloce sembrerebbe essere l'importazione dati ma non so per quale motivo non importa più righe di quelle massime di una colonna.

    Con questo codice probabilmente dovresti riuscire ad importare tutto in mezz'ora o forse meno (mi sono fermato a 4 colonne e ci ha messo circa 150 sec.).

    Codice: 
    Sub Scegli_prove()
    Dim sh1 As Worksheet, fullnome As String, testo As String, inizio As Double
    Dim conta As Double, Ncolonne As Integer, riga As Long, Col As Long, domanda
    Dim i As Long, j As Long, matrice()
    
    
    Application.ScreenUpdating = False
    inizio = Timer
    With ThisWorkbook
    Set sh1 = .Worksheets("Foglio1")
    End With
    
    
    With Application.FileDialog(msoFileDialogFilePicker)
    .AllowMultiSelect = False
    .Filters.Clear
    .Filters.Add "All files", "*.*"
    .Filters.Add "text", "*.txt", 1
    .Show
    
    
    If .SelectedItems.Count = 0 Then
    MsgBox ("Nessuna voce selezionata, procedura annullata")
    GoTo esci
    End If
    fullnome = .SelectedItems(1)
    End With
    
    
    '=========================================
    Open fullnome For Input As #1
    Do While Not EOF(1)
    Line Input #1, testo
    conta = conta + 1
    Loop
    Close #1
    
    
    If conta / 1000000 > Int(conta / 1000000) Then
        Ncolonne = Int(conta / 1000000) + 1
    Else
        Ncolonne = Int(conta / 1000000)
    End If
    MsgBox "Le righe da importare sono " & conta
    '=========================================
    ReDim matrice(1 To 1000000, 1 To Ncolonne)
    riga = 1
    Col = 1
    Open fullnome For Input As #1
    Do While Not EOF(1)
        Line Input #1, testo
        matrice(riga, Col) = testo
        riga = riga + 1
        If riga > 1000000 Then
            riga = 1
            Col = Col + 1
        End If
    Loop
    Close #1
    For i = 1 To Ncolonne
        For j = 1 To 1000000
            Cells(j, i + 1).Value = matrice(j, i)
        Next j
        domanda = MsgBox("Colonna " & i & " di " & Ncolonne & " importata. Continuare?", vbYesNo)
        If domanda = vbNo Then GoTo esci
    Next i
    esci:
    Application.ScreenUpdating = True
    MsgBox Timer - inizio & " secondi"
    End Sub
    La prima colonna ci impiega più delle altre perchè prima deve caricare anche la variabile "matrice()".
    Dopo ogni colonna importata (ogni colonna è composta da 1 milione di righe) ti uscirà un messaggio per continuare oppure no.
    Se non vuoi questo messaggio (anche se non so se potrebbe bloccarsi tutto) metti il simbolo di apice a entrambe queste righe:

    Codice: 
    domanda = MsgBox("Colonna " & i & " di " & Ncolonne & " importata. Continuare?", vbYesNo)
    If domanda = vbNo Then GoTo esci
    Che dire... prova anche questo. :288:

    Ti lascio il file in allegato...

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  17. I seguenti 2 utenti hanno dato un "Like" a cromagno per questo post:


  18. #16
    L'avatar di zio_tom2
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    veneto
    Messaggi
    1
    Versione Office
    2010
    Likes ricevuti
    0
    Likes dati
    0
    L'unica soluzione è o spezzzare il file di testo in più file
    oppure salvarlo a pezzi su più file Excel
    probabilmente è un problema di gestione della memoria
    quindi anche se carico a pezzi il problema rimane
    se va bene su più file Excel si può vedere di farlo
    visto che leggere tutto il file senza scrivere lo fa
    che fino a 5 milioni di righe a me funziona
    quindi si potrebbe, invece su 6 fogli farlo su 6 file...

  19. #17
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31
    Cromagno ho utilizzato il tuo codice ed ho importato tutte e 29 milioni di righe di dati in meno di 15 minuti! :286:
    Wowwwww!!:274: Lo utilizzerò sicuramente anche per altro, penso sia davvero utile!!

    grazie mille a tutti e buona serata.

    Loretta

  20. #18

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Citazione Originariamente Scritto da Loretta Visualizza Messaggio
    Cromagno ho utilizzato il tuo codice ed ho importato tutte e 29 milioni di righe di dati in meno di 15 minuti! :286:
    Wowwwww!!:274: Lo utilizzerò sicuramente anche per altro, penso sia davvero utile!!

    grazie mille a tutti e buona serata.

    Loretta
    Finalmente ce l'abbiamo fatta...:17:

    Loretta, se hai risolto segna questa discussione come risolto.

    P.S.
    Una curiosità...
    hai mantenuto il messaggio dopo ogni colonna importata o hai importato tutto senza soste?

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  21. #19
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31
    ho mantenuto il messaggio dopo ogni colonna importata, ma è stato molto veloce.

  22. #20
    L'avatar di zio_tom
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Veneto
    Messaggi
    526
    Versione Office
    2010 - Win10
    Likes ricevuti
    64
    Likes dati
    17
    a me si blocca dopo 105000 righe caricate nella matrice e va in out of memory
    il mio passava i 5000000 e poi si bloccava
    però rispetto a voi che avete 2013, ho 2010 sotto W10 ed alcune App
    il PC ha 8Gb di memoria ed il file è da 300Mb e non dovrebbero esserci problemi
    ho avvisaglie per reinstallare tutto......

  23. #21

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Ciao zio_tom,
    non saprei che dirti....
    fatto sta che tra una versione e l'altra hanno fatto sempre più casini.

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

Discussioni Simili

  1. limiti numero di righe excel
    Di stefanofusco nel forum Domande su Excel in generale
    Risposte: 6
    Ultimo Messaggio: 14/03/17, 18:12
  2. [Risolto] Immissioni numero identificativo per le righe uguali
    Di Paolerrai nel forum Domande su Excel in generale
    Risposte: 13
    Ultimo Messaggio: 11/01/17, 13:23
  3. Turni di oltre 24 ore
    Di Pizzetto nel forum Domande su Excel in generale
    Risposte: 6
    Ultimo Messaggio: 02/08/16, 10:54
  4. Collegare dati in un numero predeterminato di righe
    Di Thread nel forum Domande su Excel in generale
    Risposte: 5
    Ultimo Messaggio: 18/06/16, 20:30
  5. numero righe in automatico
    Di Dagatos nel forum Domande su Excel VBA e MACRO
    Risposte: 1
    Ultimo Messaggio: 25/03/16, 22:32

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •