Risultati da 1 a 10 di 10

Discussione: somma.più.se con criteri appartenenti allo stesso intervallo_criteri



  1. #1
    L'avatar di Francesco Lavista
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Piombino , (LI)
    Messaggi
    24
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    4

    somma.più.se con criteri appartenenti allo stesso intervallo_criteri

    Salve. La mia domanda riguarda appunto la formula somma.più.se e in particolare la vorrei usare scegliendo i criteri appartenenti allo stesso intervallo criteri.
    Supponiamo di avere una tabella dove nelle colonne sono riportati vari dati; ad esempio:


    A B C D
    1 Anni Spese Guadagni Investimenti
    2 2010 24 51 89
    3 2011 31 21 56
    4 2012 45 78 55
    5 2013 91 47 33
    6 2014 44 10 61
    7 2015
    8
















    Se volessi calcolare la somma delle spese sostenute negli Anni 2010, 2011, e 2014 usando somma.più.se come procedo? Ho fatto alcuni tentativi ma il risultato viene sempre 0. Cosicché mi chiedo: ma è possibile usare somma.più.se con criteri che appartengono allo stesso intervallo_criteri? Grazie
    Ultima modifica fatta da:Francesco Lavista; 21/08/15 alle 14:05

  2. #2

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Verona Provincia
    Età
    57
    Messaggi
    1017
    Versione Office
    .
    Likes ricevuti
    366
    Likes dati
    0
    Cosicché mi chiedo: ma è possibile usare somma.più.se con criteri che appartengono allo stesso intervallo_criteri?
    I criteri sono legati dalla condizione E, quindi è normale che una formula tipo
    =SOMMA.PIÙ.SE(B2:B7;A2:A7;2010;A2:A7;2011;A2:A7;2014)
    ti restituisca 0: la cella A2 per entrare nella somma dovrebbe soddisfare la condizione E(A2=2010; A2=2011;A2=2014), e così le altre celle

    Non devi usare Somma.Piu.Se ma Somma.Se():
    =SOMMA.SE(A2:A7;2010;B2:B7)+SOMMA.SE(A2:A7;2011;B2:B7)+SOMMA.SE(A2:A7;2014;B2:B7)

    che puoi condensare in
    =SOMMA(SOMMA.SE(A2:A7;{2010.2011.2014};B2:B7))

    Oppure ancora Matr.Somma.Prodotto():
    =MATR.SOMMA.PRODOTTO(((A2:A7=2010)+(A2:A7=2011)+(A2:A7=2014))*(B2:B7))

    oppure ancora Somma():
    =SOMMA(B2:B7*(A2:A7={2010\2011\2014}))
    matriciale da confermare con ctrl+maiusc+invio
    Bye!
    scossa
    scossa's web site
    ___
    Se tu hai una mela, e io ho una mela, e ce le scambiamo, allora tu ed io abbiamo sempre una mela per uno. Ma se tu hai un'idea, ed io ho un'idea, e ce le scambiamo, allora abbiamo entrambi due idee. (George Bernard Shaw)

  3. #3
    L'avatar di Francesco Lavista
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Piombino , (LI)
    Messaggi
    24
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    4
    Grazie Scossa per la tua risposta e sopratutto grazie per le tue spiegazioni. Ciao a presto

  4. #4

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Verona Provincia
    Età
    57
    Messaggi
    1017
    Versione Office
    .
    Likes ricevuti
    366
    Likes dati
    0
    Oppure ancora Matr.Somma.Prodotto():
    =MATR.SOMMA.PRODOTTO(((A2:A7=2010)+(A2:A7=2011)+(A2:A7=2014))*(B2:B7))
    dimenticavo: anch'essa condensabile in

    =MATR.SOMMA.PRODOTTO((A2:A7={2010\2011\2014})*(B2:B7))
    Bye!
    scossa
    scossa's web site
    ___
    Se tu hai una mela, e io ho una mela, e ce le scambiamo, allora tu ed io abbiamo sempre una mela per uno. Ma se tu hai un'idea, ed io ho un'idea, e ce le scambiamo, allora abbiamo entrambi due idee. (George Bernard Shaw)

  5. #5

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7131
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299
    Oltre gli ottimi consigli e formule di scossa, se invece hai bisogno di diversificare gli importi dal 2010 in base agli anni successivi, ti potrebbe essere comoda una convalida dati, come nell'esempio che allego (il risultato l'ho creato con una formula, anche se lunga, semplicissima e spero chiara).
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  6. #6
    L'avatar di Francesco Lavista
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Piombino , (LI)
    Messaggi
    24
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    4
    Hai ragione Ges un po lunga ma aggiungerei efficace. Grazie ancora e a presto

  7. #7

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Verona Provincia
    Età
    57
    Messaggi
    1017
    Versione Office
    .
    Likes ricevuti
    366
    Likes dati
    0
    il risultato l'ho creato con una formula, anche se lunga, semplicissima e spero chiara
    Ottima idea, la formula è chiara.

    Giusto per ulteriore informazione, può essere condensata in

    =MATR.SOMMA.PRODOTTO((B2:B7)*(A2:A7<=F3))
    da confermare con il semplice invio.
    Bye!
    scossa
    scossa's web site
    ___
    Se tu hai una mela, e io ho una mela, e ce le scambiamo, allora tu ed io abbiamo sempre una mela per uno. Ma se tu hai un'idea, ed io ho un'idea, e ce le scambiamo, allora abbiamo entrambi due idee. (George Bernard Shaw)

  8. #8
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Citazione Originariamente Scritto da Francesco Lavista Visualizza Messaggio
    Salve. La mia domanda riguarda appunto la formula somma.più.se e in particolare la vorrei usare scegliendo i criteri appartenenti allo stesso intervallo criteri.
    Ciao Francesco e Ciao a tutti gli amici del forum
    mi allaccio alla domanda iniziale di Francesco che chiedeva se si poteva fare qualcosa con il SOMMA.PIU.SE
    ed ecco la mia soluzione

    =MATR.SOMMA.PRODOTTO(SOMMA.PIÙ.SE(B2:B7;A2:A7;{2010.2011}))

    funziona benissimo
    anche se questa funzione è nata per sommare con piu criteri non della stessa colonna, ma io ho fatto una forzatura e ho messo più criteri (date) all'nterno del Criterio1


    la mia formula per questo motivo potrebbe essere considerata ambigua indi per cui potresti usare la formula di scossa

    =SOMMA(SOMMA.SE(A2:A7;{2010.2011.2014};B2:B7))

    con una piccola variazione cosi non devi fare CTRL+SHIFT+ENTER

    =MATR.SOMMA.PRODOTTO(SOMMA.SE(A2:A7;{2010.2011.2014};B2:B7))

    Comunque Francesco ti suggerisco di mettere il criterio in una cella esterna cosi qunado vuoi analizzare il tuo database con differenti date bastera semplicemente cambiare le date nelle celle di input senza riaprire la formula e riscriverla in alcuni argomenti
    Ciao a tutti






    Ultima modifica fatta da:Gerardo Zuccalà; 21/08/15 alle 18:04

  9. #9

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Verona Provincia
    Età
    57
    Messaggi
    1017
    Versione Office
    .
    Likes ricevuti
    366
    Likes dati
    0
    @Gerardo: =SOMMA(SOMMA.SE(A2:A7;{2010.2011.2014};B2:B7)) non è matriciale e non necessita di ctrl-maius+invio per essere confermata, ma solo di invio.
    Bye!
    scossa
    scossa's web site
    ___
    Se tu hai una mela, e io ho una mela, e ce le scambiamo, allora tu ed io abbiamo sempre una mela per uno. Ma se tu hai un'idea, ed io ho un'idea, e ce le scambiamo, allora abbiamo entrambi due idee. (George Bernard Shaw)

  10. #10
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Citazione Originariamente Scritto da scossa Visualizza Messaggio
    @Gerardo: =SOMMA(SOMMA.SE(A2:A7;{2010.2011.2014};B2:B7)) non è matriciale e non necessita di ctrl-maius+invio per essere confermata, ma solo di invio.
    :216: hai ragione avrei dovuto testarla prima di scrivere, mi sono confuso con il =SOMMA(SE..... invece è =SOMMA.SE(
    Scossa Grazie per le tua professionalità che metti in campo e solo cosi che si può migliorare
    Ciao

Discussioni Simili

  1. Casella abbinata sempre allo stesso giorno
    Di svizzera nel forum Domande su Excel in generale
    Risposte: 15
    Ultimo Messaggio: 31/12/16, 09:20
  2. Somma valori con criteri temporali
    Di damiaà nel forum Domande su Excel in generale
    Risposte: 12
    Ultimo Messaggio: 28/06/16, 11:13
  3. somma con criteri
    Di ROBYVMG nel forum Domande su Excel in generale
    Risposte: 12
    Ultimo Messaggio: 25/12/15, 13:32
  4. Ricerca con criteri somma
    Di BRAZ66 nel forum Domande su Excel in generale
    Risposte: 6
    Ultimo Messaggio: 03/08/15, 22:42
  5. Quiz #14 Somma con due criteri
    Di Gerardo Zuccalà nel forum Domande su Excel in generale
    Risposte: 9
    Ultimo Messaggio: 28/06/15, 18:34

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •