Risultati da 1 a 14 di 14

Discussione: copiare celle con due condizioni



  1. #1
    L'avatar di G.Bove
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Milano
    Età
    52
    Messaggi
    907
    Versione Office
    2010
    Likes ricevuti
    25
    Likes dati
    200

    copiare celle con due condizioni

    Ciao a tutti,
    vorrei riportare nel foglio "calcoli" (https://www.dropbox.com/s/q48o91zf1z...orum.xlsx?dl=0 ),i valori presenti nel foglio1 ma tenendo conto di due condizioni ->data (F1) e ripasso (K1).

    Ho usato con scarso risultato:
    Codice: 
    =INDICE(Foglio1!$A$1:$Q$1000000;CONFRONTA(1;INDICE((calcoli!$F$1=Foglio1!$B$1:$B$1000000)*(calcoli!$K$1=Foglio1!$A$1:$A$1000000););0))
    PS: Come d'abitudine evidenzio che il foglio1 sarà implementato giornalmente e nel file definitivo ho previsto lo spostamento in un file esterno.

    Grazie in anticipo
    Gene

  2. #2

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    54
    Messaggi
    9963
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2567
    Likes dati
    1546
    Ciao, non entro nel merito della formula, ma prova così:

    =INDICE(Foglio1!$A$1:$Q$1000000;CONFRONTA(1;(calcoli!$F$1=Foglio1!$B$1:$B$1000000)*(calcoli!$K$1=Foglio1!$A$1:$A$1000000););0)
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  3. #3
    L'avatar di G.Bove
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Milano
    Età
    52
    Messaggi
    907
    Versione Office
    2010
    Likes ricevuti
    25
    Likes dati
    200
    Ciao Ges,
    mi dà N/D.
    In ogni caso sapete che le mie conoscenze stanno crescendo grazie a voi quindi se ritieni che il risultato sia raggiungibile in altro modo sono a disposizione per imparare.

    Grazie
    Gene

  4. #4

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    54
    Messaggi
    9963
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2567
    Likes dati
    1546
    Quella che ho scritto io è matriciale, quindi CTRL+SHIFT+INVIO la tua avendo il doppio INDICE no ... che sembra anche corretta.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  5. #5
    L'avatar di G.Bove
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Milano
    Età
    52
    Messaggi
    907
    Versione Office
    2010
    Likes ricevuti
    25
    Likes dati
    200
    Ovviamente la tua funziona ma riesci a capire perchè la mia non và?

    PS Domanda da nerd ma le formule matriciali vanno riattivate (CTRL+SHIFT+INVIO) ad ogni apertura del file?

  6. #6
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    50
    Messaggi
    5386
    Versione Office
    office 365/2016
    Likes ricevuti
    1272
    Likes dati
    1339
    Ciao a tutti
    come al solito con excel non c'è mai una sola soluzione!!
    da confermare (CTRL+SHIFT+INVIO)

    =SE.ERRORE(INDICE(Foglio1!A$2:A$103;PICCOLO(SE((Foglio1!$A$2:$A$103=calcoli!$K$1)*(Foglio1!$B$2:$B$103=calcoli!$F$1);RIF.RIGA(Foglio1!$A$2:$A$103)-RIF.RIGA(Foglio1!$A$2)+1);RIGHE($A$3:A3)));"")

    GBove scrive:
    PS Domanda da nerd ma le formule matriciali vanno riattivate (CTRL+SHIFT+INVIO)
    rispondo io per Ges
    Assolutamnete no, le formule matricili o volgarmente "matrici" vanno riconfermate solo quando la cella contenete la formula viene messa in modalità di modifica esempio quando si fa Doppio click sulla cella oppure si fa F2 dal tasto funzione
    ciao
    Se non lo sai spiegare in modo semplice, non l'hai capito abbastanza bene Cit. Einstein

  7. #7
    L'avatar di G.Bove
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Milano
    Età
    52
    Messaggi
    907
    Versione Office
    2010
    Likes ricevuti
    25
    Likes dati
    200
    Grazie a tutti.

    Resta solo il mistero sul non funzionamento della formula non matriciale.

    Gene

  8. #8
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    50
    Messaggi
    5386
    Versione Office
    office 365/2016
    Likes ricevuti
    1272
    Likes dati
    1339
    Citazione Originariamente Scritto da G.Bove Visualizza Messaggio
    Grazie a tutti.

    Resta solo il mistero sul non funzionamento della formula non matriciale.

    Gene
    se tu avessi avuto la versione di excel 2010 e superiori avremmo potuto usare la funzione AGGREGA che sopporta le matrici
    ciao
    Se non lo sai spiegare in modo semplice, non l'hai capito abbastanza bene Cit. Einstein

  9. #9
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1124
    Versione Office
    2010 su Win
    Likes ricevuti
    642
    Likes dati
    224
    Ciao a tutti

    la formula

    =INDICE(Foglio1!$A$1:$Q$1000000;CONFRONTA(1;INDICE((Foglio1!$B$1:$B$1000000=F1)*(Foglio1!$A$1:$A$1000000=K1););0))

    richiederebbe per funzionare l'indicazione della colonna che vuoi interrogare, oltre che la riga che ottieni dal confronta

    =INDICE(Foglio1!$A$1:$A$1000000;CONFRONTA(1;INDICE((Foglio1!$B$1:$B$1000000=F1)*(Foglio1!$A$1:$A$1000000=K1););0))

    oppure

    =INDICE(Foglio1!$A$1:$Q$1000000;CONFRONTA(1;INDICE((Foglio1!$B$1:$B$1000000=F1)*(Foglio1!$A$1:$A$1000000=K1););0);1)

    La forma matriciale non serve, il secondo INDICE simula il control+maiusc+invio: sono d'accordo con Ges, che saluto.

    Spero sia d'aiuto

  10. #10
    L'avatar di G.Bove
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Milano
    Età
    52
    Messaggi
    907
    Versione Office
    2010
    Likes ricevuti
    25
    Likes dati
    200
    Ciao,
    provate entrambe le opzioni ma quando le trascino non copiano le altre celle.[IMG][/IMG]
    Ho provato anche a modificare la formula bloccando i campi di selezione:
    Codice: 
    =INDICE(Foglio1!$A$1:$Q$1000000;CONFRONTA(1;INDICE((Foglio1!$B$1:$B$1000000=$F$1)*(Foglio1!$A$1:$A$1000000=$K$1););0);1)
    Resto in attesa di eventuale dritta.

    @Gerardo
    In ogni caso per imparare: come la formuleresti con AGGREGA di excel2010 ?

    Gene

  11. #11
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1124
    Versione Office
    2010 su Win
    Likes ricevuti
    642
    Likes dati
    224
    Ciao,

    Prova a sostituire ultimo 1 della formula con

    Rif.colonna(a$1)

    =INDICE(Foglio1!$A$1:$Q$1000000;CONFRONTA(1;INDICE((Foglio1!$B$1:$B$1000000=$F$1)*(Foglio1!$A$1:$A$1000000=$K$1););0);Rif.colonna(A$1))


    oppure fai leggere all'indice una colonna, ma lasciala libera (leva i $ a sinistra)

    =INDICE(Foglio1!a$1:a$1000000;CONFRONTA(1;INDICE((Foglio1!$B$1:$B$1000000=$F$1)*(Foglio1!$A$1:$A$1000000=$K$1););0))Spero sia d'aiuto


    saluti

  12. #12
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    50
    Messaggi
    5386
    Versione Office
    office 365/2016
    Likes ricevuti
    1272
    Likes dati
    1339
    GBove scrive:
    @Gerardo
    In ogni caso per imparare: come la formuleresti con AGGREGA di excel2010 ?
    =SE.ERRORE(INDICE(Foglio1!A$2:A$103;AGGREGA(15;6;(RIF.RIGA(Foglio1!$A$2:$A$103)-RIF.RIGA(Foglio1!$A$2)+1)/((Foglio1!$A$2:$A$103=calcoli!$K$1)*(Foglio1!$B$2:$B$103=calcoli!$F$1));RIGHE($A$3:A3)));"")

    PS hai provato la formula nel post#6?

    fammi sapere!
    Se non lo sai spiegare in modo semplice, non l'hai capito abbastanza bene Cit. Einstein

  13. #13
    L'avatar di G.Bove
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Milano
    Età
    52
    Messaggi
    907
    Versione Office
    2010
    Likes ricevuti
    25
    Likes dati
    200
    Confermo che le formule dei post #2 (Ges) - post #6 (Gerardo) - post #11 (Canapone) funzionano tutte.
    La discriminante dopo alcune ore di test sembra la velocità esecutiva soprattutto quelle di Canapone richiedono un discreto tempo per elaborare la richiesta.

    Grazie ancora a tutti :97:e alla prossima.

    Gene

  14. #14
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1124
    Versione Office
    2010 su Win
    Likes ricevuti
    642
    Likes dati
    224
    Ciao,

    ottimo. Per confrontare le formule fai attenzione ad usare gli stessi riferimenti.

    Far elaborare ad una formula un milione o un centinaio di righe incide nella velocità di calcolo.

    Saluti
    Ultima modifica fatta da:Canapone; 28/02/16 alle 09:45

Discussioni Simili

  1. Risposte: 30
    Ultimo Messaggio: 03/01/17, 06:34
  2. Sommare celle in base a condizioni nella stessa riga
    Di Bubamara nel forum Domande su Excel in generale
    Risposte: 13
    Ultimo Messaggio: 23/11/16, 13:18
  3. Risposte: 6
    Ultimo Messaggio: 23/10/16, 17:02
  4. Somma di celle con condizioni multiple
    Di mdf91 nel forum Domande su Excel in generale
    Risposte: 15
    Ultimo Messaggio: 31/08/16, 18:55
  5. Prefiltrare celle con due condizioni
    Di G.Bove nel forum Domande su Excel in generale
    Risposte: 11
    Ultimo Messaggio: 05/03/16, 19:59

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •