Risultati da 1 a 28 di 28

Discussione: Doppioni in ordine alfabetico



  1. #1

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299

    Doppioni in ordine alfabetico

    Salve a tutti, colgo l'invito di Gerardo per proporre un quiz.

    Abbiamo diverse volte affrontato la casistiche dei doppioni di numeri, date di nascita, ecc. questa volta si tratta di mettere in ordine alfabetico dei casi di uguaglianza di età.

    A
    B
    C
    D
    E
    F
    G
    1
    COGNOME NOME ETA' COGNOME NOME ETA'
    2
    Rossi Mario
    35
    Azzurri Michele
    35
    3
    Neri Giulia
    46
    Rossi Mario
    35
    4
    Verdi Antonio
    35
    Verdi Antonio
    35
    5
    Gialli Maria
    51
    Marroni Giuseppe
    46
    6
    Marroni Giuseppe
    46
    Neri Giulia
    46
    7
    Bianchi Filippo
    51
    Bianchi Filippo
    51
    8
    Azzurri Michele
    35
    Gialli Maria
    51


    Nella prima parte ho dei nomi e cognomi con le rispettive età, ho bisogno - oltre ad una formula in G2 che mi ordini le età dal più piccolo al più grande - anche una formula in E2 (e rispettivamente una in F2) che mi ordini i cognomi di chi hanno la stessa età in ordine alfabetico.

    Sinceramente non ho la soluzione, propongo il quiz facendo anch'io delle prove.

    Buon divertimento.:90:
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  2. #2

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299
    Ragazzi .... ci sono riuscito! :28:

    Credo di aver trovato la formula che oltre a mettere in ordine di età mette anche in ordine alfabetico i nomi, aspetto fino a domani a postarla, intanto vediamo se qualcuno ha delle soluzioni.
    Adesso sono con la testa nel pallone, ci ho sbattuto sopra tutta la serata!!!:235:
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  3. #3
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Ciao Ges
    Grazie per la domande che fanno bene a tutti esperti e non

    in G2 e copia in basso

    =PICCOLO($C$2:$C$8;RIGHE($G$2:G2))

    in E2 incolla questa formula e attivala con CTRL+SHIFT+ENTER trascinala fino in F2 e poi in basso

    =INDICE(A$2:A$8;GRANDE(SE($C$2:$C$8=$G2;RIF.RIGA($B$2:$B$8)-RIF.RIGA($B$2)+1);CONTA.SE($G$2:$G2;$G2)))

    Ps purtroppo non sono riuscito a metterli in ordine alfabetico, ho fatto una forzatura con la funzione GRANDE anzichè PICCOLO ma ovviamnte va bene per questo piccolo data set disposto in questo modo

    in attesa di altre soluzioni :302:
    ciao a tutti

  4. #4

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299
    Ciao Gerardo, pur con due formule hai fatto proprio un bel lavoro, funzionano egregiamente, complimenti.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  5. #5

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4017
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Buongiorno ragazzi,
    avrei voluto avere più tempo ma devo scappare...
    Per il momento son riuscito solo a ordinare in base all'età. Proverò più tardi, ma non avrò il pc, quindi se dovessi riuscire a tirare fuori qualcosa dovreste controllare se funziona :127:

    Questa da mettere in E2 e copiare in basso e a destra:
    =INDICE($A$2:$C$8;CONFRONTA(PICCOLO($C$2:$C$8+RIF.RIGA($C$2:$C$8)/100;RIF.RIGA()-1);$C$2:$C$8+RIF.RIGA($C$2:$C$8)/100;0);RIF.COLONNA(A2))

    A dopo :43:

  6. #6

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4017
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Ri-ciao
    come vi ho detto prima, non ho potuto provarla... potreste controllare se funziona?

    Questa dovrebbe ordinare anche per ordine alfabetico (matriciale, da mettere in E2 e copiare in basso e a destra):

    =INDICE($A$2:$C$8;CONFRONTA(PICCOLO($C$2:$C$8*100+CODICE($A$2:$A$8)+RIF.RIGA($A$2:$A$8)/100;RIF.RIGA()-1);$C$2:$C$8*100+CODICE($A$2:$A$8)+RIF.RIGA($A$2:$A$8)/100;0);RIF.COLONNA(A2))

  7. #7

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299
    Ciao cromagno, ottima idea quella di usare "codice", la formula funziona benissimo se si fa riferimento alla tabella proposta, ma se si cambia qualche cognome allora sballa.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  8. #8

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4017
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Ok.
    Grazie per aver provato :)

  9. #9
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1664
    Versione Office
    2010 PC
    Likes ricevuti
    892
    Likes dati
    184
    cromagno, complimenti! , bella la trovata di CODICE(), ma con quel RIF.RIGA()-1, l'hai resa "delicata", in mano a chi non la comprende bene, gli faresti perdere la bussola :271:, opterei per RIGHE($E$2:E2)

  10. #10

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4017
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Ciao ninai (e grazie :) ),
    in effetti con la funzione RIGHE si intuisce meglio ;)

  11. #11
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1664
    Versione Office
    2010 PC
    Likes ricevuti
    892
    Likes dati
    184
    Citazione Originariamente Scritto da ges Visualizza Messaggio
    ........., ma se si cambia qualche cognome allora sballa.
    a me sembra funzionare, non è per caso usi minuscole??? ( il codice cambia)

  12. #12
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1664
    Versione Office
    2010 PC
    Likes ricevuti
    892
    Likes dati
    184
    Citazione Originariamente Scritto da cromagno Visualizza Messaggio
    Ciao ninai (e grazie :) ),
    in effetti con la funzione RIGHE si intuisce meglio ;)
    Più che altro la puoi usare per qualunque riga iniziale

  13. #13

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299
    Citazione Originariamente Scritto da ninai Visualizza Messaggio
    a me sembra funzionare, non è per caso usi minuscole??? ( il codice cambia)
    Vero, inavvertitamente ho usato minuscole, ma comunque anche se si utilizzano maiuscole e la prima lettera della parola è uguale la formula non da un ordine alfabetico, esempio se sostituisci "Galli Filippo" al posto di "Bianchi Filippo" lo posiziona sotto "Gialli Maria", ovviamente la funzione CODICE legge solo la prima lettera.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  14. #14

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4017
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Beh si, se c'è la possibilità di avere anche iniziali in minuscolo, bisognerebbe integrare anche la funzione MAIUSC o MAIUSC.INIZ:

    ....CODICE(MAIUSC(range))... etc..

    [EDIT]
    @ges
    Ho letto adesso il tuo ultimo post....
    Ultima modifica fatta da:cromagno; 21/08/15 alle 13:51

  15. #15

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299
    Cromagno la tua formula è veramente eccezionale, a sapere poi che l'hai fatta senza computer è una cosa grandiosa, io non ci sarei mai riuscito; purtroppo, come ho scritto sopra, anche se risolviamo il problema del minuscolo e maiuscolo resta quello delle iniziali uguali, che - secondo le mie prove - dovrebbe invece funzionare.
    Pomeriggio posto la mia formula così mi potete dare anche voi tutti un parere, sperando che non sia uno dei miei soliti strafalcioni che, col contributo del mio excel su mac, continuo a fare. :127:
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  16. #16

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299
    Allora … la mia formula (che mi ha fatto sbattere la testa per un'intera serata) per mettere in ordine crescente (o decrescente a seconda dell’impiego della funzione PICCOLO o GRANDE) oltre la parte numerica anche quella alfabetica, da trascinare a destra e in basso (naturalmente CTRL, SHIFT + INVIO), è la seguente :

    =INDICE(A$2:A$8;CONFRONTA(PICCOLO($C$2:$C$8+(CONTA.SE($A$2:$A$8;"<="&$A$2:$A$8))/100-RIF.RIGA($C$2:$C$8)/10000;RIF.RIGA(H5)-RIF.RIGA($H$4));$C$2:$C$8+(CONTA.SE($A$2:$A$8;"<="&$A$2:$A$8))/100-RIF.RIGA($C$2:$C$8)/10000;0))


    In pratica, si tratta dell’unione di due formule:


    1) Quella classica che mette in ordine numericamente INDICE, CONFONTA, PICCOLO, precisamente:

    =INDICE(A$2:A$8;CONFRONTA(PICCOLO($C$2:$C$8+RIF.RIGA($A$2:$A$8)/100000;RIF.RIGA(A1));$C$2:$C$8+RIF.RIGA($A$2:$A$8)/100000;0))


    2) e quella che ordina la parte alfabetica, CONTA.SE , precisamente:

    =CONTA.SE($A$2:$A$8;"<="&A2)

    se trasciniamo questa formula verso il basso ci da l’esatta posizione dei nomi in rigoroso ordine alfabetico, indipendentemente se maiuscole o minuscole.


    Io ho fatto tante prove e ha sempre funzionato, fatemi sapere.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  17. #17

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299
    Con anche delle prove estreme sembra la formula =CONTA.SE($I$2:$I$6;"<="&I2) sembra funzioni:

    I
    J
    2
    aaaaaaaaaabbcc
    1
    3
    aaaaaaaaccdd
    2
    4
    aaaaaaddee
    5
    5
    aaaaaaaeeff
    3
    6
    aaaaaaaffgg
    4
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  18. #18

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4017
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Sono ancora senza pc, ma appena riavuto cercherò di far di tutto per non farla funzionare :258:...
    Scherzo, sono sicuro che è perfetta :269:
    Ho visto che hai diviso per 10000 e 100000. Hai intenzione di usarla per qualche censimento? :258:
    Scherzi a parte... complimenti!!!

    [EDIT]
    Questo file va a finire nel mio archivio "Utili" ;)
    Ultima modifica fatta da:cromagno; 21/08/15 alle 17:03

  19. #19

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299
    Citazione Originariamente Scritto da cromagno Visualizza Messaggio
    ........Sono ancora senza pc, ma appena riavuto cercherò di far di tutto per non farla funzionare :258:...
    ..
    Allora non ho scampo!!!:93: ..... Anche se non è detto che qualcuno ci arrivi prima di te! :127:

    Scherzi a parte anche da parte mia, la formule si condividono, oltre che come accrescimento della conoscenza, anche per testarne i punti di forza e di debolezza ... se li conosci ... puoi evitarli! :90:

    Ciao Cromagno
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  20. #20

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4017
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Ma, controllando:
    =CONTA.SE($I$2:$I$6;"<="&I2)

    con "Valuta formula" dà qualche informazione in più?
    Cioè, capisco cosa fa ma non il perchè lo fa, trattandosi di lettere e non avendo dato nessuna indicazione su come si deve comportare. Comunque, buono a sapersi.

  21. #21
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Citazione Originariamente Scritto da ges Visualizza Messaggio
    Allora … la mia formula (che mi ha fatto sbattere la testa per un'intera serata) per mettere in ordine crescente (o decrescente a seconda dell’impiego della funzione PICCOLO o GRANDE) oltre la parte numerica anche quella alfabetica, da trascinare a destra e in basso (naturalmente CTRL, SHIFT + INVIO), è la seguente :

    =INDICE(A$2:A$8;CONFRONTA(PICCOLO($C$2:$C$8+(CONTA.SE($A$2:$A$8;"<="&$A$2:$A$8))/100-RIF.RIGA($C$2:$C$8)/10000;RIF.RIGA(H5)-RIF.RIGA($H$4));$C$2:$C$8+(CONTA.SE($A$2:$A$8;"<="&$A$2:$A$8))/100-RIF.RIGA($C$2:$C$8)/10000;0))
    Grande Ges!!!
    Credo che anch'io custodirò gelosamente questa formula
    Adesso me la studio bene con lo strumento "Valuta Formula" o con il tasto F9 e come se non bastasse mi salvo Questa discussione si merita nei preferiti del mio Browser
    chissaà magari un giorno ci faccio anche un video!!

    :156:
    Ultima modifica fatta da:Gerardo Zuccalà; 21/08/15 alle 18:20

  22. #22

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299
    Grazie Gerardo... ci mancano però i tuoi video, adesso che di materiale ne hai tanto dovresti mettere in conto di ricominciare! :90:
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  23. #23
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Citazione Originariamente Scritto da ges Visualizza Messaggio
    Grazie Gerardo... ci mancano però i tuoi video, adesso che di materiale ne hai tanto dovresti mettere in conto di ricominciare! :90:
    hahha è vero ho tanto materiale ma ho pochissimo tempo, credemi che per fare un video a volte va via mezza giornata...
    comunque l'ultimo video l'ho caricato l'altro ieri gaurda la home di questo forum, e vedrai che ho incorporato l'ultimo video!!
    Invece ges mi mancano i tuoi Quiz!!
    Ciao:222:

  24. #24
    L'avatar di _Carlo
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Caserta
    Messaggi
    3
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    0
    Scusate se mi intrometto...
    Premesso che le vostre formule sono fantastiche, funzionano benissimo, e che io non ho la vostra preparazione.
    Io avrei la necessità di ordinare i soggetti in ordine decrescente di età, cioè dal più grande al più piccolo, conservando l'ordine alfabetico dei cognomi.
    Ultima modifica fatta da:_Carlo; 01/09/15 alle 12:44

  25. #25

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299
    Ciao Carlo,
    per quello che devi fare basta che usi la mia formula che ho scritto sopra.

    In ogni caso, ti consiglio di aprire una nuova discussione sottoponendoci il tuo problema e allegando un file dell'esempio che vuoi ottenere.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  26. #26
    L'avatar di _Carlo
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Caserta
    Messaggi
    3
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    0
    Ciao ges
    Io mi riferivo proprio al tuo quesito e alla tua formula.
    Ho provato a sostituire la funzione piccolo con grande, mi ordina i soggetti in ordine decrescente di età ma non i cognomi dei soggetti che hanno la stessa età

  27. #27

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299
    Citazione Originariamente Scritto da _Carlo Visualizza Messaggio
    Ciao ges
    Io mi riferivo proprio al tuo quesito e alla tua formula.
    Ho provato a sostituire la funzione piccolo con grande, mi ordina i soggetti in ordine decrescente di età ma non i cognomi dei soggetti che hanno la stessa età
    Certo! Quando sostituisci PICCOLO con GRANDE per riordinare i cognomi stai dicendo a excel che li vuoi in ordine dalla Z alla A e quindi logicamente li inverte, come allo stesso modo inverte l'età.

    Pertanto devi giustamente cambiare la formula da PICCOLO a GRANDE ma devi anche cambiare il criterio di ordine (cioè il CONTA.SE) e quindi la formula diventa così:

    =INDICE(A$2:A$8;CONFRONTA(GRANDE($C$2:$C$8+(CONTA.SE($A$2:$A$8;">="&$A$2:$A$8))/100-RIF.RIGA($C$2:$C$8)/10000;RIF.RIGA(H5)-RIF.RIGA($H$4));$C$2:$C$8+(CONTA.SE($A$2:$A$8;">="&$A$2:$A$8))/100-RIF.RIGA($C$2:$C$8)/10000;0))
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  28. #28
    L'avatar di _Carlo
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Caserta
    Messaggi
    3
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    0
    Grazie... adesso è perfetta :246:

Discussioni Simili

  1. [Risolto] ordine alfabetico dopo le funzioni Indice e Confronta
    Di vittorio dit nel forum Domande su Excel in generale
    Risposte: 6
    Ultimo Messaggio: 17/11/16, 12:40
  2. Problema con ordine alfabetico
    Di Anastasyah28 nel forum Domande su Excel in generale
    Risposte: 4
    Ultimo Messaggio: 29/09/16, 23:57
  3. Mettere in ordine alfabetico un questionario
    Di il principe nel forum Domande su Excel in generale
    Risposte: 29
    Ultimo Messaggio: 14/08/16, 10:49
  4. ordine alfabetico
    Di marcotirozzi nel forum Domande su Excel in generale
    Risposte: 9
    Ultimo Messaggio: 05/07/16, 14:05
  5. Mi serve una formula che mette tutto in ordine alfabetico.
    Di Francesco nel forum Domande su Excel in generale
    Risposte: 15
    Ultimo Messaggio: 25/03/16, 11:24

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •