Risultati da 1 a 17 di 17

Discussione: Classifica Gare



  1. #1
    L'avatar di robynud
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Gardone Val Trompia
    Età
    45
    Messaggi
    155
    Versione Office
    Office 2016
    Likes ricevuti
    24
    Likes dati
    65

    Classifica Gare

    Salve a tutti,
    sto cercando una soluzione al mio problema spero che possiate aiutarmi.
    Nel mio caso devo stilare una classifica in base a delle gare disputate, ma ci sono alcune formule che non mi funzionano, in allegato ho messo il file di come è adesso la classifica e di come vorrei che fosse in realtà.
    File Allegati File Allegati
    Ultima modifica fatta da:Canapone; 05/07/17 alle 16:11

  2. #2

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4016
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Ciao Robynud,
    complimenti per l'esposizione (immagine,file allegato, prove fatte, risultato attuale e risultato voluto) :246:

    Per adesso ti propongo solo la formula da mettere nei vari fogli "Gara" nella cella E4 (da copiare poi in basso):

    =SE.ERRORE(SE((A4<>"")*(F4>=75/100);P4;"");"Nd")

    Per la classifica generale devo ancora controllare, ma so già che avrò qualche problema con la funzione INDIRETTO (in quanto immagino che i fogli "Gara" aumentino nel tempo...).

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  3. I seguenti utenti hanno dato un "Like"


  4. #3

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4016
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Ri-Ciao,
    allora, per non ricorrere anche al VBA solo per ottenere i riferimenti dei fogli in cui cercare, conviene aggiungere una cella (es. la Q4) dove scriverai il numero di gare da tenere in considerazione (e che corrisponderanno al numero di fogli "Gara"... nel tuo file dovresti scrivere 2).

    Lasciando stare le due tabella nel foglio Classifica (volendo la prima tabella la puoi nascondere), la prima riporterà i punteggi totali, mentre la seconda è la vera e propria classifica.

    Per la prima tabella (Punteggi Finali):

    cella D4:

    =MATR.SOMMA.PRODOTTO(SOMMA.SE(INDIRETTO("'Gara"&RIF.RIGA(INDIRETTO("1:"&$Q$4))&"'!B4:B13");$B4;INDIRETTO("'Gara"&RIF.RIGA(INDIRETTO("1:"&$Q$4))&"'!E4:E13")))

    cella E4:

    =MATR.SOMMA.PRODOTTO(CONTA.SE((INDIRETTO("'Gara"&RIF.RIGA(INDIRETTO("1:"&$Q$4))&"'!B4"));$B4))

    cella F4 (ho considerato "podio" le prime 3 posizioni):

    =MATR.SOMMA.PRODOTTO(CONTA.SE((INDIRETTO("'Gara"&RIF.RIGA(INDIRETTO("1:"&$Q$4))&"'!B4:B6"));$B4))

    cella G4:

    =MATR.SOMMA.PRODOTTO(CONTA.SE((INDIRETTO("'Gara"&RIF.RIGA(INDIRETTO("1:"&$Q$4))&"'!B4:B13"));$B4))

    Per la seconda tabella (Classifica):

    nella cella J4 inserisci questa formula matriciale (quindi da confermare con CTRL+MAIUSC+INVIO):

    =INDICE($B$4:$G$13;CONFRONTA(GRANDE($D$4:$D$13+RIF.RIGA($D$4:$D$13)/100;RIF.RIGA(A1));$D$4:$D$13+RIF.RIGA($D$4:$D$13)/100;0);RIF.COLONNA(A1))

    e dopo copia la cella J4 in basso e a destra per tutta la tabella.

    Ti lascio file allegato...
    File Allegati File Allegati

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  5. I seguenti 3 utenti hanno dato un "Like" a cromagno per questo post:


  6. #4
    L'avatar di robynud
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Gardone Val Trompia
    Età
    45
    Messaggi
    155
    Versione Office
    Office 2016
    Likes ricevuti
    24
    Likes dati
    65
    Grazie Cromagno per la risposta, è quasi perfetto ti chiedo solo un paio di cose non so se è possibile,
    volevo evitare di mettere la colonna Punteggi disponibili e se cera una formula come quella che ho usato per i nomi delle squaddre:

    Codice: 
    =SE(E(B5="Pippo");"Rossa";SE(E(B5="Paperino");"Bianca";SE(E(B5="Topolino");"Gialla";SE(E(B5="Paperina");"Bianca";SE(E(B5="Minni");"Gialla";SE(E(B5="Pluto");"Rossa";SE(E(B5="Paperon de Paperoni");"Verde";SE(E(B5="Archimede Pitagorico");"Blu";SE(E(B5="Pietro Gambadilegno");"Verde";SE(E(B5="Amelia");"Blu";""))))))))))
    in base al nome che trova mi mette il nome della squadra, avevo provato anche questa ma non mi funziona:

    Codice: 
    =SE((B22=1)*(C22>=75);50;SE(B22=2)*(C22>=75);46;"")
    non so se è possibile ci ho provato in tutti modi, ma non ci sono riuscito.
    Per quando riguarda la doppia classifica ne voglio mettere solo una, al limite per riordinarla metto una macro che parte e ordina ogni volta che accedo al foglio Classifica.

    Ultima cosa mi esce un errore di valore nelle percentuali invece che 0% e per quando riguardano le gare sono 10


    Spero di essere stato chiaro nella spiegazione, intanto ti rigrazio ancora per la risposta di prima!

    Ciao
    Ultima modifica fatta da:Canapone; 05/07/17 alle 16:13

  7. #5

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4016
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Non ho capito a cosa ti riferisci con "la colonna Punteggi disponibili" :256:

    Per la doppia tabella.... quindi vuoi lasciare solo la prima e nel caso ordini tu?
    Se è così elimina tranquillamente la seconda tabella (Classifica) perchè è la seconda che è dipendente dalla prima, non viceversa.

    Per il terzo punto... l'errore, controllerò.

    Se dovessi aver capito male, allega nuovamente il file riportando manualmente quello che vorresti.

    Ciao
    Ultima modifica fatta da:Canapone; 05/07/17 alle 16:12

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  8. #6

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4016
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Per l'errore, nella cella F4 puoi scrivere semplicemente :

    =SE.ERRORE(D4/$D$4;0)

    e copiare in basso.

    Non l'avevo corretto perchè ho visto che avevi già usato la funzione SE.ERRORE in altre formule.

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  9. I seguenti utenti hanno dato un "Like"


  10. #7
    L'avatar di robynud
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Gardone Val Trompia
    Età
    45
    Messaggi
    155
    Versione Office
    Office 2016
    Likes ricevuti
    24
    Likes dati
    65
    Nel senso che non volevo prendere il punteggio da assegnare dalla colonna P,

    lo avevo messo solo per per far vedere i punteggi da assegnare alla formula sempre se è possibile, ma farlo con una formula tipo quella che ho usato io per il nome delle squadre
    Ultima modifica fatta da:Canapone; 05/07/17 alle 16:13

  11. #8

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4016
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Citazione Originariamente Scritto da robynud Visualizza Messaggio
    nel senso che non volevo prendere il punteggio da assegnare dalla colonna P,



    lo avevo messo solo per per far vedere i punteggi da assegnare alla formula sempre se e possibile, ma farlo con una formula tipo quella che ho usato io per il nome delle squadre
    Per eliminare quella colonna, nella cella E4 metti questa formula e dopo copia in basso:

    =SE.ERRORE(SE((A4<>"")*(F4>=75/100);SCEGLI(A4;50;46;38;32;26;20;14;10;6;2);"");"Nd")

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  12. I seguenti 2 utenti hanno dato un "Like" a cromagno per questo post:


  13. #9
    L'avatar di robynud
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Gardone Val Trompia
    Età
    45
    Messaggi
    155
    Versione Office
    Office 2016
    Likes ricevuti
    24
    Likes dati
    65
    grazie ancora Cromagno cosi è perfetto, solo un ultima cosa volevo chiederti se conosci una formula un po piu corta o semplificata di quella che ho usato io per assegnare il nome in automatico alla squadra di appartenenza
    Ultima modifica fatta da:Canapone; 05/07/17 alle 16:13

  14. #10

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4016
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Senza colonne di appoggio la formula risulta lunga solo per via dei nomi da scrivere...

    Comunque potresti usare questa alternativa nella cella C4 (da copiare poi in basso):

    =SCEGLI(ARROTONDA.PER.ECC(CONFRONTA(B4;{"Pippo"."Pluto"."Paperino"."Paperina"."Topolino"."Minni"."Paperon de Paperoni"."Pietro Gambadilegno"."Archimede Pitagorico"."Amelia"};0)/2;0);"Rossa";"Bianca";"Gialla";"Verde";"Blu")

    Se queste due liste le mettessi all'interno di "nomi definiti", la formula sarebbe molto più corta.

    N.B.
    I separatori (per riga e colonna) delle "costanti di matrici" non sono uguali per tutte le versioni di excel (mi riferisco ad esempio a excel 2003)...

    Dovrebbero essere...
    Da excel 2010 in poi:
    matrice orizzontale: ={1\2\3\4\5}
    matrice verticale: ={1.2.3.4.5}

    Da excel 2007 e precedenti:
    matrice orizzontale: ={1;2;3;4;5}
    matrice verticale: ={1\2\3\4\5}
    Ultima modifica fatta da:Canapone; 05/07/17 alle 16:14

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  15. I seguenti utenti hanno dato un "Like"


  16. #11
    L'avatar di robynud
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Gardone Val Trompia
    Età
    45
    Messaggi
    155
    Versione Office
    Office 2016
    Likes ricevuti
    24
    Likes dati
    65
    Grazie infinite, adesso è perfetto, effettivamente se la lista è molto lunga, è meglio fare una lista separata e nasconderla, comunque gia cosi è gia piu corta.
    Ultima modifica fatta da:Canapone; 05/07/17 alle 16:14

  17. #12

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4016
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Ciao robynud,
    Se hai risolto il problema, segna questa discussione come "RISOLTO".
    Vai sul menù "Strumenti Discussione" (all'inizio del thread) e scegli la voce ""Segna questo thread come risolto...".
    Ultima modifica fatta da:Canapone; 05/07/17 alle 16:14

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  18. I seguenti utenti hanno dato un "Like"


  19. #13
    L'avatar di robynud
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Gardone Val Trompia
    Età
    45
    Messaggi
    155
    Versione Office
    Office 2016
    Likes ricevuti
    24
    Likes dati
    65
    Ok, lo faccio subito e allego anche il file finale con un po di indicazioni se dovesse servire a qualcun altro

    File Allegati File Allegati

  20. I seguenti utenti hanno dato un "Like"


  21. #14
    L'avatar di robynud
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Gardone Val Trompia
    Età
    45
    Messaggi
    155
    Versione Office
    Office 2016
    Likes ricevuti
    24
    Likes dati
    65
    Scusa cromagno ma mi sono accorto solo adesso di un piccolo errore se si puo chiamare tale, l'uscita della scritta n/d se non trova nessun nome, vorrei che non uscisse nulla, o provato a mettere:

    Codice: 
    SE.ERRORE
    ma mi dà errore di formula
    File Allegati File Allegati
    Ultima modifica fatta da:Canapone; 05/07/17 alle 16:15

  22. #15

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4016
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Hai scritto cosi nella cella C4 (da copiare poi in basso) ??? :

    =SE.ERRORE(SCEGLI(ARROTONDA.PER.ECC(CONFRONTA(B4;{"Pippo"."Pluto"."Paperino"."Paperina"."Topolino"."Minni"."Paperon de Paperoni"."Pietro Gambadilegno"."Archimede Pitagorico"."Amelia"};0)/2;0);"Rossa";"Bianca";"Gialla";"Verde";"Blu");"")
    File Allegati File Allegati
    Ultima modifica fatta da:Canapone; 05/07/17 alle 16:15

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  23. I seguenti 2 utenti hanno dato un "Like" a cromagno per questo post:


  24. #16
    L'avatar di robynud
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Gardone Val Trompia
    Età
    45
    Messaggi
    155
    Versione Office
    Office 2016
    Likes ricevuti
    24
    Likes dati
    65
    Sorry cromagno era una mia disattenzione! Non mettevo il ; davanti alle virgolette in fondo alla formula, grazie ancora per il tuo tempo speso
    Ultima modifica fatta da:Canapone; 05/07/17 alle 16:15

  25. #17

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7106
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2059
    Likes dati
    1296
    Edit:
    Allora possiamo considerare la discussione risolta. :90:
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

Discussioni Simili

  1. Estrapolare una classifica di categoria da una classifica generale
    Di Albyspace nel forum Domande su Excel in generale
    Risposte: 6
    Ultimo Messaggio: 29/09/16, 00:54
  2. Gare di tiro a segno - errore nelle classifiche
    Di Nardecchia nel forum Domande su Excel in generale
    Risposte: 16
    Ultimo Messaggio: 23/07/16, 12:00
  3. Trova gare
    Di AlexD nel forum Domande su Excel in generale
    Risposte: 15
    Ultimo Messaggio: 13/11/15, 22:06
  4. Classifica
    Di Manu nel forum Domande su Excel in generale
    Risposte: 4
    Ultimo Messaggio: 22/10/15, 14:37
  5. Classifica
    Di Jackmeda nel forum Domande su Excel in generale
    Risposte: 4
    Ultimo Messaggio: 18/09/15, 17:35

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •