Risultati da 1 a 18 di 18

Discussione: campo indice in cerca.vert



  1. #1
    L'avatar di Barchetta
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    51013
    Età
    45
    Messaggi
    81
    Versione Office
    Excel 2013
    Likes ricevuti
    0
    Likes dati
    8

    campo indice in cerca.vert

    Ciao, quando usiamo il cerca.vert il terzo campo da impostare è l'indice che sarebbe il numero della colonna dove cercare il dato.è possibile impostare l'indice su 2 colonne adiacenti. Avevo provato ad impostare una formula del genere:Formula con una colonna di ricercacerca.vert(a2;fogliodati!$A:$r;11;FALSO)cerca.vert(a2;fogliodati!$A:$R;rif.colonna(J:K);falso)però se il dato che è nella colonna k non mi trova nienteCome faccio a fargli controllare su due colonne adiacenti?Grazie

  2. #2

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299

    Re: campo indice in cerca.vert

    Ciao Barchetta,
    il file!!!!!! Devi allegare un file come esempio!!!
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  3. #3
    L'avatar di Barchetta
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    51013
    Età
    45
    Messaggi
    81
    Versione Office
    Excel 2013
    Likes ricevuti
    0
    Likes dati
    8

    Re: campo indice in cerca.vert

    ho scritto con il tablet....speravo stavolta bastasse.
    accendo il pc e vedo

  4. #4

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299

    Re: campo indice in cerca.vert

    Non è per cattiva volontà ma per provare dobbiamo costruire un file con le tue indicazioni e non è detto che abbiamo capito bene, se invece alleghi il file è più facile aiutarti.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  5. I seguenti utenti hanno dato un "Like"


  6. #5
    L'avatar di Barchetta
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    51013
    Età
    45
    Messaggi
    81
    Versione Office
    Excel 2013
    Likes ricevuti
    0
    Likes dati
    8

    Re: campo indice in cerca.vert

    allego esempio

    GES..hai ragione sono che sono stato un po' superficiale
    File Allegati File Allegati

  7. #6

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299

    Re: campo indice in cerca.vert

    Ho visto il file, la tua formula non va bene, non puoi confrontare il valore 101019 nella colonna 8 o 9, questo valore è presente solo nella colonna 1.

    Ti propongo un'alternativa, nel secondo foglio in B2 da trascinare in basso:

    =SE(INDICE(fogliodati!$G$2:$G$9*fogliodati!$H$2:$H$9;CONFRONTA(Foglio1!A2;fogliodati!$A$2:$A$9;0))>0;"OK";"Non maggiore di zero")
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  8. I seguenti utenti hanno dato un "Like"


  9. #7
    L'avatar di Barchetta
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    51013
    Età
    45
    Messaggi
    81
    Versione Office
    Excel 2013
    Likes ricevuti
    0
    Likes dati
    8

    Re: campo indice in cerca.vert

    avevo pensato anche io ad un indice e confronta, ma non con indice(foglidati....*fogliodati...)
    ma il simbolo " * " non moltiplica?

    intanto grazie. Domani lo metto in produzione

  10. #8

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299

    Re: campo indice in cerca.vert

    Citazione Originariamente Scritto da Barchetta Visualizza Messaggio
    avevo pensato anche io ad un indice e confronta, ma non con indice(foglidati....*fogliodati...)
    ma il simbolo " * " non moltiplica?

    ..
    Certo,il simbolo * moltiplica, ma - sempre se ho ben capito - tu vuoi sapere se il dato nella colonna G o H sia uguale a zero, ebbene, se c'è uno zero moltiplicando non può che fare zero e quindi si verificano entrambe le colonne con un'unica formula.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  11. #9
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126

    Re: campo indice in cerca.vert

    Sono un po confuso

    Prova questa in B3

    =SE(MATR.SOMMA.PRODOTTO((fogliodati!$A$2:$A$9=A3)*((fogliodati!$G$2:$G$9>0)+(fogliodati!$H$2:$H$9>0)))=1;"ok";"no")

    Mi pare di aver capito che in B2 ci sono altre condizioni

    In attesa di un riscontro un saluto

    Gerardo

  12. I seguenti utenti hanno dato un "Like"


  13. #10
    L'avatar di Gianfranco55
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Vicenza
    Età
    62
    Messaggi
    2072
    Versione Office
    2016
    Likes ricevuti
    553
    Likes dati
    117

    Re: campo indice in cerca.vert

    Ciao

    in difesa del Cerca Verticale:32:

    si possono utilizzare queste formule
    Con la moltiplicazione dei risultati

    Codice: 
    = SE(CERCA.VERT($A2;fogliodati!$A$2:$I$9;7;FALSO)*CERCA.VERT($A2;fogliodati!$A$2:$I$9;8;FALSO)>0;"oK";"Non maggiore di zero")
    Codice: 
    con la funzione O
    
    = SE(O(CERCA.VERT($A3;fogliodati!$A$2:$I$9;7;FALSO)<=0;CERCA.VERT($A3;fogliodati!$A$2:$I$9;8;FALSO)<=0);"Non maggiore di zero";"OK")
    W il cerca vertivale:167:

  14. I seguenti 2 utenti hanno dato un "Like" a Gianfranco55 per questo post:


  15. #11
    L'avatar di pkrome59
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Reggio Calabria
    Età
    58
    Messaggi
    1188
    Versione Office
    Office 2013
    Likes ricevuti
    1198
    Likes dati
    2133

    Re: campo indice in cerca.vert

    Ciao a tutti, tanto per partecipare, variante con funzione SE; Indice e Aggrega:

    =SE(INDICE((fogliodati!$G$2:$G$9)*(fogliodati!$H$2:$H$9);AGGREGA(15;6;(RIF.RIGA(fogliodati!$G$2:$G$9)-1)/(fogliodati!$A$2:$A$9=Foglio1!A2);1))>0;"OK";"Non maggiore di zero")

    Saluti.

  16. I seguenti utenti hanno dato un "Like"

    ges

  17. #12
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1664
    Versione Office
    2010 PC
    Likes ricevuti
    892
    Likes dati
    184

    Re: campo indice in cerca.vert

    ciao a tutti
    della serie, "mi ci ficco" e "corto è bello" :167::167::167::
    =SE(PRODOTTO(CERCA.VERT(A2;fogliodati!$A$2:$H$9;{7.8};FALSO));"ok";"Non maggiore di zero")
    matriciale
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  18. I seguenti 5 utenti hanno dato un "Like" a ninai per questo post:


  19. #13
    L'avatar di Barchetta
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    51013
    Età
    45
    Messaggi
    81
    Versione Office
    Excel 2013
    Likes ricevuti
    0
    Likes dati
    8

    Re: campo indice in cerca.vert

    Ciao, perdonate la latitanza e grazie innanzi tutto.
    Le vostre soluzioni sono corrette ma molto probabilmente vi ho posto la domanda in modo errato, perdonate ci riprovo.
    Il file di esempio è corretto, io avrei bisogno di avere "ok" se nella colonna G e nella colonna H è presente una valore maggiore di zero, ma allo stesso tempo può verificarsi che nella colonna G sia zero ma nella colonna H sia maggiore di zero o nella colonna G sia maggiore di zero e nella colonna H sia zero (le tre condizioni) quindi il risultato sa sempre ok.
    Oltre a queste condizioni ne ho altre, in pratica è un controllo su ordini in essere; arrivi; fatturazioni e altre 4 o 5 condizioni in base all'articolo, destinazione e reparto.

    Allegare esempio reale è un pochino complesso, se riuscivo a trovare la soluzione per le due colonne G e H poi cercavo il modo di concatenare le varie condizioni
    Mi scuso ancora per avervi postato una domanda non corretta.

  20. #14
    L'avatar di pkrome59
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Reggio Calabria
    Età
    58
    Messaggi
    1188
    Versione Office
    Office 2013
    Likes ricevuti
    1198
    Likes dati
    2133

    Re: campo indice in cerca.vert

    Ciao Barchetta, se ho capito bene la tua richiesta, copia la seguente:

    In Foglio1, A2:
    =SE.ERRORE(SE(O(INDICE((fogliodati!$G$2:$G$9);AGGREGA(15;6;(RIF.RIGA(fogliodati!$G$2:$G$9)-1)/(fogliodati!$A$2:$A$9=Foglio1!A2);1))<>0;INDICE((fogliodati!$H$2:$H$9);AGGREGA(15;6;(RIF.RIGA(fogliodati!$G$2:$G$9)-1)/(fogliodati!$A$2:$A$9=Foglio1!A2);1))<>0);"OK";"Non maggiore di zero");"")

    Allego il file di prova, fai sapere se va bene.
    Ciao.
    File Allegati File Allegati

  21. I seguenti utenti hanno dato un "Like"


  22. #15
    L'avatar di Gianfranco55
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Vicenza
    Età
    62
    Messaggi
    2072
    Versione Office
    2016
    Likes ricevuti
    553
    Likes dati
    117

    Re: campo indice in cerca.vert

    Ciao
    vale anche con
    Codice: 
    = SE(O(CERCA.VERT($A2;fogliodati!$A$2:$I$9;7;FALSO)>0;CERCA.VERT($A2;fogliodati!$A$2:$I$9;8;FALSO)>0);"OK";"Non maggiore di zero")
    Codice: 
    = SE(CERCA.VERT($A2;fogliodati!$A$2:$I$9;7;FALSO)+CERCA.VERT($A2;fogliodati!$A$2:$I$9;8;FALSO)>0;"oK";"Non maggiore di zero")
    perché non elenchi le condizioni?

  23. I seguenti utenti hanno dato un "Like"


  24. #16
    L'avatar di Barchetta
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    51013
    Età
    45
    Messaggi
    81
    Versione Office
    Excel 2013
    Likes ricevuti
    0
    Likes dati
    8

    Re: campo indice in cerca.vert

    Ciao e GRAZIE! Adesso e' perfetto.

  25. #17
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1664
    Versione Office
    2010 PC
    Likes ricevuti
    892
    Likes dati
    184

    Re: campo indice in cerca.vert

    anche nella mia, basta sostituire PRODOTTO con SOMMA.
    Ma alla luce del fatto che ti servono altri criteri, forse la formula più adatta (già esatta da prima) è quella di Gerardo , dove puoi aggiungere tutti i criteri che vuoi, moltiplicandoli (per condizioni di E) o addizionandoli (per condizioni di O)
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  26. #18
    L'avatar di Barchetta
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    51013
    Età
    45
    Messaggi
    81
    Versione Office
    Excel 2013
    Likes ricevuti
    0
    Likes dati
    8

    Re: campo indice in cerca.vert

    Dopo in ufficio provo anche la versione con somma.
    Probabilmente hai ragione, ma per semplificare l'esempio ho ridotto il file e le condizioni dove ho inserito la formula. Infatti le vostre soluzioni sono state inserite in una formula più lunga. Purtroppo la mia conoscenza di Excel rispetto a voi è limitata (come v'invidio :167:) e sono meno "elastico" nella soluzione.

Discussioni Simili

  1. [Risolto] Come cercare date: CERCA.VERT() o INDICE+CONFRONTA ?
    Di luca.donati nel forum Domande su Excel in generale
    Risposte: 14
    Ultimo Messaggio: 15/02/17, 12:27
  2. [Risolto] Cerca valori che si ripetono in tabella. Formula per arrivare dove il cerca.vert non può
    Di Gatt88 nel forum Domande su Excel in generale
    Risposte: 7
    Ultimo Messaggio: 02/12/16, 11:45
  3. Cerca.Vert con Se
    Di jigen nel forum Domande su Excel in generale
    Risposte: 4
    Ultimo Messaggio: 02/08/16, 12:31
  4. Cerca.vert
    Di Snoopy nel forum Domande su Excel in generale
    Risposte: 4
    Ultimo Messaggio: 09/06/16, 17:01
  5. vba, cerca.vert con campo ricerca variabile
    Di tanimon nel forum Domande su Excel VBA e MACRO
    Risposte: 9
    Ultimo Messaggio: 21/12/15, 23:38

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •