Risultati da 1 a 16 di 16

Discussione: Ricerca mese per statistica



  1. #1
    L'avatar di BaldoGiovane
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Verona
    Età
    32
    Messaggi
    41
    Versione Office
    2010
    Likes ricevuti
    0
    Likes dati
    0

    Ricerca mese per statistica

    Salve, ho in Foglio1 una tabella di questo tipo

    11-Giu-2016 25
    15-Giu-2016 22
    28-Giu-2016 11
    2-Lug-2016 10
    5-Lug-2016 15

    In Foglio2 volevo far una statistica media per mese e quindi volevo che mi riconoscesse in Foglio1 dove c'è "Giu-2016" e mi facesse la media di tutti i valori della seconda colonna di tale mese

    Giugno 2016 19,3
    Luglio 2016 12,5


    Come posso fare?

    Grazie!

  2. #2
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126

    Re: Ricerca mese per statistica

    Ciao Baldo Giovane
    Se non vuoi scomodare il VBA eccoti qui una formula Matricile da confermare con i tasti CTRL+SHIFT+ENTER

    in B8 e trascina giù

    =MEDIA(SE(TESTO(A$1:A$5;"mmmm")=A8;B$1:B$5))

    A
    B
    1
    11-giu-16
    25
    2
    15-giu-16
    22
    3
    28-giu-16
    11
    4
    02-lug-16
    10
    5
    05-lug-16
    15
    6
    7
    8
    giugno
    19,33333333
    9
    luglio
    12,5


    ----------Post unito in automatico----------

    Oppure una formula con un approccio un po diverso

    =MEDIA(SE(MESE($A$1:$A$5)=MESE(A8&1);$B$1:$B$5))

    Saluti

  3. #3

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7161
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2065
    Likes dati
    1301

    Re: Ricerca mese per statistica

    Ciao,
    aggiungo ancora due alternative alle formule a quelle proposte da Gerardo, che saluto:

    Per la media di giugno:

    =MATR.SOMMA.PRODOTTO((MESE(A1:A5)=MESE(A1))*(B1:B5))/MATR.SOMMA.PRODOTTO((MESE(A1:A5)=MESE(A1))*1)

    Per la media di luglio:

    =MATR.SOMMA.PRODOTTO((MESE(A1:A5)=MESE(A4))*(B1:B5))/MATR.SOMMA.PRODOTTO((MESE(A1:A5)=MESE(A4))*1)

    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  4. #4

    L'avatar di Rubik72
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Cosenza
    Età
    45
    Messaggi
    2810
    Versione Office
    Excel 2013
    Likes ricevuti
    1022
    Likes dati
    979

    Re: Ricerca mese per statistica

    Ciao a tutti, giusto per partecipare propongo la versione matriciale (CTRL+SHIFT+ENTER)

    =SOMMA((MESE($A$1:$A$5)=MESE(A8&0))*($B$1:$B$5))/SOMMA((MESE($A$1:$A$5)=MESE(A8&0))*1)

  5. #5
    L'avatar di BaldoGiovane
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Verona
    Età
    32
    Messaggi
    41
    Versione Office
    2010
    Likes ricevuti
    0
    Likes dati
    0

    Re: Ricerca mese per statistica

    Citazione Originariamente Scritto da Rubik72 Visualizza Messaggio
    Ciao a tutti, giusto per partecipare propongo la versione matriciale (CTRL+SHIFT+ENTER)

    =SOMMA((MESE($A$1:$A$5)=MESE(A8&0))*($B$1:$B$5))/SOMMA((MESE($A$1:$A$5)=MESE(A8&0))*1)
    Grazie a tutti!!

    scusate son rimbambito, non volevo la media ma la somma delle cifre di ogni mese

    Se fosse in fogli diversi tabella e statistica?

  6. #6

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7161
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2065
    Likes dati
    1301

    Re: Ricerca mese per statistica

    Citazione Originariamente Scritto da BaldoGiovane Visualizza Messaggio
    Grazie a tutti!!

    ...
    Se fosse in fogli diversi tabella e statistica?
    Allega un file excel come esempio.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  7. #7

    L'avatar di Rubik72
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Cosenza
    Età
    45
    Messaggi
    2810
    Versione Office
    Excel 2013
    Likes ricevuti
    1022
    Likes dati
    979

    Re: Ricerca mese per statistica

    Citazione Originariamente Scritto da BaldoGiovane Visualizza Messaggio
    Grazie a tutti!!

    scusate son rimbambito, non volevo la media ma la somma delle cifre di ogni mese

    Se fosse in fogli diversi tabella e statistica?
    Allora solo:

    =SOMMA((MESE($A$1:$A$5)=MESE(A8&0))*($B$1:$B$5))

    Sempre con CTRL+SHIFT+ENTER

  8. #8
    L'avatar di BaldoGiovane
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Verona
    Età
    32
    Messaggi
    41
    Versione Office
    2010
    Likes ricevuti
    0
    Likes dati
    0

    Re: Ricerca mese per statistica

    Funziona, perfetto!! se la statistica la volessi fare su un altro Foglio?

  9. #9
    L'avatar di rollis13
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Cordenons
    Messaggi
    820
    Versione Office
    2016 64bit
    Likes ricevuti
    148
    Likes dati
    54

    Re: Ricerca mese per statistica

    Puoi fare Taglia/Incolla delle celle con riferimento mese e formula che hai già nel Foglio1 e le sposti in Foglio2.
    La formula di Rubik72 ora sarà qualcosa così (e sempre matriciale):

    =SOMMA((MESE(Foglio1!$A$1:$A$5)=MESE(A8))*(Foglio1!$B$1:$B$5))

  10. #10
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126

    Re: Ricerca mese per statistica

    Citazione Originariamente Scritto da BaldoGiovane Visualizza Messaggio
    Funziona, perfetto!! se la statistica la volessi fare su un altro Foglio?

    =SOMMA((MESE(nomefoglio!$A$1:$A$5)=MESE(nomefoglio!A8&0))*(nomefoglio!$B$1:$B$5))

    Con l'ultima formula di Rubik () dovresti mettere il nome del foglio (vedi rosso)

    [EDIT]

    Opps Rolando non ti avevo visto!

  11. #11
    L'avatar di BaldoGiovane
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Verona
    Età
    32
    Messaggi
    41
    Versione Office
    2010
    Likes ricevuti
    0
    Likes dati
    0

    Re: Ricerca mese per statistica

    Perfetto, però ho alcuni problemi con il riconoscimento del mese

    29-Gen-2016, questo è il formato...

    vorrei che mi riconoscesse ad esempio solo il Gennaio 2016 e non 2015... e con la formula attuale trova tutti

    ps. ho notato che funziona solo se il sistema cerca tra celle in cui c'è del testo.... solo che lui deve cercare in una lista in continua creazione e non posso aggiornare il numero di riga ogni volta che inserisco un nuovo valore

    cioè quello che voi mettete tra A1 e A5.... va bene solo se da A1 ad A5 c'è del testo... ma io avrei bisogno di farlo cercare da A1 fino ad A? dove ? sta per l'ultimo record inserito che oggi è A5 ma magari domani A16 e dopodomani A27

  12. #12
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126

    Re: Ricerca mese per statistica

    Ciao BaldoGiovane, scusa se ti rispondo solo adesso, ma questa mi era sfuggita

    tu scrivi:
    vorrei che mi riconoscesse ad esempio solo il Gennaio 2016 e non 2015... e con la formula attuale trova tutti
    è semplice basta aggiungere un'altra condizione *(ANNO(nomefoglio!$A$1:$A$5=2015)

    Tu scrivi:
    solo che lui deve cercare in una lista in continua creazione e non posso aggiornare il numero di riga ogni volta che inserisco un nuovo valore
    Si puo fare con intervalli dinamici, inserendo una formula con la funzione SCARTO in un nome definito o ancora meglio con lo strumento Tabelle

    Prova ad inserire un piccolo file di excel come esempio (senza dati sensibili) cosi da vedere meglio cosa c'è da fare
    Ciao

  13. I seguenti utenti hanno dato un "Like"


  14. #13
    L'avatar di BaldoGiovane
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Verona
    Età
    32
    Messaggi
    41
    Versione Office
    2010
    Likes ricevuti
    0
    Likes dati
    0

    Re: Ricerca mese per statistica

    eccolo

    grazie
    File Allegati File Allegati

  15. #14

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7161
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2065
    Likes dati
    1301

    Re: Ricerca mese per statistica

    Ciao,
    una soluzione con questa formula:

    =MATR.SOMMA.PRODOTTO((MESE(Dati!$A$1:$A$14)=MESE(B4))*(ANNO(Dati!$A$1:$A$14)=ANNO(B4))*(Dati!$B$1:$B$14))


    File Allegati File Allegati
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  16. #15
    L'avatar di Pitagora
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Milano
    Età
    54
    Messaggi
    782
    Versione Office
    WIN , 2013 2016
    Likes ricevuti
    318
    Likes dati
    1

    Re: Ricerca mese per statistica

    Buona Sera

    Ho ampliato la formule dal 2015 a seguire

    =MATR.SOMMA.PRODOTTO((MESE(Dati!$A$1:$A$1000)=MESE(Statistica!$B4))*(ANNO(Dati!$A$1:$A$1000)=Statistica!C$3)*(Dati!$B$1:$B$1000))

    Saluti






    File Allegati File Allegati
    Window 8.1 Excel 2013/2016

  17. #16
    L'avatar di BaldoGiovane
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Verona
    Età
    32
    Messaggi
    41
    Versione Office
    2010
    Likes ricevuti
    0
    Likes dati
    0

    Re: Ricerca mese per statistica

    Ringrazio tutti, sempre magnifici! Pitagora grazie funziona alla perfezione!

Discussioni Simili

  1. excel scalare ferie annuali mese mese ad ore
    Di babi66v nel forum Domande su Excel in generale
    Risposte: 1
    Ultimo Messaggio: 09/03/17, 14:26
  2. [Risolto] ricerca 1 3 lunedè del mese
    Di KARLO16 nel forum Domande su Excel in generale
    Risposte: 5
    Ultimo Messaggio: 21/10/16, 21:38
  3. Problemi di statistica con excel
    Di Franz nel forum Domande su Excel in generale
    Risposte: 5
    Ultimo Messaggio: 12/09/16, 14:37
  4. Ricerca giorni mancanti a fine mese e mese successivo
    Di pixartao nel forum Domande su Excel in generale
    Risposte: 3
    Ultimo Messaggio: 02/08/16, 15:08
  5. Conteggio servizi personale mese per mese
    Di pinnighi nel forum Domande su Excel in generale
    Risposte: 4
    Ultimo Messaggio: 06/06/16, 16:20

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •