Risultati da 1 a 20 di 20

Discussione: Somma se in presenza di dati univoci



  1. #1
    L'avatar di G.Bove
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Milano
    Età
    51
    Messaggi
    870
    Versione Office
    2010
    Likes ricevuti
    24
    Likes dati
    186

    Somma se in presenza di dati univoci

    Ciao a tutti.
    Vorrei calcolare il numero univoco di impianti funzionanti per operatore in un giorno definito e ottenerne anche il subtotale.

    Spiegazioni più chiare (spero!!) all'interno del file (https://www.dropbox.com/s/bqj5doeh5v...orum.xlsm?dl=0) al foglio "DB_addetti"

    Ho provato ad usare per il calcolo degli impianti funzionanti:
    Codice: 
    =CONTA.PIÙ.SE(data1!$A:$K;Legenda!$B$56;data1!$A:$K;DB_addetti!B5)
    ma sbaglio qualcosa. Identico risultato negativo anche al foglio P3 dove mi sono cimentato con una tabella pivot.

    PS E' possibile che il foglio di lavoro "data1" attualmente compreso nel file possa poi diventare un collegamento esterno.

    Grazie in anticipo
    Gene

  2. #2
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1125
    Ciao G.Bove
    giusto per capire
    ma perchè il il primo risultato dovrebbe essere 1 (uno) quando ad esempio in questo screen-shot puoi vedere che pippo sono 3 alla data 29/01/2016 e gli impianti sono 2? forse non ho capito bene la domanda..
    altra domanda la data inizio e data fine è sempre la stessa?

    Ciao


  3. #3
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1652
    Versione Office
    2010 PC
    Likes ricevuti
    889
    Likes dati
    183
    ciao, la risposta alla prima domanda potrebbe essere:
    =SOMMA(--VAL.NUMERO(CONFRONTA(RIF.RIGA(data1!$A$2:$A$11605)-1;SE((data1!$G$2:$G$11605=$C$3)*(data1!$I$2:$I$11605=B5);CONFRONTA(data1!$K$2:$K$11605;data1!$K$2:$K$11605;0));0)))
    Matriciale!!
    ma è un mattone che rallenta il calcolo, quì Gerardo può mettere in pratica la velocità di FREQUENZA().

    inoltre , la data (29/01/2016) l'ho scritta in C3, (non sono riuscito a trovare la data della casella combinata)

    se l'ho adattata bene, la formula con Frequenza(), dovrebbe essere:
    =SOMMA(SE(FREQUENZA(SE((data1!$G$2:$G$11605=$C$3)*(data1!$I$2:$I$11605=B5);CONFRONTA(data1!$K$2:$K$11605;data1!$K$2:$K$11605;0);"");SE((data1!$G$2:$G$11605=$C$3)*(data1!$I$2:$I$11605=B5);CONFRONTA(data1!$K$2:$K$11605;data1!$K$2:$K$11605;0);""))>0;1))


    vedete voi se c'è differenza di velocità, io non l'ho capito


    edit
    facciamola completa, per il subtotale, dovrebbe essere:
    =SOMMA(SE(FREQUENZA(SE((data1!$G$2:$G$11605=$C$3);CONFRONTA(data1!$K$2:$K$11605;data1!$K$2:$K$11605;0);"");SE((data1!$G$2:$G$11605=$C$3);CONFRONTA(data1!$K$2:$K$11605;data1!$K$2:$K$11605;0);""))>0;1))
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  4. I seguenti 3 utenti hanno dato un "Like" a ninai per questo post:


  5. #4
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1125
    Citazione Originariamente Scritto da ninai Visualizza Messaggio
    quì Gerardo può mettere in pratica la velocità di FREQUENZA().
    Ciao Santo!
    volevo provarci ma ci sono alcune cose che non ho capito che ho evidenziato nel post #2 e poi verificare se si riesce a fare con il frequenza
    =SOMMA(SE(FREQUENZA(SE(......chi? cosa?

  6. #5
    L'avatar di Gianfranco55
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Vicenza
    Età
    62
    Messaggi
    2065
    Versione Office
    2016
    Likes ricevuti
    551
    Likes dati
    116
    ciao
    Gerardo e Ninai

    Gerardo mi permetto di dirti che le macchine o impianti sono nel foglio
    DATA1 nella colonna K
    e sono da confrontare con i nomi degli operatori in una determinata data.

    ciao

  7. #6
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1125
    @ninai prova questa formula!! :171:

    @Gianfranco adesso è più chiaro grazie!

    @Bove
    visto che dovevo saltare da un foglio all'altro per fare le formule, ho preferito lavorare con i nomi defniti,(attenzione ho creato dei nomi definiti nuovi perche quelli precedenti erano simili ma facevano riferimento ad altri range)

    dove il range:

    =data1!$I$2:$I$1160 corrisponde a operatore
    =data1!$G$2:$G$11605 corrisponde a data_fine
    =data1!$K$2:$K$11605 corrisponde a cucitrice
    attenzione usare i nomi definiti che finiscono con "e
    " al singolare perchè quelli che finiscono con il plurale fanno riferimento ad altri intervalli che aveva creato prima Bove

    da confermare con CTRL+SHIFT+ENTER
    =SOMMA(SE(FREQUENZA(SE(cucitrice<>"";SE(operatore=B5;SE(data_fine=$C$3;CONFRONTA(cucitrice;cucitrice;0))));RIF.RIGA(Cucitrice)-RIF.RIGA(data1!$K$2)+1);1))

    PS per fare svelto ho inserito a mano la data in C3 senza usare la combo box
    fatemi sapere!

    https://www.dropbox.com/s/eu8ujauee7...ardo.xlsm?dl=0
    Ultima modifica fatta da:Gerardo Zuccalà; 22/02/16 alle 22:39

  8. I seguenti utenti hanno dato un "Like"


  9. #7
    L'avatar di G.Bove
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Milano
    Età
    51
    Messaggi
    870
    Versione Office
    2010
    Likes ricevuti
    24
    Likes dati
    186
    Ciao e grazie a tutti per la velocità ed efficacia :97:.
    Nei prossimi giorni farò delle prove e vi faccio sapere.
    Uno dei test riguarderà il foglio "data1". Infatti quest'ultimo si popola tutti i giorni e non sò se i nomi definiti accettano di avere solo l'indicazione della colonna. Per esempio: operatore=data1!$I$2:$I$1160 può diventare =data1!$I:$I e funzionare lo stesso?

    A presto
    Gene

    PS in ogni caso mi piacerebbe comunque se qualcuno (esempio :@Pitagora -> esperto di pivot) mi aiutasse a capire come ottenere il risultato anche usando la tabella pivot creata in P3.

  10. #8
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1125
    : operatore=data1!$I$2:$I$1160 può diventare =data1!$I:$I e funzionare lo stesso?
    Ciao grazie per il tuo riscontro positivo, comunque la risposta è si, come ho spiegato nel lost #6 ho voluto lavorare con la definizione dei nomi per evitare di saltare da un foglio all' altro per selezionare gli intervalli, infatti con il sistema della definizione dei nomi è molto più semplice e robusto perche quando scrivo la formula incollo il nome con il tasto F3 ed quindi non ci sono margini di errore, comunque se preferisci selezionare l'intervallo è la stessa cosa
    Ciao e alla prossima

  11. #9
    L'avatar di G.Bove
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Milano
    Età
    51
    Messaggi
    870
    Versione Office
    2010
    Likes ricevuti
    24
    Likes dati
    186
    Ciao Gerardo,
    provo a spiegarmi meglio.
    Ragionavo sulla necessità di lasciare solo i riferimenti colonna perchè per quelle che sono le mie limitate conoscenze excel, credo che nel momento in cui nel foglio di lavoro "data1" si aggiungono altri scarichi e quindi le righe supereranno il valore attuale di 11605, le formule resteranno "ancorate" a quanto impostogli (es. =data1!$G$2:$G$11605 corrisponde a data_fine ).
    E' corretto quanto affermo?

    Gene

  12. #10
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1125
    Ok per cui hai bisogno delle formule che si adattano ad intervalli che si espandono, e ci sono diversi modi per aggirare il problema
    1)inserire una formula dinamica con la funzione SCARTO all'interno del box del nome definito

    2) abbandonare il metodo dei nomi definiti e trasformare l' intervallo del foglio in "tabella" (CTRL+T) in questo modo le formule si adatteranno automaticamente al range espanso

    3) correggere i riferimenti delle formule fino ad un numero di celle che soddisfa le tue esigenze esempio =data1!$G$2:$G$10000000

    Provaci e fammi sapere!!

  13. #11
    L'avatar di G.Bove
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Milano
    Età
    51
    Messaggi
    870
    Versione Office
    2010
    Likes ricevuti
    24
    Likes dati
    186
    Ciao Gerardo,
    vorrei sviluppare utilizzando il consiglio del punto 1 quindi il nome definito diventerà:
    Codice: 
    =SOMMA(SCARTO(data1!$G$2:$G$11605))
    Corretto?

    Grazie
    Gene

  14. #12
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1125
    Ciao GBove
    vorrei sviluppare utilizzando il consiglio del punto 1
    sicuramente hai scelto il metodo più stabile e robusto
    questa volta anzichè farti trovare il file pronto vorrei vedere se riesci ad intervenire da solo
    queste sono le formule dinamiche che devi inserire nei vari box dei nomi
    vai in >formule>gestioni nomi>doppio click su nome>>e nel campo riferito a inserisci le formule sottostante

    per il nome Cucitrice:
    =SCARTO(data1!$K$2;;;CONTA.VALORI(data1!$K$2:$K$1000000))

    per il nome data_fine:
    =SCARTO(data1!$G$2;;;CONTA.VALORI(data1!$G$2:$G$1000000))

    Per il nome operatore:
    =SCARTO(data1!$I$2;;;CONTA.VALORI(data1!$I$2:$I$1000000))

    fammi sapere se hai problemi!

  15. #13
    L'avatar di G.Bove
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Milano
    Età
    51
    Messaggi
    870
    Versione Office
    2010
    Likes ricevuti
    24
    Likes dati
    186
    Ciao Gerardo,
    ovviamente con le tue spiegazioni era impossibile non riuscirci:28:.
    Mentre la formula per il calcolo del subtotale non "collabora". (https://www.dropbox.com/s/btrb2pr4lo...lsm?dl=0)...da un valore non corretto o in alternativa l'errore VALORE.

    Basta solo la dritta..il lavoro sporco lo faccio io...:50:

    Grazie
    Gene

  16. #14
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1125
    Ciao GBove
    mi fa piacere che con la definizione dei nomi hai risolto gli intervalli dinamici
    G.Bove abituati a fare una domanda alla volta, per quest'ultima domanda prova a iniziare una nuova discussione nuova perchè questo è una cosa completamente diversa e quindi la tua domanda potrebbe essere non vista
    comunque io metterei risolto a questa discussione e ne aprirei un'altra.
    Ciao

  17. #15
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1652
    Versione Office
    2010 PC
    Likes ricevuti
    889
    Likes dati
    183
    ciao a tutti

    purtroppo non ho più seguito attentamente ma se non sbaglio, le formule da me proposte nel post #3, funzionano tutte, compresa quella per il subtotale, che adesso, con la definizione dei nomi e lo spostamento della date in B3, diventa:
    =SOMMA(SE(FREQUENZA(SE((data_fine=$B$3);CONFRONTA(cucitrice;cucitrice;0);"");SE((data_fine=$B$3);CONFRONTA(cucitrice;cucitrice;0);""))>0;1))
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  18. #16
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1652
    Versione Office
    2010 PC
    Likes ricevuti
    889
    Likes dati
    183
    oppure per renderla conforme alle altre:
    =SOMMA(SE(FREQUENZA(SE(data_fine=$B$3;CONFRONTA(cucitrice;cucitrice;0));RIF.RIGA(cucitrice)-RIF.RIGA(data1!$K$2)+1);1))
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  19. #17
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1125
    Citazione Originariamente Scritto da ninai Visualizza Messaggio
    oppure per renderla conforme alle altre:
    =SOMMA(SE(FREQUENZA(SE(data_fine=$B$3;CONFRONTA(cucitrice;cucitrice;0));RIF.RIGA(cucitrice)-RIF.RIGA(data1!$K$2)+1);1))

    Ciao ninai, la tua formula è molto simile a quella mia del post #6 e noto con piacere che stai iniziando ad usare il FREQUENZA:255:
    comunque la tua formula hai una condizione in meno cioè l'operatore che io ho segnato in rosso,
    comunque non ho ancora capito l discorso del SUBTOTALE... aiuto!!

    =SOMMA(SE(FREQUENZA(SE(cucitrice<>"";SE(operatore=B5;SE(data_fine=$C$3;CONFRONTA(cucitrice;cucitrice;0))));RIF.RIGA(Cucitrice)-RIF.RIGA(data1!$K$2)+1);1))

  20. #18
    L'avatar di G.Bove
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Milano
    Età
    51
    Messaggi
    870
    Versione Office
    2010
    Likes ricevuti
    24
    Likes dati
    186
    Ciao a tutti

    @Ninai
    Confermo che per il subtotale ho usato la tua formula ma il risultato non corrisponde a quello atteso ( 1 rispetto al corretto 10 ossia c11+c12+c13+c14+c15+c16+c18+c19+c21+c22 per il 29/01/2016).

    @ Gerardo
    Per subtotale intendo e ricerco il numero degli impianti funzionanti nella giornata selezionata quindi è indipendente dagli operatori.

    Gene

  21. #19
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1652
    Versione Office
    2010 PC
    Likes ricevuti
    889
    Likes dati
    183
    Citazione Originariamente Scritto da G.Bove Visualizza Messaggio
    ......... il risultato non corrisponde a quello atteso ( 1 rispetto al corretto 10 ossia c11+c12+c13+c14+c15+c16+c18+c19+c21+c22 per il 29/01/2016).......
    ciao
    a me, il risultato viene 10....., ma l'hai confermata matriciale?????



    Gerardo
    ho ritenuto ininfluente l'operatore, in base all'univocità dei dati, infatti il risultato è identico

    allego link
    https://www.dropbox.com/s/bmufwwukyd...inai.xlsm?dl=0
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  22. #20
    L'avatar di G.Bove
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Milano
    Età
    51
    Messaggi
    870
    Versione Office
    2010
    Likes ricevuti
    24
    Likes dati
    186
    @ Ninai

    Azz...domani sono in ufficio e controllo.

    Ma dal tuo cilindro non riesci a tirarne fuori una non matriciale?

    A presto per la chiusura del thread.

    Grazie ancora.
    Gene

Discussioni Simili

  1. Copiare dati univoci su altro foglio
    Di totorom1 nel forum Domande su Excel in generale
    Risposte: 11
    Ultimo Messaggio: 20/02/17, 16:20
  2. Definire area su cui cercare i dati univoci
    Di Vincenzo Damiani nel forum Domande su Excel VBA e MACRO
    Risposte: 28
    Ultimo Messaggio: 14/03/16, 19:03
  3. Combobox a cascata dati univoci
    Di nessi nel forum Domande su Excel VBA e MACRO
    Risposte: 9
    Ultimo Messaggio: 29/12/15, 00:12
  4. [Risolto] dati univoci tramite funzione
    Di annnndrea nel forum Domande su Excel in generale
    Risposte: 16
    Ultimo Messaggio: 15/10/15, 22:19
  5. Convalida dati da elenco per dati univoci dinamica
    Di tsunami1978 nel forum Domande su Excel in generale
    Risposte: 8
    Ultimo Messaggio: 27/08/15, 00:52

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •