Risultati da 1 a 13 di 13

Discussione: Creare una lista unica con dati su piu colonne (celle vuote)



  1. #1
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126

    Creare una lista unica con dati su piu colonne (celle vuote)

    Ciao a tutti
    Come potete vedere ho un data-set di prodotti (frutta)
    e in F2 ho bisogno di una formula che mi restituisce una lista unica di quei prodotti che io ho scritto a mano per far capire bene il risultato finale
    Io non ho problemi a creare una lista unica ma il problema che i prodotti sono in piu colonne e ci son delle celle vuote
    grazie per l'aiuto

    A
    B
    C
    D
    E
    F
    1
    risultato
    2
    mela arancia pesca pera mela
    3
    banana pesca banana banana
    4
    pera mela pera
    5
    banana mela pesca pera kiwi
    6
    kiwi kiwi arancia
    7
    banana banana pesca
    8
    arancia pesca pesca
    Invia MPPM 

  2. #2
    L'avatar di Jos
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Torino, Piemonte
    Messaggi
    84
    Versione Office
    2013 PC
    Likes ricevuti
    90
    Likes dati
    5
    Ciao, Gerry!

    È importante l'ordine in cui i risultati sono dati?

    Se no, allora in F1:

    =MATR.SOMMA.PRODOTTO((A2:D8<>"")/CONTA.SE(A2:D8;A2:D8&""))

    E poi, in F2, da confermare con CONTROL+MAIUSC+INVIO:

    =SE(RIGHE($1:1)>$F$1;"";INDIRETTO(TESTO(MIN(SE($A$2:$D$8<>"";SE(CONTA.SE(F$1:F1;$A$2:$D$8)=0;10^5*RIF.RIGA($A$2:$D$8)+RIF.COLONNA($A$2:$D$8))));"R0C00000");0))

    (Penso che "R" e "C" siano utilizzati cosi anche in italiano.)

    È un po' più difficile da dare i risultati per quanto riguarda le colonne, ma non troppo. Farmi sapere!

    Saluti
    Advanced Excel Techniques: http://excelxor.com/
    Invia MPPM 

  3. I seguenti 5 utenti hanno dato un "Like" a Jos per questo post:


  4. #3
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1674
    Versione Office
    2010 PC
    Likes ricevuti
    895
    Likes dati
    184
    un alternativa, Giusto perchè ne ho trovata una simile in archivio, l'ho adattata, ma è praticamente la stessa di quella di XOR, in F2:
    =SE.ERRORE(INDIRETTO("r" & SOSTITUISCI(TESTO(MIN(SE($A$2:$D$8<>"";SE(CONTA.SE(F$1:F1;$A$2:$D$8)=0; RIF.RIGA($A$2:$D$8)+RIF.COLONNA($A$2:$D$8)/1000)));"#,000"); ","; "C");FALSO);"")

    edit
    per completezza, pubblico anche quella che li estrae per colonna:
    =SE.ERRORE(INDIRETTO(INDIRIZZO(RESTO(MIN(SE(($A$2:$D$8<>"");SE(CONTA.SE(F$1:F1;$A$2:$D$8)=0; RIF.COLONNA($A$2:$D$8)+RIF.RIGA($A$2:$D$8)/1000)));1)*1000;INT(MIN(SE(($A$2:$D$8<>"");SE(CONTA.SE(F$1:F1;$A$2:$D$8)=0; RIF.COLONNA($A$2:$D$8)+RIF.RIGA($A$2:$D$8)/1000))))));"")
    Invia MPPM 

  5. I seguenti 4 utenti hanno dato un "Like" a ninai per questo post:


  6. #4
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Citazione Originariamente Scritto da XOR LX Visualizza Messaggio
    Ciao, Gerry!

    È importante l'ordine in cui i risultati sono dati?
    Cioa Jos
    Scusa se non ho risposto prima ero con il telefono in auto, comunque non è importate l'ordine in cui sono i dati
    Mi piace molto anche la formula con il MATR.SOMMA.PRODOTTO
    Grande Jos
    e mi raccomando fatti vedere in questo forum that misses you!!
    Invia MPPM 

  7. #5
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Grande Ninai
    ho provato tutte e due le tue formule e funzionano benissimo anche se non le ho ancora capite, ma questa volta è un po dura capirle
    Ci proverò e di sicuro le archivierò da custodire gelosemente
    Grazie a tutti e se nessun'altro ha delle soluzioni alternative considero questa discussione RISOLTA
    Invia MPPM 

  8. #6

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7153
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2064
    Likes dati
    1300
    Grande Jos, che saluto! :299:

    Cercando su internet mi sono imbattuto in QUESTA discussione e sto cercando di studiarmi la formula, per ora però non mi funziona. :92:
    Invia MPPM 

  9. #7
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Citazione Originariamente Scritto da XOR LX Visualizza Messaggio
    Ciao, Gerry!

    È importante l'ordine in cui i risultati sono dati?

    Se no, allora in F1:

    =MATR.SOMMA.PRODOTTO((A2:D8<>"")/CONTA.SE(A2:D8;A2:D8&""))

    E poi, in F2, da confermare con CONTROL+MAIUSC+INVIO:

    =SE(RIGHE($1:1)>$F$1;"";INDIRETTO(TESTO(MIN(SE($A$2:$D$8<>"";SE(CONTA.SE(F$1:F1;$A$2:$D$8)=0;10^5*RIF.RIGA($A$2:$D$8)+RIF.COLONNA($A$2:$D$8))));"R0C00000");0))

    (Penso che "R" e "C" siano utilizzati cosi anche in italiano.)

    È un po' più difficile da dare i risultati per quanto riguarda le colonne, ma non troppo. Farmi sapere!

    Saluti
    Jos!
    and what about this?
    You are everywhere in Internet!!
    questa però è più difficile ancora
    http://excelxor.com/2014/11/08/uniqu...veral-columns/
    Invia MPPM 

  10. #8
    L'avatar di Jos
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Torino, Piemonte
    Messaggi
    84
    Versione Office
    2013 PC
    Likes ricevuti
    90
    Likes dati
    5
    Per colonna, anche:

    =SE(RIGHE($1:1)>$F$1;"";INDIRETTO(TESTO(SOMMA(10^{5;0}*STRINGA.ESTRAI(TESTO(MIN(SE($A$2:$D$8<>"";SE(CONTA.SE(F$1:F1;$A$2:$D$8)=0;10^5*RIF.COLONNA($A$2:$D$8)+RIF.RIGA($A$2:$D$8))));"R00000C00000");{8;2};5));"R0C00000");0))

    (Non sono sicuro se il separatore delle costanti di matrice verticali nelle versione italiana sia ";" o "."?)

    Saluti.
    Advanced Excel Techniques: http://excelxor.com/
    Invia MPPM 

  11. #9
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Citazione Originariamente Scritto da XOR LX Visualizza Messaggio



    (Non sono sicuro se il separatore delle costanti di matrice verticali nelle versione italiana sia ";" o "."?)
    =SE(RIGHE($1:1)>$F$1;"";INDIRETTO(TESTO(SOMMA(10^{5.0}*STRINGA.ESTRAI(TESTO(MIN(SE($A$2:$D$8<>"";SE(CONTA.SE(F$1:F1;$A$2:$D$8)=0;10^5*RIF.COLONNA($A$2:$D$8)+RIF.RIGA($A$2:$D$8))));"R00000C00000");{8.2};5));"R0C00000");0))

    Il delimitatore di costanti è il Punto (dot) e non punto e virgola
    Comunque la tua formula è troppo complicata servirebbe un Tutorial anche in inglese
    Ciao
    Invia MPPM 

  12. #10

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4020
    Versione Office
    2013
    Likes ricevuti
    1228
    Likes dati
    923
    :124:
    Non conoscevo l'uso di "R" e "C"... vado studiare :286: :262:

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."
    Invia MPPM 

  13. #11
    L'avatar di Jos
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Torino, Piemonte
    Messaggi
    84
    Versione Office
    2013 PC
    Likes ricevuti
    90
    Likes dati
    5
    Citazione Originariamente Scritto da ges Visualizza Messaggio
    Grande Jos, che saluto! :299:

    Cercando su internet mi sono imbattuto in QUESTA discussione e sto cercando di studiarmi la formula, per ora però non mi funziona. :92:
    Ciao, Ges!

    Neanche per me.

    Io preferisco, in D1:

    =SOMMA(SE(FREQUENZA(SE(Elenco<>"";CONFRONTA(Elenco;Elenco;0));RIF.RIGA(Elenco)-MIN(RIF.RIGA(Elenco))+1);1))

    Poi, in G2:

    =SE(RIGHE($1:1)>$D$1;"";CERCA(1;0/FREQUENZA(0;1/(1+SE(FREQUENZA(SE(CONTA.SE(G$1:G1;Elenco)=0;CONFRONTA(Elenco;Elenco;0));RIF.RIGA(Elenco)-MIN(RIF.RIGA(Elenco))+1);RIGHE(Elenco)-CONTA.SE(Elenco;"<"&Elenco&""))));Elenco))

    le due da confermare con CONTROL+MAIUSC+INVIO.

    (Però, forse più logico è:

    =SE(RIGHE($1:1)>$D$1;"";INDICE(Elenco;CONFRONTA(MIN(SE(FREQUENZA(SE(CONTA.SE(F$1:F1;Elenco)=0;CONFRONTA(Elenco;Elenco;0));RIF.RIGA(Elenco)-MIN(RIF.RIGA(Elenco))+1);CONTA.SE(Elenco;"<"&Elenco)));SE(FREQUENZA(SE(CONTA.SE(F$1:F1;Elenco)=0;CONFRONTA(Elenco;Elenco;0));RIF.RIGA(Elenco)-MIN(RIF.RIGA(Elenco))+1);CONTA.SE(Elenco;"<"&Elenco));0)))

    ...ma anche più lungo! :-))

    Saluti.
    Advanced Excel Techniques: http://excelxor.com/
    Invia MPPM 

  14. #12
    L'avatar di Jos
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Torino, Piemonte
    Messaggi
    84
    Versione Office
    2013 PC
    Likes ricevuti
    90
    Likes dati
    5
    Citazione Originariamente Scritto da Gerardo Zuccalà Visualizza Messaggio
    Il delimitatore di costanti è il Punto (dot) e non punto e virgola
    Grazie mille!

    Citazione Originariamente Scritto da Gerardo Zuccalà Visualizza Messaggio
    Comunque la tua formula è troppo complicata servirebbe un Tutorial anche in inglese
    Ma non lo è!

    Ciao!
    Advanced Excel Techniques: http://excelxor.com/
    Invia MPPM 

  15. #13
    L'avatar di Jos
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Torino, Piemonte
    Messaggi
    84
    Versione Office
    2013 PC
    Likes ricevuti
    90
    Likes dati
    5
    Citazione Originariamente Scritto da Gerardo Zuccalà Visualizza Messaggio
    You are everywhere in Internet!!
    Ma questo forum è il mio preferito!

    Citazione Originariamente Scritto da Gerardo Zuccalà Visualizza Messaggio
    questa però è più difficile ancora
    http://excelxor.com/2014/11/08/uniqu...veral-columns/
    È vero.
    Advanced Excel Techniques: http://excelxor.com/
    Invia MPPM 

Discussioni Simili

  1. DatePicker attivo solo su celle vuote di alcune colonne
    Di AiaceT nel forum Domande su Excel VBA e MACRO
    Risposte: 10
    Ultimo Messaggio: 26/01/17, 03:31
  2. [Risolto] Modificare righe/colonne da lista di dati importati tramite txt
    Di GioAlba nel forum Domande su Excel VBA e MACRO
    Risposte: 26
    Ultimo Messaggio: 05/11/16, 11:09
  3. [Risolto] Estrarre dati da più colonne e riportarli in un'unica colonna
    Di andreafuri nel forum Domande su Excel VBA e MACRO
    Risposte: 9
    Ultimo Messaggio: 14/10/16, 21:49
  4. [Risolto] Riportare in riga, solo celle non vuote formanti colonne
    Di brian747 nel forum Domande su Excel in generale
    Risposte: 25
    Ultimo Messaggio: 30/09/16, 22:15
  5. Lista unica incrociata
    Di Gerardo Zuccalà nel forum Domande su Excel in generale
    Risposte: 11
    Ultimo Messaggio: 07/08/15, 18:36

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •