Risultati da 1 a 12 di 12

Discussione: Estrarre solo i numeri da una stringa



  1. #1
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    50
    Messaggi
    5388
    Versione Office
    office 365/2016
    Likes ricevuti
    1274
    Likes dati
    1342

    Estrarre solo i numeri da una stringa

    Ciao ragazzi
    Da queste stringhe di testo devo estrarre solo i numeri

    A
    B
    1
    DATA Risultato
    2
    Line1,ABCDORG,1234567,Test Data, Test Addrress
    1234567
    3
    Line2,AB,15485,Test Data, Test Addrress
    15485
    4
    Line1,ABCD,68787,Test Data, Test Addrress
    68787
    Se non lo sai spiegare in modo semplice, non l'hai capito abbastanza bene Cit. Einstein

  2. #2

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Verona Provincia
    Età
    58
    Messaggi
    1209
    Versione Office
    .
    Likes ricevuti
    453
    Likes dati
    0
    Se le stringhe in colonna A hanno sempre 5 caratteri prima della virgola (Line1 et simili), questo è un modo:

    Codice: 
    =STRINGA.ESTRAI(A2;TROVA(",";A2;7)+1;TROVA(",";STRINGA.ESTRAI(A2;TROVA(",";A2;7)+1;9^9))-1)
    ora ci pensa ninai o canapone a darle una sforbiciata!

  3. #3

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Verona Provincia
    Età
    58
    Messaggi
    1209
    Versione Office
    .
    Likes ricevuti
    453
    Likes dati
    0
    P.S.: Se ti serve che quelli estratti siano numeri veri e non stringhe:
    Codice: 
    =--STRINGA.ESTRAI(A2;TROVA(",";A2;7)+1;TROVA(",";STRINGA.ESTRAI(A2;TROVA(",";A2;7)+1;9^9))-1)

  4. #4
    L'avatar di Andre81
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Parma
    Età
    37
    Messaggi
    65
    Versione Office
    2013
    Likes ricevuti
    2
    Likes dati
    9
    Ciao a tutti,

    io ho creato una formula allucinante, ma sembra funzionare:

    =RIMPIAZZA(RIMPIAZZA(RIMPIAZZA(A1;1;TROVA(",";A1;1);"");1;TROVA(",";RIMPIAZZA(A1;1;TROVA(",";A1;1);"");1);"");TROVA(",";RIMPIAZZA(RIMPIAZZA(A1;1;TROVA(",";A1;1);"");1;TROVA(",";RIMPIAZZA(A1;1;TROVA(",";A1;1);"");1);"");1);50;"")

    Excel 2013
    Row\Col
    A
    B
    1
    Line1,ABCDORG,1234567,Test Data, Test Addrress 1234567
    2
    Line2,AB,15485,Test Data, Test Addrress 15485
    3
    Line1,ABCD,68787,Test Data, Test Addrress 68787
    4
    Line1,ABCDORG,5555555555,Test Data, Test Addrress 5555555555
    5
    Line1,ABCDORG,7,Test Data, Test Addrress 7
    6
    Line2,AB,32,Test Data, Test Addrress 32
    7
    Line2,AB,196,Test Data, Test Addrress 196
    Sheet: Foglio3
    Ultima modifica fatta da:Andre81; 15/07/15 alle 13:45

  5. #5
    L'avatar di Andre81
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Parma
    Età
    37
    Messaggi
    65
    Versione Office
    2013
    Likes ricevuti
    2
    Likes dati
    9
    Il ragionamento che ho fatto è semplice: i numeri che Gerardo vuole estrarre soono tutti dopo la seconda virgola, per cui questo è stato il mio punto di partenza.

  6. #6

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Verona Provincia
    Età
    58
    Messaggi
    1209
    Versione Office
    .
    Likes ricevuti
    453
    Likes dati
    0
    Ciao Andre,
    Il ragionamento che ho fatto è semplice: i numeri che Gerardo vuole estrarre soono tutti dopo la seconda virgola, per cui questo è stato il mio punto di partenza.
    anch'io sono partito da quel presupposto.

    Volendo eliminare il vincolo che avevo messo, cioè che la stringa cominci con LineX:
    Codice: 
    =--STRINGA.ESTRAI(A4;TROVA(",";A4;7)+1;TROVA(",";STRINGA.ESTRAI(A4;TROVA(",";A4;TROVA(",";A4)+1)+1;9^9))-1)
    Bye!
    scossa
    scossa's web site
    ___
    Se tu hai una mela, e io ho una mela, e ce le scambiamo, allora tu ed io abbiamo sempre una mela per uno. Ma se tu hai un'idea, ed io ho un'idea, e ce le scambiamo, allora abbiamo entrambi due idee. (George Bernard Shaw)

  7. #7
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    50
    Messaggi
    5388
    Versione Office
    office 365/2016
    Likes ricevuti
    1274
    Likes dati
    1342
    Anchi'io sono partito con la vostra stessa logica, cioè estrarre tutto dopo la seconda virgola

    Questa è la mia soluzione:

    =ANNULLA.SPAZI(STRINGA.ESTRAI(SOSTITUISCI(A2;",";RIPETI(" ";100));200;100))+0



    A
    B
    1
    DATA Risultato
    2
    Line1,ABCDORG,1234567,Test Data, Test Addrress 1234567
    3
    Line2,AB,15485,Test Data, Test Addrress 15485
    4
    Line1,ABCD,6876666666687,Test Data, Test Addrress 6876666666687


    Se qualcuno vuole darsi una schiarita su come estarre le stringhe con questo sistema evoluto con il SOSTITUISCI e RIPETI
    Guarda questo video!!



    Ultima modifica fatta da:Gerardo Zuccalà; 15/07/15 alle 14:20
    Se non lo sai spiegare in modo semplice, non l'hai capito abbastanza bene Cit. Einstein

  8. #8

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Verona Provincia
    Età
    58
    Messaggi
    1209
    Versione Office
    .
    Likes ricevuti
    453
    Likes dati
    0
    Ciao Gerardo,
    conoscevo questo metodo, ma a fronte di una maggior semplicità la trovo un po' meno "generica": se sostituisci Linea1 con una novantina di caratteri (AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA)
    la formula fallisce.

    P.S.: correggo qui (non posso modificare il mio post) la formula proposta sopra per svincolare dalla lunghezza della stringa prima della virgola:
    Codice: 
    =--STRINGA.ESTRAI(A2;TROVA(",";A2;TROVA(",";A2)+1)+1;TROVA(",";STRINGA.ESTRAI(A2;TROVA(",";A2;TROVA(",";A2)+1)+1;9^9))-1)
    Bye!
    scossa
    scossa's web site
    ___
    Se tu hai una mela, e io ho una mela, e ce le scambiamo, allora tu ed io abbiamo sempre una mela per uno. Ma se tu hai un'idea, ed io ho un'idea, e ce le scambiamo, allora abbiamo entrambi due idee. (George Bernard Shaw)

  9. #9
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    50
    Messaggi
    5388
    Versione Office
    office 365/2016
    Likes ricevuti
    1274
    Likes dati
    1342
    Citazione Originariamente Scritto da scossa Visualizza Messaggio
    Ciao Gerardo,
    conoscevo questo metodo, ma a fronte di una maggior semplicità la trovo un po' meno "generica": se sostituisci Linea1 con una novantina di caratteri (AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA)
    la formula fallisce.

    P.S.: correggo qui (non posso modificare il mio post) la formula proposta sopra per svincolare dalla lunghezza della stringa prima della virgola:
    Codice: 
    =--STRINGA.ESTRAI(A2;TROVA(",";A2;TROVA(",";A2)+1)+1;TROVA(",";STRINGA.ESTRAI(A2;TROVA(",";A2;TROVA(",";A2)+1)+1;9^9))-1)
    Certo hai perfettamente ragione
    anche se è raro che ci siano una 90 di caratteri prima
    se vuoi andare sul sicuro puoi incrementare i numeri:

    =ANNULLA.SPAZI(STRINGA.ESTRAI(SOSTITUISCI(A2;",";RIPETI(" ";1000));2000;1000))+0

    Comunque la tua soluzione è sicuramente più stabile
    Ciao grazie per la tua precisazione potrebbe essere utile in alcuni casi
    ciao
    Se non lo sai spiegare in modo semplice, non l'hai capito abbastanza bene Cit. Einstein

  10. #10
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    2142
    Versione Office
    2010 PC
    Likes ricevuti
    1180
    Likes dati
    239
    ciao
    della serie, "famolo strano":
    =-CERCA(2;-SINISTRA(DESTRA(SOSTITUISCI(A2;",";RIPETI(" ";100);2);100);RIF.RIGA($1:$125)))

  11. #11
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    50
    Messaggi
    5388
    Versione Office
    office 365/2016
    Likes ricevuti
    1274
    Likes dati
    1342
    Ragazzi che dire!! fantastico
    qui il livello di excel si alzato alla massima potenza, pensare che fino a qualche giorno fa eravamo a bisticciare con qualche CERCA.VERT e qualche INDICE e CONFRONTA..
    direi che adesso con l'arrivo di scossa e ninai siamo in una botte di ferro questo forum è pronto a risolvere qualsiasi problema
    l'unica cosa che mancano adesso sono le domande dagli utenti registrarti che probabilmente hanno gettato la spugna visto il caldo torrido.
    ciao un grazie a tutti gli amici del forum e buon divertimento
    Se non lo sai spiegare in modo semplice, non l'hai capito abbastanza bene Cit. Einstein

  12. #12
    L'avatar di Andre81
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Parma
    Età
    37
    Messaggi
    65
    Versione Office
    2013
    Likes ricevuti
    2
    Likes dati
    9
    Ne ho creata un'altra, e funziona a prescindere dal numero di caratteri (e quindi non richiede modifiche):

    =SINISTRA(RIMPIAZZA(SOSTITUISCI(A1;",";"";1);1;TROVA(",";SOSTITUISCI(A1;",";"";1);1);"");TROVA(",";RIMPIAZZA(SOSTITUISCI(A1;",";"";1);1;TROVA(",";SOSTITUISCI(A1;",";"";1);1);"");1)-1)

Discussioni Simili

  1. [Risolto] CERCA VERT: corrispondenza con solo una parte di una stringa
    Di MannyX nel forum Domande su Excel in generale
    Risposte: 4
    Ultimo Messaggio: 10/03/17, 15:21
  2. Copia solo se è presente una determinta stringa
    Di bifuz nel forum Domande su Excel in generale
    Risposte: 17
    Ultimo Messaggio: 24/02/17, 14:11
  3. Invertire numeri in una stringa di testo
    Di Silvio65 nel forum Domande su Excel in generale
    Risposte: 10
    Ultimo Messaggio: 16/02/17, 16:33
  4. [Risolto] Applicare una formula solo in corrispondenza di una stringa
    Di iFarto nel forum Domande su Excel in generale
    Risposte: 4
    Ultimo Messaggio: 19/10/16, 20:05
  5. estrarre numeri da stringa
    Di BRAZ66 nel forum Domande su Excel in generale
    Risposte: 17
    Ultimo Messaggio: 10/09/16, 14:11

Tag per Questa Discussione

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •