Risultati da 1 a 19 di 19

Discussione: cercare numeri o segni corrispondenti ai valori più alti o più presenti nella stessa



  1. #1
    L'avatar di kroma
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    Lecce
    Messaggi
    23
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    0

    cercare numeri o segni corrispondenti ai valori più alti o più presenti nella stessa

    Un saluto a tutti !!! Combatto da giorni con un grosso problema (sicuramente piccolo per molti di voi) per il quale vi chiedo un grosso aiuto. Provo a farmi capire senza esempi, ma illustrandovi direttamente il mio progetto (VEDI ALLEGATO). Settimanalmente riporto su un file Excel alcune partite. Successivamente condivido con alcuni amici il file su Google Drive per fare in modo che ognuno inserisca con tutta calma i propri pronostici. A cosa fatta, tutti insieme giochiamo TUTTE le schedine ed un SISTEMONE che nelle nostre intenzioni dovrebbe rappresentare l'insieme di tutti i pronostici. E qui iniziano i problemi Ho provato a ragionarci su e a risolvere mettendo in campo le mie conoscenze (pochino pochino EXCEL...no VBA): innanzitutto ho effettuato su una nuova tabella un conteggio dei pronostici con un semplice CONTA.SE. Successivamente ho provveduto ad estrarre i pronostici più giocati con la seguente formula =INDICE($C$14:$I$14;CONFRONTA(MAX(C15:I15);C15:I15 ;0)) dove in $C$14:$I$14 è riportata la matrice e nella riga 15 i vari pronostici. PROBLEMA 1: la formula così com'è mi restituisce solo il segno corrispondente al PRIMO numero più alto e spesso i pronostici più giocati sono 2 o più. PROBLEMA 2: il sistemone prevede l'eventuale utilizzo delle DOPPIE e vorrei trovare il modo di ottenere anche il SECONDO pronostico più giocato. In sostanza nella stessa cella il risultato dovrebbe essere "1;goal" dove "1" e "goal"possono rappresentare allo stesso modo i pronostici più giocati oppure il PRIMO ed il SECONDO segno più giocato. PROBLEMA 3: su Google Drive non girano le macro. Buona Giornata
    File Allegati File Allegati

  2. #2
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Ciao benvenuto a forum excel.it
    non so se ho capito bene la tua domanda normalmente le domande troppo lunghe mi confondono e preferisco una domanda alla volta

    Per adesso (per motivi di tempo) rispondo solo alla domanda nr.1 cioè come si fa ad estrarre i valori con i numeri più alti
    bene ci sono diversi modi e il mio modo è quello di mettere i valori su più celle e non tutti in una cella
    e quindi il risultato finale l'ho spostato in un altra zona del foglio dove c'è più spazio.

    Però prima devi sistemare la formula C15
    copia incolla e trascina a destra ed in basso

    =CONTA.SE($K3:$P3;C$2)

    in L15 (o dove vuoi tu) metti questa formula e trascinala a destra ed in basso

    =SE.ERRORE(INDICE($C$14:$I$14;;AGGREGA(15;6;(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1)/($C15:$I15=MAX($C15:$I15));COLONNE($A1:A1)));"")

    Fammi sapere!

  3. #3
    L'avatar di pkrome59
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Reggio Calabria
    Età
    58
    Messaggi
    1188
    Versione Office
    Office 2013
    Likes ricevuti
    1198
    Likes dati
    2133
    Ciao kroma e un grosso ciao a Gerardo, provo a dare una mia possibile soluzione che rappresenta un'estensione della formula proposta da Gerardo cioè:
    =SE.ERRORE(INDICE($C$14:$I$14;;AGGREGA(15;6;(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1)/($C15:$I15=GRANDE($C15:$I15;1));COLONNE($A2:A2)))&" "&SE(CONTA.SE(C15:I15;GRANDE(C15:I15;1))>1;INDICE($C$14:$I$14;;AGGREGA(15;6;(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1)/($C15:$I15=GRANDE($C15:$I15;1));CONTA.SE(C15:I15;GRANDE(C15:I15;1))));"");"")
    da incollare in B3 e trascinarla in basso. Nel file di prova che ho allegato è stata incollata in L15 e trascinata giù.
    Fa sapere.
    File Allegati File Allegati

  4. #4
    L'avatar di kroma
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    Lecce
    Messaggi
    23
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    0
    :252: Grazie Gerardo e grazie pkrome59, ma come avete fatto? Ho provato a leggerla più volte, ma proprio non riesco a capirla!!! In ogni modo funziona a meraviglia. Dovrei adesso copiare la stessa formula nella colonna accanto per riportare in questo caso non i pronostici più giocati, ma quelli che vengono subito dopo. Giusto per capirci il secondo pronostico più giocato, in modo tale da avere a disposizione una seconda colonna con i pronostici di seconda fascia per giocare eventuali doppie. Posso utilizzare la stessa formula?

  5. #5
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    @kroma
    non vorrei aver capito male ma se il valore massimo ce ne sono tre duplicati, e il secondo valore più grande ce ne sono 2 duplicati, tu vorresti estrarre i secondi valori duplicati?
    fammi sapere!

  6. #6
    L'avatar di kroma
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    Lecce
    Messaggi
    23
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    0
    Gerardo, vorrei visualizzare sulla prima colonna il o i pronostici più giocati (che possono essere da 1 a 6....per assurdo può anche accadere che i 6 giocatori esprimano 6 pronostici differenti tra loro....ma è un caso veramente raro). Nella seconda colonna vorrei visualizzare, con lo stesso ragionamento, i pronostici che hanno un' importanza minore rispetto a quelli più giocati, in modo tale da tenerne conto qualora volessimo giocare delle doppie. Esempio 1: GOAL GOAL GOAL 2 2 1 ... Il pronostico più giocato è "GOAL" (finiscono nella prima colonna) e quello subito dopo e che ha un valore inferiore è "2" (seconda colonna). Esempio 2: GOAL GOAL 2 2 1 1 ... i pronostici più giocati sono alla pari "GOAL;2;1" (tutti nella prima colonna). Esempio 3: GOAL GOAL 2 2 1 X ... i pronostici più giocati sono "GOAL;2" (prima colonna) e quelli che vengono subito dopo sono "1X" (nella seconda colonna). Con gli esempi dovrebbe essere tutto più chiaro...spero

  7. #7
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Scusami ma non sono riuscito a seguirti
    prova a mettere un allegato con il risultato desiderato scritto a mano direttamente nel file, con una piccola descrizione del perchè di quel risultato, perchè una immagine vale mille parole
    cerca di essere piu conciso e descrittivo spiega in quale cella vorresti il risultato a quali sono i riferimenti per la formula, vorresti il numero o testo più ricorrente/frequente?
    ciao

  8. #8
    L'avatar di kroma
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    Lecce
    Messaggi
    23
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    0
    Ok Gerardo, hai ragione. Con il file ed i commenti che ho aggiunto dovrebbe essere tutto più chiaro. Ciao e grazie
    File Allegati File Allegati

  9. #9
    L'avatar di pkrome59
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Reggio Calabria
    Età
    58
    Messaggi
    1188
    Versione Office
    Office 2013
    Likes ricevuti
    1198
    Likes dati
    2133
    Ciao kroma; credo che per quanto riguarda il GRANDE, dovremmo esserci con la seguente:
    =SE.ERRORE(INDICE($C$14:$I$14;;AGGREGA(15;6;(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1)/($C15:$I15=GRANDE($C15:$I15;1));1))&" "&SE.ERRORE(INDICE($C$14:$I$14;;AGGREGA(15;6;(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1)/($C15:$I15=GRANDE($C15:$I15;1));2));"")&" "&SE.ERRORE(INDICE($C$14:$I$14;;AGGREGA(15;6;(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1)/($C15:$I15=GRANDE($C15:$I15;1));3));"");"")
    In B3 da copiare e tirare giù.
    Fai sapere se va bene.
    File Allegati File Allegati

  10. #10
    L'avatar di kroma
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    Lecce
    Messaggi
    23
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    0
    Ciao pkrome59 :246: sei stato grande, mi hai dato una grossa mano ed elaborando la tua formula ho risolto anche il problema dei pronostici di 2a fascia (GRANDE -1). Ho dovuto rielaborare la tua formula rendendola ancora più lunga perché ho voluto prendere in considerazione l'ipotesi, a dir la verità molto molto remota, di trovarmi davanti 6 pronostici tutti diversi tra loro. Per i pronostici di 2a fascia, quelli con il valore GRANDE -1 ho apportato una piccola modifica alla tua formula =SE.ERRORE(INDICE($C$14:$I$14;;AGGREGA(15;6;(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1)/($C15:$I15=GRANDE($C15:$I15;1)-1);1))&" "&SE.ERRORE(INDICE($C$14:$I$14;;AGGREGA(15;6;(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1)/($C15:$I15=GRANDE($C15:$I15;1)-1);2));"")&" "&SE.ERRORE(INDICE($C$14:$I$14;;AGGREGA(15;6;(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1)/($C15:$I15=GRANDE($C15:$I15;1)-1);3));"")&" "&SE.ERRORE(INDICE($C$14:$I$14;;AGGREGA(15;6;(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1)/($C15:$I15=GRANDE($C15:$I15;1)-1);4));"")&" "&SE.ERRORE(INDICE($C$14:$I$14;;AGGREGA(15;6;(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1)/($C15:$I15=GRANDE($C15:$I15;1)-1);5));"")&" "&SE.ERRORE(INDICE($C$14:$I$14;;AGGREGA(15;6;(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1)/($C15:$I15=GRANDE($C15:$I15;1)-1);6));"");"") ...... Grazie!!!!!
    File Allegati File Allegati

  11. #11

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4024
    Versione Office
    2013
    Likes ricevuti
    1228
    Likes dati
    923
    Ciao a tutti,
    @Kroma

    Se hai risolto il problema, segna questa discussione come "RISOLTO".
    Vai sul menù "Strumenti Discussione" (all'inizio del thread) e scegli la voce ""Segna questo thread come risolto...".

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  12. #12
    L'avatar di kroma
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    Lecce
    Messaggi
    23
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    0
    Credevo di aver finalmente risolto ed invece....:292: Formula perfetta che mi consente di estrarre i pronostici più giocati e quelli di seconda fascia da utilizzare per eventuali DOPPIE nel sistema, ma mentre gira tutto perfettamente in EXCEL, purtroppo non funziona in Google drive dove i file Excel vengono aperti con google fogli. Di solito la maggior parte delle formule che utilizzo funzionano lo stesso e sono tante quelle che ho utilizzato, ma quelle in A6:A14 e B6:B14 non girano e Google fogli le trasforma così: =IFERROR(INDEX($E$21:$K$21;;AGGREGATE(15;6;(COLUMN($E$21:$K$21)-COLUMN($E$21)+1)/($E22:$K22=LARGE($E22:$K22;1));1))&ʺ ʺ&IFERROR(INDEX($E$21:$K$21;;AGGREGATE(15;6;(COLUMN($E$21:$K$21)-COLUMN($E$21)+1)/($E22:$K22=LARGE($E22:$K22;1));2));ʺʺ)&ʺ ʺ&IFERROR(INDEX($E$21:$K$21;;AGGREGATE(15;6;(COLUMN($E$21:$K$21)-COLUMN($E$21)+1)/($E22:$K22=LARGE($E22:$K22;1));3));ʺʺ)&ʺ ʺ&IFERROR(INDEX($E$21:$K$21;;AGGREGATE(15;6;(COLUMN($E$21:$K$21)-COLUMN($E$21)+1)/($E22:$K22=LARGE($E22:$K22;1));4));ʺʺ)&ʺ ʺ&IFERROR(INDEX($E$21:$K$21;;AGGREGATE(15;6;(COLUMN($E$21:$K$21)-COLUMN($E$21)+1)/($E22:$K22=LARGE($E22:$K22;1));5));ʺʺ)&ʺ ʺ&IFERROR(INDEX($E$21:$K$21;;AGGREGATE(15;6;(COLUMN($E$21:$K$21)-COLUMN($E$21)+1)/($E22:$K22=LARGE($E22:$K22;1));6));ʺʺ);ʺʺ) Spero che qualcuno conosca il problema e la soluzione. Allego il file. Un saluto a tutti
    File Allegati File Allegati

  13. #13
    L'avatar di kroma
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    Lecce
    Messaggi
    23
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    0
    Ciao e tutti, sto cercando ancora di capire perché la formula non funziona in Google fogli. L'ho ridotta ed ho confrontato le seguenti formule:

    EXCEL =SE.ERRORE(INDICE($E$21:$K$21;;AGGREGA(15;6;(RIF.COLONNA($E$21:$K$21)-RIF.COLONNA($E$21)+1)/($E22:$K22=GRANDE($E22:$K22;1));1))
    GOOGLE FOGLI =IFERROR(INDEX($E$21:$K$21;;AGGREGATE(15;6;(COLUMN($E$21:$K$21)-COLUMN($E$21)+1)/($E22:$K22=LARGE($E22:$K22;1));1));"")

    Mi pare di capire che GOOGLE FOGLI non riconosce la funzione AGGREGATE (AGGREGA). Sbaglio? C'è una funzione o una formula alternativa?

  14. #14
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Ciao kroma
    Credo che google fogli non abbia la funzione AGGREGATE dovresti fare una formula matrice con la funzione =SMALL(IF....
    fammi sapere!

  15. #15
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Ok prova questa:
    i Italiano: (attenzione questa formula in excel è considerata una formula matrice e per essere attivata devi fare CTRL+SHIFT+ENTER

    =SE.ERRORE(INDICE($C$14:$I$14;;PICCOLO(SE($C15:$I15=MAX($C15:$I15);RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1);COLONNE($A1:A1)));"")

    in Inglese non so se questa formula deve essere attivata con CTRL+SHIFT+ENTER

    =IFERROR(INDEX($C$14:$I$14,,SMALL(IF($C15:$I15=MAX($C15:$I15),COLUMN($C$14:$I$14)-COLUMN($C$14)+1),COLUMNS($A1:A1))),"")

    fammi sapere! ciao

    EDIT
    kroma potrebbe esserti utile questo link per tradurre l formule in tutte le lingue di excel
    http://it.excel-translator.de/translator/

  16. #16
    L'avatar di kroma
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    Lecce
    Messaggi
    23
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    0
    Gerardo, finalmente sembra che questa stia girando anche su Google fogli (senza formula matrice). Proseguiamo un passo alla volta. Adesso vorrei ricostruire con queste funzioni la formula intera che in Excel mi consentiva di estrarre anche gli altri segni nell'ipotesi in cui ci trovavamo più valori MAX. La formula di pkrome59 che in Excel era OK era questa: =SE.ERRORE(INDICE($C$14:$I$14;;AGGREGA(15;6;(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1)/($C15:$I15=GRANDE($C15:$I15;1));1))&" "&SE.ERRORE(INDICE($C$14:$I$14;;AGGREGA(15;6;(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1)/($C15:$I15=GRANDE($C15:$I15;1));2));"")&" "&SE.ERRORE(INDICE($C$14:$I$14;;AGGREGA(15;6;(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1)/($C15:$I15=GRANDE($C15:$I15;1));3));"");"") .... Come posso sviluppare allo stesso modo la tua formula?

  17. #17
    L'avatar di pkrome59
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Reggio Calabria
    Età
    58
    Messaggi
    1188
    Versione Office
    Office 2013
    Likes ricevuti
    1198
    Likes dati
    2133
    Ciao kroma; la formula seguente:

    =SE.ERRORE(INDICE($C$14:$I$14;;PICCOLO(SE(($C15:$I15=GRANDE($C15:$I15;1));(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1));1))&" "&SE.ERRORE(INDICE($C$14:$I$14;;PICCOLO(SE(($C15:$I15=GRANDE($C15:$I15;1));(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1));2));"")&" "&SE.ERRORE(INDICE($C$14:$I$14;;PICCOLO(SE(($C15:$I15=GRANDE($C15:$I15;1));(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1));3));"");"")

    da incollare in B3, ricostruisce quella che tu hai evidenziato, e gestisce i "grandi", (naturalmente da tradurre in Inglese)

    Per quanto riguarda i "grandi-1":

    =SE.ERRORE(INDICE($C$14:$I$14;;PICCOLO(SE(($C15:$I15=GRANDE($C15:$I15;1)-1);(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1));1))&" "&SE.ERRORE(INDICE($C$14:$I$14;;PICCOLO(SE(($C15:$I15=GRANDE($C15:$I15;1)-1);(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1));2));"")&" "&SE.ERRORE(INDICE($C$14:$I$14;;PICCOLO(SE(($C15:$I15=GRANDE($C15:$I15;1)-1);(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1));3));"");"")

    In italiano entrambe da attivare con CTRL+SHIFT+ENTER


    Fa sapere.
    Ciao.
    File Allegati File Allegati

  18. #18
    L'avatar di kroma
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    Lecce
    Messaggi
    23
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    0
    Un saluto a tutti. La ultime 2 formule di pkrome59 rappresentavano nel mio caso la soluzione ideale ed anche dopo la trasformazione in inglese ha funzionato tutto alla grande. Ho ancora un problema con i "grandi -2". Ho elaborato la formula utilizzata per i "grandi -1" che con una piccola modifica funziona anche per i GRANDI -2, solo che in questo caso devo escludere dal conteggio le celle che hanno valore ZERO altrimenti, quando il valore PIU' GRANDE è uguale a 2, mi ritrovo tra i pronostici GRANDI -2 anche quelli non giocati (vedi celle N16;N17;N23). Non so se sono stato abbastanza chiaro. Allego il file SCHEDINA 4 dove in N15:N23 ho aggiunto celle e formule per i GRANDI -2
    File Allegati File Allegati

  19. #19
    L'avatar di pkrome59
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Reggio Calabria
    Età
    58
    Messaggi
    1188
    Versione Office
    Office 2013
    Likes ricevuti
    1198
    Likes dati
    2133
    Ciao kroma; la formula seguente:

    =SE.ERRORE(SE(GRANDE($C15:$I15;1)-2>0;INDICE($C$14:$I$14;;PICCOLO(SE(($C15:$I15=GRANDE($C15:$I15;1)-2);(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1));1));"")&" "&SE.ERRORE(SE(GRANDE($C15:$I15;1)-2>0;INDICE($C$14:$I$14;;PICCOLO(SE(($C15:$I15=GRANDE($C15:$I15;1)-2);(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1));2));"");"")&" "&SE.ERRORE(SE(GRANDE($C15:$I15;1)-2>0;INDICE($C$14:$I$14;;PICCOLO(SE(($C15:$I15=GRANDE($C15:$I15;1)-2);(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1));3));"");"")&" "&SE.ERRORE(SE(GRANDE($C15:$I15;1)-2>0;INDICE($C$14:$I$14;;PICCOLO(SE(($C15:$I15=GRANDE($C15:$I15;1)-2);(RIF.COLONNA($C$14:$I$14)-RIF.COLONNA($C$14)+1));4));"");"");"")

    dovrebbe risolvere il tuo problema.
    Allego il file di prova.
    Di nuovo ciao.
    File Allegati File Allegati

Discussioni Simili

  1. [Risolto] CONTA.SE con due valori nella stessa cella
    Di Silvio65 nel forum Domande su Excel in generale
    Risposte: 6
    Ultimo Messaggio: 16/03/17, 00:16
  2. Creazione Packing List - Dati Presenti su Altri Fogli ma nella Stessa Cartella
    Di Bauhaus nel forum Domande su Excel in generale
    Risposte: 2
    Ultimo Messaggio: 06/03/17, 00:12
  3. Creazione Packing List - Dati Presenti su Altri Fogli ma nella Stessa Cartella
    Di Bauhaus nel forum Domande su Excel VBA e MACRO
    Risposte: 2
    Ultimo Messaggio: 06/03/17, 00:12
  4. cercare i primi 10 valori piu alti di una colonna
    Di alex_drastic nel forum Domande su Excel in generale
    Risposte: 31
    Ultimo Messaggio: 04/02/17, 22:17
  5. Risposte: 2
    Ultimo Messaggio: 04/10/16, 19:49

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •