Risultati da 1 a 13 di 13

Discussione: Pescare un valore all'interno di una tabella tramite coordinate



  1. #1
    L'avatar di quartafeira
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Italia
    Età
    35
    Messaggi
    23
    Versione Office
    2010
    Likes ricevuti
    1

    Pescare un valore all'interno di una tabella tramite coordinate

    Ciao a tutti,
    ho un problema che non riesco a risolvere, sto creando un file per gli orari di lavoro, fare i calcoli a fine mese e altro ancora, una delle cose che vorrei fare è far comparire in automatico l'orario di inizio e fine turno in base al giorno, visto che lavoro 5 giorni e poi ho un riposo, seguo una ciclazione, lavorando così sabato e domenica, per semplificare ho creato un file che allego, mettendo orari diversi (inventati) a seconda del giorno.
    Vorrei inserendo il giorno (lun mar mer...) ed il turno (Mattina Pomeriggio Sera) che compaia l'ora di inizio e fine turno tramite la tabella nel foglio successivo, un po' come se fosse la battaglia navale, avevo pensato ad un più se o modificando la tabella ad un cerca vert ma vorrei qualcosa di più immediato
    PS: ho cercato qualcosa su internet e mi sembra di aver capito che fanno al caso mio funzioni come db.valori indiretto o indice che però non ho capito come funzionano
    GRAZIE IN ANTICIPO!!!!!
    Invia MPPM 

  2. #2
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1657
    Versione Office
    2010 PC
    Likes ricevuti
    891
    Likes dati
    184
    ciao
    In base a come ho capito io, in B4:
    =CERCA.VERT(TESTO(B$1;"ggg");Foglio2!$A$2:$D$8;CONFRONTA(B$3;Foglio2!$A$1:$D$1;0);FALSO)

    in B5, cambi solo la matrice del Cerca.vert():
    =CERCA.VERT(TESTO(B$1;"ggg");Foglio2!$F$1:$I$8;CONFRONTA(B$3;Foglio2!$A$1:$D$1;0);FALSO)
    e trascini ambedue a destra.
    si può fare anche in vari altri modi.
    Invia MPPM 

  3. I seguenti utenti hanno dato un "Like"


  4. #3
    L'avatar di quartafeira
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Italia
    Età
    35
    Messaggi
    23
    Versione Office
    2010
    Likes ricevuti
    1
    Grazie mille Ninai!
    il risultato che volevo era proprio questo, con le mie conoscenze l'avrei fatto con il cerca.vert ma molto più complesso in quanto avrei fatto una lista immensa unendo il giorno ed il turno, avrei dato un nome alla matrice e nel cercavert del foglio1 avrei messo concatena e cercavert.
    Quali altri metodi ci sarebbero per pescare all'interno della griglia?
    C'è un metodo che si avvicini alla metodologia della battaglia navale, nel senso che dando i due riferimenti va ad incrociare il valore all'interno della griglia?
    Grazie!



    PS: ora mi vado a studiare bene confronta per capirlo meglio!
    Ultima modifica fatta da:Canapone; 28/06/17 alle 14:34
    Invia MPPM 

  5. #4
    L'avatar di Alessandro
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Roma
    Età
    45
    Messaggi
    851
    Versione Office
    2010 64 bit
    Likes ricevuti
    113
    Likes dati
    61
    un altro modo può esser questo:
    in B4
    =INDICE(Foglio2!$B$2:$D$8;CONFRONTA(TESTO(B2;"ggg");Foglio2!$A$2:$A$8);CONFRONTA(B3;Foglio2!$B$1:$D$1))
    in B5
    =INDICE(Foglio2!$G$2:$I$8;CONFRONTA(TESTO(B2;"ggg");Foglio2!$A$2:$A$8);CONFRONTA(B3;Foglio2!$B$1:$D$1))
    oppure volendo utilizzare i nomi
    in B4
    =INDICE(ent;CONFRONTA(TESTO(B2;"ggg");gg);CONFRONTA(B3;turn))
    in B5
    =INDICE(usc;CONFRONTA(TESTO(B2;"ggg");gg);CONFRONTA(B3;turn))
    dove
    ent=Foglio2!$B$2:$D$8
    gg=Foglio2!$A$2:$A$8
    turn=Foglio2!$B$1:$D$1
    usc=Foglio2!$G$2:$I$8
    ricordati il formato celle in B4 e B5.
    ciao
    ale
    Invia MPPM 

  6. I seguenti utenti hanno dato un "Like"


  7. #5
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1075
    Versione Office
    2010 su Win
    Likes ricevuti
    598
    Likes dati
    202
    Ciao a tutti,

    riprendo i ragionamenti di chi mi ha preceduto.

    Potremmo servirsi di somme condizionali

    =MATR.SOMMA.PRODOTTO((Foglio2!$A$2:$A$8=TESTO(B$1;"ggg"))*(Foglio2!$B$1:$D$1=B$3)*Foglio2!$B$2:$D$8)

    =MATR.SOMMA.PRODOTTO((Foglio2!$F$2:$F$8=TESTO(B$1;"ggg"))*(Foglio2!$G$1:$I$1=B$3)*Foglio2!$G$2:$I$8)

    In un INDICE per individuare la riga al posto dei CONFRONTA si potrebbe usare

    GIORNO.SETTIMANA(B$1;2)

    TROVA(B$3;"MPS")


    =INDICE(Foglio2!$B$2:$D$8;GIORNO.SETTIMANA(B$1;2);TROVA(B$3;"MPS"))

    =INDICE(Foglio2!$G$2:$I$8;GIORNO.SETTIMANA(B$1;2);TROVA(B$3;"MPS"))


    Solo per condividere altre idee. Non voglio creare confusione.

    Saluti
    Ultima modifica fatta da:Canapone; 22/09/15 alle 13:18
    Invia MPPM 

  8. I seguenti utenti hanno dato un "Like"


  9. #6
    L'avatar di quartafeira
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Italia
    Età
    35
    Messaggi
    23
    Versione Office
    2010
    Likes ricevuti
    1
    Grazie Ale, come torno a casa provo subito e mi studio la funzione indice, anche se l'avevo vista un po' di tempo fa e non avevo capito bene i campi matrice riga e col, ma con gli esempi sarà tutta un'altra storia.
    Grazie
    Invia MPPM 

  10. #7
    L'avatar di quartafeira
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Italia
    Età
    35
    Messaggi
    23
    Versione Office
    2010
    Likes ricevuti
    1
    Grazie Canapone, proverò anche questa nuova soluzione, prima mi studio le funzioni per capire come lavorano.
    Grazie a tutti!
    Ultima modifica fatta da:Canapone; 28/06/17 alle 14:35
    Invia MPPM 

  11. #8
    L'avatar di Alessandro
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Roma
    Età
    45
    Messaggi
    851
    Versione Office
    2010 64 bit
    Likes ricevuti
    113
    Likes dati
    61
    Quartafeira,
    considera la funzione INDICE tipo il gioco della battaglia navale.
    In sostanza avrai: il range dove pescherà i dati e l'incrocio tra il nr di riga e il nr di colonna determinerà il dato da prendere.
    Per capire la funzione, prova a selezionare una parte della formula e spingi F9. Tipo, sulla mia
    =INDICE(Foglio2!$B$2:$D$8;CONFRONTA(TESTO(B2;"ggg");Foglio2!$A$2:$A$8);CONFRONTA(B3;Foglio2!$B$1:$D$1))
    in B5
    xls farà: sul range
    Foglio2!$B$2:$D$8 andrà a prendere i dati
    poi se selezioni solo
    CONFRONTA(TESTO(B2;"ggg") e fai F9 ti indicherà il nr della riga da prendere
    e se selezioni solo
    CONFRONTA(B3;Foglio2!$B$1:$D$1) e farai F9 ti dirà il nr della colonna.
    per cui poi ti troverai tipo
    =
    INDICE(Foglio2!$B$2:$D$8;2;3)
    vorrà dire che nel range
    Foglio2!$B$2:$D$8 il dato da prendere sarà all'incrocio di riga 2 e colonna 3.
    ciao
    ale
    Invia MPPM 

  12. I seguenti utenti hanno dato un "Like"


  13. #9
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Citazione Originariamente Scritto da quartafeira Visualizza Messaggio
    Ciao a tutti,
    ho un problema che non riesco a risolvere, sto creando un file per gli orari di lavoro, fare i calcoli a fine mese e altro ancora, una delle cose che vorrei fare è far comparire in automatico l'orario di inizio e fine turno in base al giorno, visto che lavoro 5 giorni e poi ho un riposo, seguo una ciclazione, lavorando così sabato e domenica, per semplificare ho creato un file che allego, mettendo orari diversi (inventati) a seconda del giorno.
    Vorrei inserendo il giorno (lun mar mer...) ed il turno (Mattina Pomeriggio Sera) che compaia l'ora di inizio e fine turno tramite la tabella nel foglio successivo, un po' come se fosse la battaglia navale, avevo pensato ad un più se o modificando la tabella ad un cerca vert ma vorrei qualcosa di più immediato
    PS: ho cercato qualcosa su internet e mi sembra di aver capito che fanno al caso mio funzioni come db.valori indiretto o indice che però non ho capito come funzionano
    GRAZIE IN ANTICIPO!!!!!
    Ciao Quartafeira

    Ho preso spunto dalla bella formula di ninai per creare una formula con la funzione INDIRETTO che per chi non lo sapesse ci restituisce un riferimento (le tabelle) da una stringa (A4, A5)
    questa soluzione ha il vantaggio che basta solo una formula e con i giusti riferimenti di cella tutto diventa semplice
    In B4 incolla questa formula e trascina la formula in basso e poi a destra:

    =SE.ERRORE(CERCA.VERT(TESTO(B$1;"ggg");INDIRETTO($A7);CONFRONTA(B$3;INDIRETTO($A7&"_int");0);0);"")

    Attenzione in questo caso lavoreremo con la definizione dei nomi
    e daremo un nome prima di fare le formule

    la parte verde ENTRATA
    la parte rossa : USCITA
    la parte blu : ENTRATA_INT
    la parte Viola: USCITA_INT


    Se sei interessato a capire la funzione INDIRETTO guarda questo video

    Ultima modifica fatta da:Gerardo Zuccalà; 22/09/15 alle 19:36 Motivo: Ortografici
    Invia MPPM 

  14. I seguenti 2 utenti hanno dato un "Like" a Gerardo Zuccalà per questo post:


  15. #10
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1075
    Versione Office
    2010 su Win
    Likes ricevuti
    598
    Likes dati
    202
    Ciao a tutti,

    un altro modo per pescare gli orari potrebbe essere questo

    In B4 a destra ed in basso

    =SE.ERRORE(INDICE((Foglio2!$B$2:$D$8;Foglio2!$G$2:$I$8);GIORNO.SETTIMANA(B$1;2);TROVA(B$3;"MPS");RIGHE($A$1:$A1));"")
    Uso un unico INDICE che legge i due range guidato da RIGHE finale.

    E' un esempio dove nell'INDICE viene indicata il numero dell'area che vogliamo interrogare.

    Saluti
    Ultima modifica fatta da:Canapone; 22/09/15 alle 20:49
    Invia MPPM 

  16. I seguenti 3 utenti hanno dato un "Like" a Canapone per questo post:


  17. #11
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1657
    Versione Office
    2010 PC
    Likes ricevuti
    891
    Likes dati
    184
    Canapone
    il parametro "area" di INDICE() lo conoscevi solo tu ed il Signor Excel :285:, sei una fonte inesauribile!!!!

    un altro modo per rendere plastica la formula:
    =SE.ERRORE(CERCA.VERT(TESTO(B$1;"ggg");SCARTO(Foglio2!$A$2:$D$8;;5*($A4="uscita"));CONFRONTA(B$3;Foglio2!$A$1:$D$1;0);FALSO);"")
    da trascinare in basso ed a destra
    Invia MPPM 

  18. I seguenti utenti hanno dato un "Like"


  19. #12
    L'avatar di quartafeira
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Italia
    Età
    35
    Messaggi
    23
    Versione Office
    2010
    Likes ricevuti
    1
    Buongiorno a tutti,
    scusate se rispondo solo ora ma lavorando con i turni (non quelli della tabella) come posso torno a casa e crollo.
    che dire... grazie a tutti, ora mi metterò sotto a cercare di capire al meglio le dritte che mi avete dato, funzioni ed esempi.
    Siete Fantastici!
    Simone
    Invia MPPM 

  20. #13
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1075
    Versione Office
    2010 su Win
    Likes ricevuti
    598
    Likes dati
    202
    Ciao,

    ti ringrazio del riscontro anche a nome degli amici del Forum.

    Se avessi bisogno di chiarimenti sugli INDICE o sul CERCA.VERT o sulla MATR.SOMMA.PRODOTTO faccelo sapere.

    Saluti
    Invia MPPM 

  21. I seguenti utenti hanno dato un "Like"


Discussioni Simili

  1. Pescare valori da un foglio differente da quello in uso tramite un tasto
    Di MattiaLoca nel forum Domande su Excel VBA e MACRO
    Risposte: 3
    Ultimo Messaggio: 03/01/17, 22:41
  2. [Risolto] Cercare dei valori all'interno di una tabella
    Di peppe1 nel forum Domande su Excel in generale
    Risposte: 3
    Ultimo Messaggio: 09/10/16, 13:18
  3. [Risolto] Estrarre un testo da una stringa di una tabella tramite query, e poi creare una nuova tabella
    Di ProgrammD69 nel forum Domande su Microsoft Access
    Risposte: 11
    Ultimo Messaggio: 05/09/16, 10:21
  4. Cerca valore all´interno di un intervallo
    Di Biogennari nel forum Domande su Excel in generale
    Risposte: 13
    Ultimo Messaggio: 28/01/16, 19:24
  5. [Risolto] come pescare un valore da altra parte
    Di Dagatos nel forum Domande su Excel in generale
    Risposte: 14
    Ultimo Messaggio: 10/06/15, 07:23

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •