Risultati da 1 a 5 di 5

Discussione: Calcolo tempo fermo macchina in data specifica



  1. #1
    L'avatar di pancry03
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    busto arsizio
    Messaggi
    2
    Versione Office
    office 2013
    Likes ricevuti
    0
    Likes dati
    1

    Calcolo tempo fermo macchina in data specifica

    Ciao a tutti,
    come potete vedere nell'allegato, ho una tabella che riassume data e ora di avvio e fermata di alcune macchine e che calcola la durata della lavorazione.
    Nella tabellina a fianco devo calcolare per ogni macchina il tempo di fermo ma relativo solo alla data scritta nella prima riga. Non so proprio da dove partire, zero idee.
    Grazie in anticipo per l'aiuto.
    File Allegati File Allegati

  2. #2

    L'avatar di Rubik72
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Cosenza
    Età
    45
    Messaggi
    2808
    Versione Office
    Excel 2013
    Likes ricevuti
    1020
    Likes dati
    979

    Re: Calcolo tempo fermo macchina in data specifica

    Se ho capito bene prova con questa funzione matriciale (da inserire con CTRL + SHIFT + ENTER):

    K3=SOMMA(($B$3:$B$14=$O$1)*($A$3:$A$14=K2)*$F$3:$F$14)

    e ricopia a destra

  3. #3
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126

    Re: Calcolo tempo fermo macchina in data specifica

    Ciao a tutti
    Come al solito capisco il topic solo dopo che qualcun'altro ha fatto le formule
    infatti nella forumla di rubik (che saluto) mi sono limitato a togliere lo stato matriciale

    =MATR.SOMMA.PRODOTTO(($B$3:$B$14=$O$1)*($A$3:$A$14=K2)*$F$3:$F$14)

    ciao a tutti

  4. #4
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1665
    Versione Office
    2010 PC
    Likes ricevuti
    892
    Likes dati
    184

    Re: Calcolo tempo fermo macchina in data specifica

    ciao
    il problema si presta a diverse interpretazioni, ecco la mia:

    il fermo potrebbe calcolarsi, detraendo alle 24 ore, le ore di attività della macchina in quel giorno, pertanto:
    sommo:
    l'attività con inizio e fine all'interno della stessa giornata:
    =MATR.SOMMA.PRODOTTO(($A$3:$A$14=K$2)*($B$3:$B$14=$O$1)*($D$3:$D$14=$O$1)*($E$3:$E$14-$C$3:$C$14))
    l'attività con inizio il giorno precedente e fine nella giornata in esame:
    =MATR.SOMMA.PRODOTTO(($A$3:$A$14=K$2)*($B$3:$B$14=$O$1-1)*($D$3:$D$14=$O$1)*$E$3:$E$14)
    l'attività con inizio nella giornata in esame e fine il giorno dopo:
    =MATR.SOMMA.PRODOTTO(($A$3:$A$14=K$2)*($B$3:$B$14=$O$1)*($D$3:$D$14=$O$1+1)*(1-$C$3:$C$14))

    a questo punto potrei sottrarre ad 1 (24 ore) la somma delle tre formule.
    =1-MATR.SOMMA.PRODOTTO(($A$3:$A$14=K$2)*($B$3:$B$14=$O$1)*($D$3:$D$14=$O$1)*($E$3:$E$14-$C$3:$C$14))-MATR.SOMMA.PRODOTTO(($A$3:$A$14=K$2)*($B$3:$B$14=$O$1-1)*($D$3:$D$14=$O$1)*$E$3:$E$14)-MATR.SOMMA.PRODOTTO(($A$3:$A$14=K$2)*($B$3:$B$14=$O$1)*($D$3:$D$14=$O$1+1)*(1-$C$3:$C$14))

    la formula è da testare, ed il risultato è in formato orario.

    ma restano tanti dubbi su varie casistiche, esempio:
    può verificarsi che inizi un giorno e finisca 2, 3 o più giorni dopo??
    il formato deve essere con minuti sessagesimali e centesimali??
    Testa e fammi sapere

    NB
    ovviamente, la formula va in K3 e trascinata a destra
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  5. I seguenti 3 utenti hanno dato un "Like" a ninai per questo post:


  6. #5
    L'avatar di pancry03
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    busto arsizio
    Messaggi
    2
    Versione Office
    office 2013
    Likes ricevuti
    0
    Likes dati
    1

    Re: Calcolo tempo fermo macchina in data specifica

    =1-MATR.SOMMA.PRODOTTO(($A$3:$A$14=K$2)*($B$3:$B$14=$O$1)*($D$3:$D$14=$O$1)*($E$3:$E$14-$C$3:$C$14))-MATR.SOMMA.PRODOTTO(($A$3:$A$14=K$2)*($B$3:$B$14=$O$1-1)*($D$3:$D$14=$O$1)*$E$3:$E$14)-MATR.SOMMA.PRODOTTO(($A$3:$A$14=K$2)*($B$3:$B$14=$O$1)*($D$3:$D$14=$O$1+1)*(1-$C$3:$C$14))

    la formula è da testare, ed il risultato è in formato orario.

    ma restano tanti dubbi su varie casistiche, esempio:
    può verificarsi che inizi un giorno e finisca 2, 3 o più giorni dopo??
    il formato deve essere con minuti sessagesimali e centesimali??
    Eccoci,
    la soluzione di Ninai testata sembra la più completa. Effettivamente non sono stato chiaro su tutti i punti, infatti le macchine possono lavorare per più (x) giorni, come anche non lavorare per lunghi periodi.
    Ho comunque bisogno che il risultato sia 0,00 h, nel caso in cui nella data in O1 la macchina abbia lavorato dalle 0 alle 24, e che sia 24 h nel caso in cui la macchina sia stata ferma.
    Il formato deve essere con i minuti centesimali. Per quello ho risolto moltiplicando =(formula ninai)*24.

    Grazie ancora per l'aiuto!

Discussioni Simili

  1. [Risolto] E' possibile collegare dei fogli di calcolo tramite data???
    Di GiamB81 nel forum Domande su Excel in generale
    Risposte: 9
    Ultimo Messaggio: 23/01/17, 23:50
  2. [Risolto] Calcolo automatico della data scadenza di fatture
    Di rmalenc nel forum Domande su Excel in generale
    Risposte: 11
    Ultimo Messaggio: 18/11/16, 12:09
  3. [Risolto] Calcolo con data di nascita
    Di Allocco nel forum Domande su Excel in generale
    Risposte: 2
    Ultimo Messaggio: 27/10/16, 14:12
  4. Calcolo tempo trascorso
    Di Marius44 nel forum Domande su Excel VBA e MACRO
    Risposte: 7
    Ultimo Messaggio: 21/10/16, 02:59
  5. Tempo di fermo macchina comparato con KPI
    Di Windrider nel forum Domande su Excel in generale
    Risposte: 5
    Ultimo Messaggio: 12/02/16, 12:17

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •