Risultati da 1 a 14 di 14

Discussione: Funzione SE su intervallo celle



  1. #1
    L'avatar di mirko.esposito
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    Milano
    Messaggi
    59
    Versione Office
    2016 MAC
    Likes ricevuti
    3
    Likes dati
    2

    Funzione SE su intervallo celle

    Ciao a tutti ragazzi!

    Sono nuovo del forum e vorrei sottoporvi un problema a cui non ho trovato una soluzione facilmente praticabile.
    Il problema riguarda la funzione SE.
    Ho una una lista di nominativi in una colonna ed una lista di luoghi di lavoro nella colonna successiva.
    Io cerco di riportare il nome di una persona in un'altro sheet di excel se fa parte di un certo luogo di lavoro.
    Quindi vorrei che ogni volta che excel trova la parola "Vigneto", mi riporti il nome corrispondente in prima colonna, altrimenti dovrebbe passare alla cella successiva.
    L'unica soluzione che ho trovato è l'annidamento della funzione che può andar bene quando sono pochi nominativi ma quando sono 100 diventa impossibile.

    Grazie mille in anticipo a chiunque di voi risponderà .
    Ultima modifica fatta da:Canapone; 30/06/17 alle 15:57

  2. #2
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1075
    Versione Office
    2010 su Win
    Likes ricevuti
    598
    Likes dati
    202

    Re: Funzione SE su intervallo celle

    Ciao,

    ho capito questo: nel primo foglio nomi nella colonna A, eventuali vigneto nella colonna B

    In un altro foglio in A2

    =SE.ERRORE(INDICE(Foglio1!$A$1:$A$1000;AGGREGA(15;6;RIF.RIGA($1:$1000)/(Foglio1!$B$1:$B$1000="Vigneto");RIF.RIGA(A1)));"")

    Copiando in basso la formula ottieni l'elenco dei nominativi.

    Se alleghi un piccolo esempio, possiamo correggere il tiro.

    Saluti

  3. I seguenti utenti hanno dato un "Like"


  4. #3
    L'avatar di mirko.esposito
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    Milano
    Messaggi
    59
    Versione Office
    2016 MAC
    Likes ricevuti
    3
    Likes dati
    2

    Re: Funzione SE su intervallo celle

    Grazie per la risposta, ti allego subito la tabella e nel frattempo provo la formula che mi hai consigliato.

    Grazie mille ancora!
    File Allegati File Allegati

  5. #4
    L'avatar di pkrome59
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Reggio Calabria
    Età
    58
    Messaggi
    1188
    Versione Office
    Office 2013
    Likes ricevuti
    1198
    Likes dati
    2133

    Re: Funzione SE su intervallo celle

    Ciao mirko.esposito, guardando la struttura del file che hai allegato, ho capito questo:

    nel foglio "COMPLESSIVO LAVORAZIONI"

    In B6:
    =SE.ERRORE(SE.ERRORE(INDICE(Tabella1[NOMINATIVO];AGGREGA(15;6;(RIF.RIGA(Tabella1[NOMINATIVO])-RIF.RIGA('LIBRO DEL LAVORO'!$B$3)+1)/(Tabella1[LUOGO DILAVORO PRINCIPALE]="VIGNETO");RIGHE('COMPLESSIVO LAVORAZIONI'!$B$6:$B6)));INDICE(Tabella1[NOMINATIVO];AGGREGA(15;6;(RIF.RIGA(Tabella1[NOMINATIVO])-RIF.RIGA('LIBRO DEL LAVORO'!$B$3)+1)/(Tabella1[LUOGO DILAVORO PRINCIPALE]="ENTRAMBI");RIGHE('COMPLESSIVO LAVORAZIONI'!$B$6:$B6)-CONTA.SE(Tabella1[LUOGO DILAVORO PRINCIPALE];"VIGNETO"))));"")

    In B22:
    =SE.ERRORE(SE.ERRORE(INDICE(Tabella1[NOMINATIVO];AGGREGA(15;6;(RIF.RIGA(Tabella1[NOMINATIVO])-RIF.RIGA('LIBRO DEL LAVORO'!$B$3)+1)/(Tabella1[LUOGO DILAVORO PRINCIPALE]="SEMINATIVO");RIGHE('COMPLESSIVO LAVORAZIONI'!$B$22:$B22)));INDICE(Tabella1[NOMINATIVO];AGGREGA(15;6;(RIF.RIGA(Tabella1[NOMINATIVO])-RIF.RIGA('LIBRO DEL LAVORO'!$B$3)+1)/(Tabella1[LUOGO DILAVORO PRINCIPALE]="ENTRAMBI");RIGHE('COMPLESSIVO LAVORAZIONI'!$B$22:$B22)-CONTA.SE(Tabella1[LUOGO DILAVORO PRINCIPALE];"SEMINATIVO"))));"")

    In B35:
    =SE.ERRORE(INDICE(Tabella1[NOMINATIVO];AGGREGA(15;6;(RIF.RIGA(Tabella1[NOMINATIVO])-RIF.RIGA('LIBRO DEL LAVORO'!$B$3)+1)/(Tabella1[LUOGO DILAVORO PRINCIPALE]="ALTRO");RIGHE('COMPLESSIVO LAVORAZIONI'!$B$35:$B35)));"")

    tutte e tre le formule da tirare giù, fino ai limiti degli intervalli delle rispettive tabelle.
    Allego il file di prova.
    Fa sapere se vanno bene.
    File Allegati File Allegati

  6. I seguenti 3 utenti hanno dato un "Like" a pkrome59 per questo post:


  7. #5
    L'avatar di mirko.esposito
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    Milano
    Messaggi
    59
    Versione Office
    2016 MAC
    Likes ricevuti
    3
    Likes dati
    2

    Re: Funzione SE su intervallo celle

    La formula purtroppo non funziona...

  8. #6
    L'avatar di mirko.esposito
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    Milano
    Messaggi
    59
    Versione Office
    2016 MAC
    Likes ricevuti
    3
    Likes dati
    2

    Re: Funzione SE su intervallo celle

    Ciao Pkrome59, le tue formule vanno alla grande.
    Ti chiederei un piacere: puoi spiegarmi come hai fatto?
    Grazie mille

  9. #7
    L'avatar di mirko.esposito
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    Milano
    Messaggi
    59
    Versione Office
    2016 MAC
    Likes ricevuti
    3
    Likes dati
    2

    Re: Funzione SE su intervallo celle

    Funziona alla perfezione! Grazie mille!
    Ti chiederei un piacere dunque: puoi spiegarmi come hai fatto?
    Ultima modifica fatta da:Canapone; 30/06/17 alle 15:57

  10. #8

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7147
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1300

    Re: Funzione SE su intervallo celle

    Pkrome, che cordialmente saluto, è uno dei maghi della funzione "AGGREGA"! :255:
    Geniale la scelta dell'uso del doppio SE.ERRORE che permette di fare la scelta nei diversi intervalli. :286:
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  11. #9
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1665
    Versione Office
    2010 PC
    Likes ricevuti
    892
    Likes dati
    184

    Re: Funzione SE su intervallo celle

    ciao
    mi scuso per non aver seguito a dovere il discorso ma ad intuito mi viene da pensare che basta mette nel denominatore della matrice di aggrega , le due condizioni come somma, la scrivo al volo dipendendola da quella precedente, con la premessa di poter sbagliare o addirittura di essere fuori tema:

    =SE.ERRORE(INDICE(Tabella1[NOMINATIVO];AGGREGA(15;6;(RIF.RIGA(Tabella1[NOMINATIVO])-RIF.RIGA('LIBRO DEL LAVORO'!$B$3)+1)/((Tabella1[LUOGO DILAVORO PRINCIPALE]="VIGNETO")+(Tabella1[LUOGO DILAVORO PRINCIPALE]="ENTRAMBI"));RIGHE($B$6:$B6)));"")

    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  12. I seguenti utenti hanno dato un "Like"


  13. #10
    L'avatar di mirko.esposito
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    Milano
    Messaggi
    59
    Versione Office
    2016 MAC
    Likes ricevuti
    3
    Likes dati
    2

    Re: Funzione SE su intervallo celle

    Ringrazio tutti per la partecipazione alla discussione e per aver risoltomi il problema. :166:
    Posso chiedervi se c'è un modo che mi permetta di raggiungere il medesimo risultato ma alla portata di uno che non conosce bene excel come voi?

    Grazie mille ancora

  14. #11
    L'avatar di pkrome59
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Reggio Calabria
    Età
    58
    Messaggi
    1188
    Versione Office
    Office 2013
    Likes ricevuti
    1198
    Likes dati
    2133

    Re: Funzione SE su intervallo celle

    Ciao Ninai, soluzione più che geniale, fantastica, da tuo pari ai ottenuto i medesimi risultati, utilizzando una formula molto più corta più elegante.
    Comunque mi sono permesso di aggiungere una parentesi che ti è sfuggita, sicuramente perché come spesso ti accade scrivi al volo.

    Riallego la tua creatura, con l'aggiunta della parentesi mancante.

    =SE.ERRORE(INDICE(Tabella1[NOMINATIVO];AGGREGA(15;6;(RIF.RIGA(Tabella1[NOMINATIVO])-RIF.RIGA('LIBRO DEL LAVORO'!$B$3)+1)/((Tabella1[LUOGO DILAVORO PRINCIPALE]="VIGNETO")+(Tabella1[LUOGO DILAVORO PRINCIPALE]="ENTRAMBI"));RIGHE($B$6:$B6)));"")

    Di nuovo Grande!!!!!!

    Ninai, ti chiedo scusa, probabilmente nel copiare la formula non ho preso una parentesi, perché vedo che adesso va bene, ti chiedo umilmente scusa.
    Ciao alla prossima.

  15. #12
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1665
    Versione Office
    2010 PC
    Likes ricevuti
    892
    Likes dati
    184

    Re: Funzione SE su intervallo celle

    grazie pkrome59 per la correzione (me ne ero accorto appena dopo ma tu l'avevi già acquisita) e per gli elogi .
    Parlando scorciatoie si potrebbe ancora sfoltire, così:
    =SE.ERRORE(INDICE(Tabella1[NOMINATIVO];AGGREGA(15;6;RIF.RIGA(Tabella1[NOMINATIVO])-RIF.RIGA('LIBRO DEL LAVORO'!$B$3)+1/(Tabella1[LUOGO DILAVORO PRINCIPALE]={"vigneto"\"entrambi"});RIGHE($B$6:$B6)));"")
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  16. I seguenti 2 utenti hanno dato un "Like" a ninai per questo post:


  17. #13
    L'avatar di pkrome59
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Reggio Calabria
    Età
    58
    Messaggi
    1188
    Versione Office
    Office 2013
    Likes ricevuti
    1198
    Likes dati
    2133

    Re: Funzione SE su intervallo celle

    Ciao, se ti vengo dietro impazzisco.
    Di nuovo Ciao.

  18. #14

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1228
    Likes dati
    923

    Re: Funzione SE su intervallo celle

    I miei complimenti a pkrome (non conosco ancora il nome...non era un invito, rispetto l'anonimato :246:) e ninai (conosco il nome ma non credo gradisca che venga usato).... :255:

    Come per altre formule (che alla fine mi sono imposto di imparare) anche AGGREGA ha il mio rifiuto... :87:_
    Mi sa che dovrò studiarmela.

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

Discussioni Simili

  1. [Risolto] Sommare dei numeri in funzione ad un intervallo di date
    Di sitolofi nel forum Domande su Excel in generale
    Risposte: 4
    Ultimo Messaggio: 03/01/17, 08:06
  2. Risposte: 3
    Ultimo Messaggio: 13/09/16, 16:38
  3. Funzione per trovare una data compresa in un intervallo
    Di ProgrammD69 nel forum Domande su Excel in generale
    Risposte: 14
    Ultimo Messaggio: 07/07/16, 15:10
  4. Come fare avanzare il contenuto di un intervallo di celle
    Di Paoletto nel forum Domande su Excel in generale
    Risposte: 4
    Ultimo Messaggio: 16/05/16, 17:09
  5. Funzione: se testo presente in un intervallo allora..
    Di serra890 nel forum Domande su Excel in generale
    Risposte: 9
    Ultimo Messaggio: 21/12/15, 10:48

Tag per Questa Discussione

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •