Risultati da 1 a 9 di 9

Discussione: Ripartizione forecast in base al negozio



  1. #1
    L'avatar di Barchetta
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    51013
    Età
    44
    Messaggi
    47
    Versione Office
    Excel 2013
    Mi Piace ricevuti
    0
    Mi Piace dati
    5

    Ripartizione forecast in base al negozio

    Ciao, ho un piccolo dilemma che non riesco a risolvere.
    Ho 6 negozi identificati con negozio1, negozio2...
    3 sezioni ed ogni sezione ha una % d'incidenza per la suddivione del forecast.
    La formula inserita nella parte in verde funziona perfettamente se il forecast legato all'articolo deve essere suddiviso per tutti e i 6 negozi. Ma se l'articolo ha un forecast solo per 3 o 4 negozi come posso rendere dinamica la formula?
    Avevo pensato di aggiungere 6 colonne dove andare ad inserire una "X" che identifica a chi suddividere il forecast e in caso di assenza di"X" il forecast da suddividere sarebbe per tutti e sei i negozi.
    Come posso far calcolare la suddivisione in base alla X e chiaramente la % d'incidenza aumenta perchè la mancanza dei 3 negozi dovrà essere ripartizionata sui 3 che ritirano.

    Allego file di esempio
    Grazie
    File Allegati File Allegati
    Ultima modifica fatta da:Gerardo Zuccalà; 02/10/16 alle 23:22 Motivo: Messo risolto

  2. #2

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    36
    Messaggi
    2774
    Versione Office
    2016
    Mi Piace ricevuti
    799
    Mi Piace dati
    674

    Re: Ripartizione forecast in base al negozio

    Ciao,

    sempre che abbia capito bene, potresti usare questa formula matriciale (quindi da confermare con la combinazione di tasti CTRL+MAIUSC+INVIO anzichè solo con INVIO), da mettere nella cella L15 e poi copiare a destra ed in basso per tutta la tabella:

    =SE(E($B15<>"";E15="");0;SE.NON.DISP.(($D15/1)*INDICE($O$4:$Q$9;CONFRONTA(L$13;$N$4:$N$9;0);CONFRONTA($B15;$O$3:$Q$3;0))+SOMMA(MATR.TRASPOSTA(INDICE($O$4:$Q$9;;CONFRONTA($B15;$O$3:$Q$3;0))*$D15)*($E15:$J15<>"x"))/CONTA.SE($E15:$J15;"=x");"-"))


    ti riallego il file...
    File Allegati File Allegati

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  3. I seguenti 2 utenti hanno dato un MI Piace a cromagno per questo post:


  4. #3
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    54
    Messaggi
    1500
    Versione Office
    2010 PC
    Mi Piace ricevuti
    789
    Mi Piace dati
    154

    Re: Ripartizione forecast in base al negozio

    Ciao
    bella soluzione cromagno!!!

    mi permetto di fare qualche osservazione

    la parte finale della formula :
    /CONTA.SE($E15:$J15;"=x")

    divide in parti uguali la quota non oggetto di ripartizione percentuale.

    proporrei di dividere tale quota in proporzione all'incidenza percentuale del negozio, pertanto la TUA formula diventerebbe:

    =SE(E($B15<>"";E15="");0;$D15*INDICE($O$4:$Q$9;CONFRONTA(L$13;$N$4:$N$9;0);CONFRONTA($B15;$O$3:$Q$3;0))+SOMMA(MATR.TRASPOSTA(INDICE($O$4:$Q$9;;CONFRONTA($B15;$O$3:$Q$3;0))*$D15)*($E15:$J15<>"x"))*((E15<>"")*INDICE($O$4:$Q$9;CONFRONTA(L$13;$N$4:$N$9;0);CONFRONTA($B15;$O$3:$Q$3;0))/SOMMA(MATR.TRASPOSTA(INDICE($O$4:$Q$9;;CONFRONTA($B15;$O$3:$Q$3;0)))*($E15:$J15="x"))))

    ho tolto la gestione dell'errore (esclusiva per i successivi al 2010).

    per essere più chiaro, es.
    per i 50000 in D16:
    vengono ripartiti:
    16% negozio2
    20% negozio3
    20 negozio5
    per un totale del 56%
    il 44% rimanente (22000)
    invece di dividerlo in tre parti uguali (come nella tua formula originale)
    li ho ripartiti in base alla percentuale di incidenza dei tre negozi interessati:

    28,57% 35,71% 35,71%


    sicuramente è tutto semplificabile ma ho preferito accodarmi (comodamente) al tuo algoritmo
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  5. I seguenti 2 utenti hanno dato un MI Piace a ninai per questo post:


  6. #4
    L'avatar di Marius44
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Catania
    Età
    73
    Messaggi
    1578
    Versione Office
    Excel2007
    Mi Piace ricevuti
    401
    Mi Piace dati
    100

    Re: Ripartizione forecast in base al negozio

    Salve a tutti
    Dopo i doverosi complimenti a cromagno (ciao Tore) e a ninai (ciao Santo) ho tentato di seguire i consigli di quest'ultimo per cercare di "semplificare" la formula.

    Ho ottenuto questa MATRICIALE che, però, mi dà un problema. Nella prima riga è tutto OK, dalla seconda in poi sballa. Se dalla seconda riga in poi si aggiunge un ARROTONDA a 1 cifra, tutto OK ma sballa la prima riga.

    La formula in L9 (e poi trascinare a destra e in basso) è questa:

    Codice: 
    =SE(E9="x";$D9*INDICE($L$3:$Q$5;CONFRONTA(CERCA.VERT($C9;$T$3:$U$13;2;0);$K$3:$K$5;0);CONFRONTA(L$7;$L$2:$Q$2;0))/SOMMA(SE($E9:$J9="x";$L$3:$Q$3));"")
    Se in L10 (e poi trascinare a destra e in basso) mettiamo questa

    Codice: 
    =SE(E10="x";$D10*INDICE($L$3:$Q$5;CONFRONTA(CERCA.VERT($C10;$T$3:$U$13;2;0);$K$3:$K$5;0);CONFRONTA(L$7;$L$2:$Q$2;0))/ARROTONDA(SOMMA(SE($E10:$J10="x";$L$3:$Q$3));1);"")
    Nel file allegato (Foglio2) non è necessaria la colonna per la sezione (la trova la formula).

    Qualcuno che "mastica" le formule meglio di me può dare un'occhiata e spigarmi l'arcano? Grazie anticipate.

    Ciao,
    Mario
    File Allegati File Allegati

  7. I seguenti utenti hanno dato un "Mi Piace"


  8. #5

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    36
    Messaggi
    2774
    Versione Office
    2016
    Mi Piace ricevuti
    799
    Mi Piace dati
    674

    Re: Ripartizione forecast in base al negozio

    Ciao Mario,
    intanto complimenti perchè modificando leggermente la struttura delle tabelle non c'è più bisogno della conversione delle matrici con MATR.TRASPOSTA

    Per quanto riguarda la tua formula, funziona solo con la prima riga ( o meglio con la "sezione 1" ) a causa dei riferimenti assoluti che hai messo qui (in rosso) e che per l'appunto fanno riferimento sempre alla prima riga della tabella in L3:Q5:

    =SE(E9="x";$D9*INDICE($L$3:$Q$5;CONFRONTA(CERCA.VERT($C9;$T$3:$U$13;2;0);$K$3:$K$5;0);CONFRONTA(L$7;$L$2:$Q$2;0))/SOMMA(SE($E9:$J9="x";
    $L$3:$Q$3));"")

    quindi è necessario "allungarla" per rendere dinamici quei riferimenti:

    =SE(E9="x";$D9*INDICE($L$3:$Q$5;CONFRONTA(CERCA.VERT($C9;$T$3:$U$13;2;0);$K$3:$K$5;0);CONFRONTA(L$7;$L$2:$Q$2;0))/SOMMA(SE($E9:$J9="x";INDICE($L$3:$Q$5;CONFRONTA(CERCA.VERT($C9;$T$3:$U$13;2;0);$K$3:$K$5;0);)));"")

    Ciao
    Tore

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  9. I seguenti utenti hanno dato un "Mi Piace"


  10. #6
    L'avatar di Marius44
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Catania
    Età
    73
    Messaggi
    1578
    Versione Office
    Excel2007
    Mi Piace ricevuti
    401
    Mi Piace dati
    100

    Re: Ripartizione forecast in base al negozio

    Ciao Tore
    Grazie per la dritta. Quando si dice "cercar l'asino ed esserci a cavallo"

    E questo risolve, ovviamente, anche il problema con arrotonda.

    Ciao e ancora grazie,
    Mario

  11. #7
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    54
    Messaggi
    1500
    Versione Office
    2010 PC
    Mi Piace ricevuti
    789
    Mi Piace dati
    154

    Re: Ripartizione forecast in base al negozio

    ciao

    Mario
    sostituendo SOMMA(SE()) con MATR.SOMMA.PRODOTTO() si può evitare l'invio matriciale (è una seccatura, tuttora, dimenticando l'invio, a volte mi impallo)

    =SE(E9="x";$D9*INDICE($L$3:$Q$5;CONFRONTA(CERCA.VERT($C9;$T$3:$U$13;2;FALSO);$K$3:$K$5;0);CONFRONTA(L$7;$L$2:$Q$2;0))/MATR.SOMMA.PRODOTTO(INDICE($L$3:$Q$5;CONFRONTA(CERCA.VERT($C9;$T$3:$U$13;2;FALSO);$K$3:$K$5;0);)*($E9:$J9="x"));"")
    "So che spiegare il proprio problema, in modo comprensibile, richiede un certo impegno ed è un lavoro "palloso", ma qualcuno lo deve pur fare ....., indovina chi?" (Cit. "Scossa")

  12. #8
    L'avatar di Marius44
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Catania
    Età
    73
    Messaggi
    1578
    Versione Office
    Excel2007
    Mi Piace ricevuti
    401
    Mi Piace dati
    100

    Re: Ripartizione forecast in base al negozio

    Ciao Santo
    ovviamente, ottima soluzione.
    Ma, come sai, sto imparando le formule e ancora non sono arrivato a MATR.SOMMA.PRODOTTO

    Ciao e grazie anche a te,
    Mario

  13. #9
    L'avatar di Barchetta
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    51013
    Età
    44
    Messaggi
    47
    Versione Office
    Excel 2013
    Mi Piace ricevuti
    0
    Mi Piace dati
    5

    Re: Ripartizione forecast in base al negozio

    A dire che siete fenomeni sarei bugiardo, vi ringrazio tutti per l'aiuto.
    Il mio problema è stato risolto, adesso lascio a voi mitici scambi d idee e soluzioni.
    Grazie ancora

Discussioni Simili

  1. Macro trasformazione da Base 32 a Base 10.
    Di mirko.esposito nel forum Domande su Excel VBA e MACRO
    Risposte: 11
    Ultimo Messaggio: 03/11/16, 19:30
  2. [Risolto] Ripartizione Efficiente + Calcolo Schema
    Di Deeevil86 nel forum Domande su Excel VBA e MACRO
    Risposte: 32
    Ultimo Messaggio: 19/10/16, 15:59
  3. Ripartizione Efficiente + Calcolo Schema
    Di Deeevil86 nel forum Domande su Excel in generale
    Risposte: 1
    Ultimo Messaggio: 07/10/16, 15:32
  4. Ricerca Elenco Negozio per Responsabile
    Di Emanuele nel forum Domande su Excel in generale
    Risposte: 5
    Ultimo Messaggio: 22/01/16, 22:30
  5. seleziona in base all'eta' dal cf
    Di lim87 nel forum Domande su Excel in generale
    Risposte: 39
    Ultimo Messaggio: 13/01/16, 13:41

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •