Risultati da 1 a 15 di 15

Discussione: SOMMA.SE con FILTRO



  1. #1
    L'avatar di ranaone
    Clicca e Apri
    Data Registrazione
    Jul 2016
    Località
    milano
    Età
    48
    Messaggi
    1
    Versione Office
    2010
    Likes ricevuti
    0
    Likes dati
    0

    SOMMA.SE con FILTRO

    ho un problema che vorrei cercare di risolvere con una funzione senza ricorrere a macro:
    in un foglio ho un elenco di record divisi per riga con vari dati nelle colonne; vorrei poter sommare i dati di una colonna. Facile, direte, esiste la funzione SOMMA. Io invece ho la necessità che questa somma si adatti ai filtri applicati sulle varie colonne che riducono i record visualizzati.
    In pratica un mix tra la funzione "SOMMA.SE(A1:B100;"Nord";B1:B100)" e "SUBTOTALE(9;A1:A100)"

    Riescite ad aiutarmi?

    Grazie anticipatamente

    Saluti a tutti

  2. #2
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1076
    Versione Office
    2010 su Win
    Likes ricevuti
    598
    Likes dati
    204

    Re: SOMMA.SE con FILTRO

    Ciao,

    riesci ad allegare un piccolo file d'esempio a cui adattare la formula?

    La formula dovrebbe essere qualcosa di simile a

    =MATR.SOMMA.PRODOTTO(SUBTOTALE(9;SCARTO(B1:B100;RIF.RIGA(A1:A100)-MIN(RIF.RIGA(A1:A100));;1));--(A1:A100="Nord"))

    Il segmento finale della formula è la condizione da imporre alla somma.


    Saluti

  3. #3
    L'avatar di NEW LOOKAT
    Clicca e Apri
    Data Registrazione
    Jul 2016
    Località
    Sesto Fiorentino
    Messaggi
    11
    Versione Office
    excel 2008
    Likes ricevuti
    0
    Likes dati
    0

    Re: SOMMA.SE con FILTRO

    buongiorno,
    scusa anche io ho bisogno di qualcosa di smile SOMMA.SE + SUBTOTALE con filtro ...mi spiego meglio:
    ho 1 file exl con 2 fogli nel FGL1 ho nella colonna G elenco i fornitori e nella colonna L imponibile, poi vado al FGL2 dove ho i riepiloghi con la formula SOMMA.SE ora in questo foglio ho bisogno di una formula SUBTOTALE in modo che se nel FGL1 metto il filtro in un'altra colonna che non è né G né L mi dia il risultato delle colonne G e L del somm.se. ALLEGO 2 FILE x chiarezza, la formula serve nel foglio2
    GRAZIE IMMENSAMENTE A CHIUNQUE POTRA' VORRA' AIUTARMI...
    File Allegati File Allegati

  4. #4

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7160
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2065
    Likes dati
    1301

    Re: SOMMA.SE con FILTRO

    Ciao a tutti,
    forse ti serve qualcosa del genere - nel file Spese di gestione - in B5 da trascinare in basso:

    =SOMMA(INDIRETTO("B5:B"&RIF.RIGA()))
    File Allegati File Allegati
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  5. #5
    L'avatar di NEW LOOKAT
    Clicca e Apri
    Data Registrazione
    Jul 2016
    Località
    Sesto Fiorentino
    Messaggi
    11
    Versione Office
    excel 2008
    Likes ricevuti
    0
    Likes dati
    0

    Re: SOMMA.SE con FILTRO

    grazie per la solerte risposta ma credo di non capire o forse non sono stata sufficientemente chiara nel porre la domanda...
    nel FGL2 nella colona del SUBTOTALE ho bisogno di una formula che somma.se ma deve prendere i dati dal FGL1 con il filtro applicato in qualsiasi colonna

  6. #6
    L'avatar di Giuse
    Clicca e Apri
    Data Registrazione
    Jul 2016
    Località
    Genova
    Età
    36
    Messaggi
    2
    Versione Office
    2010
    Likes ricevuti
    0
    Likes dati
    1

    Re: SOMMA.SE con FILTRO

    La soluzione più rapida è quella di utilizzare la formula "SOMMA.PIÙ.SE".
    Utilizzata con il wizard risulta di semplice intuizione. In più puoi applicare tutti i filtri che vuoi.

  7. #7
    L'avatar di TuttoExcel
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    Milano
    Età
    43
    Messaggi
    82
    Versione Office
    Excel 2013
    Likes ricevuti
    19
    Likes dati
    3

    Re: SOMMA.SE con FILTRO

    Ciao,
    ecco la mia soluzione, spero di averla capita bene :-)

    La formula è la seguente

    Codice: 
    =MATR.SOMMA.PRODOTTO(('ELENCO FATT spese'!$A$11:$A$51=SPLIT!A5)*(SUBTOTALE(9;INDIRETTO(INDIRIZZO(RIF.RIGA('ELENCO FATT spese'!$A$11:$A$51);10;;;"Elenco FATT spese")))>0)*'ELENCO FATT spese'!$J$11:$J$51)
    Praticamente usa il MATR.SOMMA.PRODOTTO per identificare le voci che, nella colonna A del foglio ELENCO FATT Spese, corrispondono alla voce selezionata, se, per ogni riga, questa condizione è vera viene restituito VERO che equivale al valore 1, altrimenti FALSO che equivale a 0.

    La seconda analisi usa subtotale(9) sulla riga in analisi, quindi se è visibile il valore sarà quello della cella imponibile, altrimenti sarà 0, come prima faccio un confronto, se il valore è superiore a 0 restituisce VERO (quindi 1).

    Moltiplicando i 2 valori ottento 1x1 o 0x1 o 1x0 o 0x0, va da se che solo 1x1 da come risultato 1 mentre gli altri danno 0.

    A questo punto 0 o 1 vengono moltiplicati per l'imponibile della riga, se moltiplico per 0 ottengo 0.

    Infine la formula somma tutti i valori ed ottiene il risultato sperato :-)

    P.S.: dimenticavo un paio di cose, ho limitato le righe di analisi fino alla 51 ma puoi tranquillamente espandere l'intervallo fino al numero che preferisci cambiando semplicemente $A$11:$A$51 con, chessò, $A$11:$A$500.
    Se non è l'imponibile la cella che vuoi sommare devi cambiare la parte INDIRIZZO(RIF.RIGA('ELENCO FATT spese'!$A$11:$A$51);10;;;"Elenco FATT spese") sostituendo il 10 in rosso con il numero corrispondente della colonna che ti interessa.
    Inoltre la formula funziona indipendentemente da quale colonna usi per i filtri (una o più)
    File Allegati File Allegati
    Condividi la tua conoscenza. E’ un modo per raggiungere l’immortalità. (Dalai Lama)
    Amministratore di www.tuttoexcel.it

  8. #8
    L'avatar di NEW LOOKAT
    Clicca e Apri
    Data Registrazione
    Jul 2016
    Località
    Sesto Fiorentino
    Messaggi
    11
    Versione Office
    excel 2008
    Likes ricevuti
    0
    Likes dati
    0

    Re: SOMMA.SE con FILTRO

    GRAZIE A TUTTI :) mi state risolvendo un problema veramente ingombrante...GRAZIEgrazieGRAZIE !!!
    ma soprattutto a te "TUTTO EXCEL" hai centrato il risultato ... però non capisco perché in alcune celle funziona e in altre no eppure mi sembra tutto uguale...allego file ho evidenziato in rosso quelle sbagliate !!!
    File Allegati File Allegati

  9. #9
    L'avatar di TuttoExcel
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    Milano
    Età
    43
    Messaggi
    82
    Versione Office
    Excel 2013
    Likes ricevuti
    19
    Likes dati
    3

    Re: SOMMA.SE con FILTRO

    Errore mio, non avevo considerato i valori negativi. Essendoci un controllo che somma solo se maggiore di 0 non somma quelli al di sotto, ovviamente. Puoi risolvere modificando il >0 in <> 0

    Quindi da
    =MATR.SOMMA.PRODOTTO(('ELENCO FATT spese'!$A$11:$A$1000=SPLIT!A5)*(SUBTOTALE(9;INDIRETTO(INDIRIZZO(RIF.RIGA('ELENCO FATT spese'!$A$11:$A$1000);10;;;"Elenco FATT spese")))>0)*'ELENCO FATT spese'!$J$11:$J$1000)

    a

    =MATR.SOMMA.PRODOTTO(('ELENCO FATT spese'!$A$11:$A$1000=SPLIT!A5)*(SUBTOTALE(9;INDIRETTO(INDIRIZZO(RIF.RIGA('ELENCO FATT spese'!$A$11:$A$1000);10;;;"Elenco FATT spese")))<>0)*'ELENCO FATT spese'!$J$11:$J$1000)

    Scusa per la svista :-)

    P.S.: la cella A20 del foglio split ha uno spazio alla fine della stringa che non è presente nell'elenco, quindi non lo trova, cambia da "FIERA HOMI MILANO " a "FIERA HOMI MILANO" :-)
    Condividi la tua conoscenza. E’ un modo per raggiungere l’immortalità. (Dalai Lama)
    Amministratore di www.tuttoexcel.it

  10. I seguenti utenti hanno dato un "Like"


  11. #10
    L'avatar di NEW LOOKAT
    Clicca e Apri
    Data Registrazione
    Jul 2016
    Località
    Sesto Fiorentino
    Messaggi
    11
    Versione Office
    excel 2008
    Likes ricevuti
    0
    Likes dati
    0

    Re: SOMMA.SE con FILTRO

    GRAZIE "TUTTO EXCEL" lo sai che per me sei un genio ??!!!!!! ti invidio perché riesci a partorire una formula di 35 cm (l'ho misurata)... infinitamente grata a vita :)

  12. #11
    L'avatar di TuttoExcel
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    Milano
    Età
    43
    Messaggi
    82
    Versione Office
    Excel 2013
    Likes ricevuti
    19
    Likes dati
    3

    Re: SOMMA.SE con FILTRO

    Di nulla, grazie a te per il riscontro :-)

    Comunque in questo forum ci sono tanti altri "geniacci" che invidio a mia volta, frequentalo e diventerai un genio anche tu
    Condividi la tua conoscenza. E’ un modo per raggiungere l’immortalità. (Dalai Lama)
    Amministratore di www.tuttoexcel.it

  13. #12
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1076
    Versione Office
    2010 su Win
    Likes ricevuti
    598
    Likes dati
    204

    Re: SOMMA.SE con FILTRO

    Ciao a tutti,

    fuori tempo massimo aggiusto i riferimenti alla formula del post#2 al file di NEW LOOKAT.

    In B5:

    =MATR.SOMMA.PRODOTTO(SUBTOTALE(9;SCARTO('ELENCO FATT spese'!J$11:J$1000;RIF.RIGA($11:$1000)-11;;1));--('ELENCO FATT spese'!A$11:A$1000=A5))

    Ne approfitto per salutare gli amici del Forum.

  14. I seguenti 2 utenti hanno dato un "Like" a Canapone per questo post:


  15. #13
    L'avatar di TuttoExcel
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    Milano
    Età
    43
    Messaggi
    82
    Versione Office
    Excel 2013
    Likes ricevuti
    19
    Likes dati
    3

    Re: SOMMA.SE con FILTRO

    Bella ed elegante anche la tua Canapone :-)
    Condividi la tua conoscenza. E’ un modo per raggiungere l’immortalità. (Dalai Lama)
    Amministratore di www.tuttoexcel.it

  16. #14
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1076
    Versione Office
    2010 su Win
    Likes ricevuti
    598
    Likes dati
    204

    Re: SOMMA.SE con FILTRO

    Ciao TuttoExcel,

    la formula credo sia stata pubblicata la prima volta da Laurent Longre, quello che di morefunc.

    Saluti da Firenze

  17. #15
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126

    Re: SOMMA.SE con FILTRO

    Ciao Stefano (Canapone )
    Stavo studiando la tua bellissima formula e ho fatto una piccola modifica all'argomento righe della funzione SCARTO (vedi modifica in rosso) perchè se accidentalmente qualcuno inserisce una nuova riga in alto, la formula non funziona piu, mentre con la modifica è più robusta

    =MATR.SOMMA.PRODOTTO(SUBTOTALE(9;SCARTO('ELENCO FATT spese'!J$11:J$1000;RIF.RIGA($11:$1000)-11;;1));--('ELENCO FATT spese'!A$11:A$1000=A5))


    =MATR.SOMMA.PRODOTTO(SUBTOTALE(9;SCARTO('ELENCO FATT spese'!J$11:J$1000;RIF.RIGA($A$11:$J$1000)-RIF.RIGA($A$11);;1));--('ELENCO FATT spese'!A$11:A$1000=A5))

    Complimenti anche a Gianfranco appena posso mi studio anche la sua formula

    Tutto qui!
    Un Saluto a tutti

Discussioni Simili

  1. [Risolto] Subtotale con Filtro
    Di tk71 nel forum Domande su Excel in generale
    Risposte: 5
    Ultimo Messaggio: 27/10/16, 21:51
  2. >Come estrappolare la somma "automatica" di un DB con funzione "FILTRO"<
    Di tk71 nel forum Domande su Excel in generale
    Risposte: 1
    Ultimo Messaggio: 11/06/16, 11:44
  3. Formula della somma con filtro
    Di simo86s nel forum Domande su Excel in generale
    Risposte: 4
    Ultimo Messaggio: 23/05/16, 12:29
  4. filtro da elenco
    Di nessi nel forum Domande su Excel VBA e MACRO
    Risposte: 2
    Ultimo Messaggio: 22/03/16, 14:58
  5. [Risolto] filtro per formule
    Di Stefano nel forum Domande su Excel in generale
    Risposte: 1
    Ultimo Messaggio: 04/06/15, 08:27

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •