Risultati da 1 a 24 di 24

Discussione: Calendario dinamico con nomi delle festività



  1. #1
    L'avatar di Trial4life
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Roma
    Età
    24
    Messaggi
    59
    Versione Office
    Excel 2007
    Likes ricevuti
    0
    Likes dati
    2

    Calendario dinamico con nomi delle festività

    Ciao a tutti,
    mi sono iscritto a questo forum perché ho un quesito apparentemente complesso da risolvere...
    Ho creato un foglio excel che, impostato l'anno, crea i calendari di ogni mese di quell'anno.
    Ora, poiché i giorni non sono in caselle fisse (si spostano al variare dell'anno), non posso associare manualmente a una data precisa il nome della festività (poichè se poi si cambia l'anno, la festività si trova "sfasata").
    C'è un modo per dire ad EXCEL di controllare tutte le celle e, laddove trova una "data chiave", scrivere a destra di quella cella il nome della festività?

    Visto che le festività sono tante, avevo pensato di aggiungere un foglio contenente i nomi associati alle date delle festività (in modo da poter aggiungere ricorrenze come compleanni, onomastici, etc.)... ma poi come faccio a correlare il calendario all'elenco delle festività? E soprattutto, come faccio a dirgli di controllare in massa tutte le date in modo efficiente e rapido?

    Allego una figura per spiegarmi meglio. Grazie in anticipo.



  2. #2

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Ciao Trial4life,
    l'immagine serve a poco...
    Dovresti allegare il file in modo da poterci far su delle prove. :246:

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  3. #3
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Ciao trial4life
    benvenuto in ForumExce.it
    grazie per la domanda che è molto chiara, tuttavia sarebbe necessario che tu allegassi questo file cosi che ci si possa lavorare direttamente sopra perchè in questo caso una immagine statica formato .gif ... non ci aiuta di certo.
    Cosi possiamo vedere se ci sono altre formule sotto oppure codici VBA
    Trial4ife Per allegare un file ci sono diversi modi e dipende dalla dimensione del file

    --> se hai un file di dimensioni inferiore a 50 kb lo puoi inserire direttamente dal tuo computer nel forum, e se non sai come fare guarda questo video


    --->>> oppure se hai dei file con dimensioni maggiori di 50 kb. Potresti allegare un file con una delle tante piattaforme di file-hosting gratuiti come ad esempio i miei preferiti DropBox, Box, FileDropper ecc ecc. ecc
    ciao

  4. #4
    L'avatar di Trial4life
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Roma
    Età
    24
    Messaggi
    59
    Versione Office
    Excel 2007
    Likes ricevuti
    0
    Likes dati
    2
    Eccolo qui. Ho messo solo 6 mesi altrimenti il file pesava troppo. Non c'è nessun codice VBA, solo qualche formula nelle caselle delle date.

  5. #5

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Ciao,
    per come hai sistemato i fogli (celle unite, formato testo, etc...), non dico che è impossibile ma con le formule diventerebbe un calvario.....anche se qualche utente potrebbe fare una magia...
    Proverò (l'ho sottolineato apposta "proverò" :184: ) con VBA in attesa di altre soluzioni.

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  6. #6

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Ciao Trial4life,
    ti propongo qualcosa in VBA....

    Piccola premessa:
    1) Ho levato l' "unione celle" per ogni tabella (calendario) di ogni foglio, visto che complicavano la vita e basta.
    2) Ho aggiunto (come dicevi tu) un foglio Festività.

    Il codice "principale" (all'interno di un modulo) è questo:
    Codice: 
    Option Explicit
    
    Sub feste()
    Dim anno As Integer, holiday As Range, wkfeste As Worksheet, riga_feste As Long
    Dim data_confronto As Date, i As Integer, j As Integer, mese As Integer, giorno As Integer
    Dim x As Integer, cella As Range, awks As Worksheet
    Set wkfeste = Worksheets("Festività")
    Set awks = ActiveSheet
    riga_feste = wkfeste.Range("D2").End(xlDown).Row
    Set holiday = wkfeste.Range("D3:D" & riga_feste)
    anno = Worksheets("Gennaio").Range("C2").Value
    mese = Application.WorksheetFunction.Match(ActiveSheet.Name, wkfeste.Range("K2:K13"), 0)
    
    
    With awks
        For i = 3 To 15 Step 2
            .Range(Cells(5, i), Cells(40, i)).ClearContents
        Next i
    End With
    
    
    For i = 5 To 35 Step 6
        For j = 2 To 14 Step 2
        x = 0
            If Cells(i, j).Value <> "" Then
                giorno = Day(Cells(i, j).Value)
                data_confronto = DateSerial(anno, mese, giorno)
                For Each cella In holiday
                    If data_confronto = cella.Value And x <= 6 Then
                        With Cells(i + x, j + 1)
                            .Value = cella.Offset(0, -3).Value
                            .HorizontalAlignment = xlCenter
                            .VerticalAlignment = xlCenter
                            .Font.ColorIndex = 3
                        End With
                        x = x + 1
                    End If
                Next
            End If
        Next j
    Next i
    
    Set wkfeste = Nothing
    Set awks = Nothing
    Set holiday = Nothing
    
    End Sub


    Questo codice viene richiamato ogni volta che lasci ("deattivi") il foglio "Festività ed ogni volta che modifichi l'anno nella cella "C2" del Foglio "Gennaio".
    Quindi (parliamo di editor VBA) nel Foglio "Festività" hai questo codice:
    Codice: 
    Option Explicit
    
    Private Sub Worksheet_Deactivate()
    Dim i As Integer
    Application.ScreenUpdating = False
    For i = 1 To Sheets.Count
        If Sheets(i).Name <> "Festività" Then
            Sheets(i).Activate
            Call feste
        End If
    Next
    Worksheets("Gennaio").Activate
    Application.ScreenUpdating = True
    End Sub


    Mentre nel foglio "Gennaio" hai questo:
    Codice: 
    Option Explicit
    
    Private Sub Worksheet_Change(ByVal Target As Range)
        If Not Intersect(Target, Range("C2")) Is Nothing Then
        Dim i As Integer
        Application.ScreenUpdating = False
        For i = 1 To Sheets.Count
            If Sheets(i).Name <> "Festività" Then
                Sheets(i).Activate
                Call feste
            End If
        Next
        Worksheets("Gennaio").Activate
        Application.ScreenUpdating = True
    End If
    End Sub


    Di questi ultimi due codici se ne poteva fare solo uno in un modulo e dopo essere richiamato a seconda dell'evento ("
    Worksheet_Change" o "Worksheet_Deactivate"). Vabbè... è andata così . :184:
    Naturalmente si può migliorare, ma con la struttura che hai usato questa è la prima cosa che mi è sembrato logico fare.

    Il file supera i 50 Kb quindi lo puoi scaricare da qui:
    http://dropcanvas.com/15mlw

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  7. #7
    L'avatar di Trial4life
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Roma
    Età
    24
    Messaggi
    59
    Versione Office
    Excel 2007
    Likes ricevuti
    0
    Likes dati
    2
    ... WOW!
    Era proprio quello che intendevo, grazie, ma soprattutto complimenti! Non conosco bene il VBA, quindi non credo che avrei mai potuto creare nulla di simile...

    Però avrei altre due domande:
    1) C'è un modo per selezionare il formato per ogni festività? Ad esempio, come si vede in figura, ho creato un'altra colonna accanto alla data della festività, che funge da "indicatore". Se ad esempio l'indicatore è "1", viene evidenziata di giallo tutta la macro-cella del singolo giorno (come accade per i sabati e le domeniche); se invece è "2", cambia il colore della festività, e così via per quanti formati si vuole.



    2) C'è un modo per lasciare le celle unite all'interno dei giorni? Perché hai scritto che questo complicherebbe molto il codice? Se possibile sarebbe molto più comodo averle unite.

  8. #8

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Ciao,
    il punto 1 lo puoi fare tranquillamente con la "Formattazione condizionale". Ho visto che l'hai già usata per colorare di grigio la caselle vuote del calendario, quindi non dovresti aver problemi a fare quello che chiedi... a meno che non abbia frainteso. In tal caso prova a spiegarti meglio allegando un file che abbia solo foglio quel ("Festività").

    Ho tolto l' "unione celle" sia perchè complicava i riferimenti per il codice ma anche perchè alla fine le cella "disunite" sotto il numero del giorno non hanno alcuna utilità pratica, almeno per come hai spiegato quello che ti serviva. Non so se "l'unione" complichi di molto il codice (non ci ho proprio provato, al primo errore del codice mi è sembrato più pratico togliere l'unione celle), se proprio ti servono unite ci si può provare.

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  9. #9
    L'avatar di Trial4life
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Roma
    Età
    24
    Messaggi
    59
    Versione Office
    Excel 2007
    Likes ricevuti
    0
    Likes dati
    2
    Citazione Originariamente Scritto da cromagno Visualizza Messaggio
    Ciao,
    il punto 1 lo puoi fare tranquillamente con la "Formattazione condizionale". Ho visto che l'hai già usata per colorare di grigio la caselle vuote del calendario, quindi non dovresti aver problemi a fare quello che chiedi... a meno che non abbia frainteso. In tal caso prova a spiegarti meglio allegando un file che abbia solo foglio quel ("Festività").
    Il fatto è che bisogna evidenziare il rispettivo giorno nel calendario, non quello nella scheda festività! Mi spiego meglio con questo screen:



    I giorni di capodanno e dell'Epifania si devono evidenziare automaticamente, così come viene scritto automaticamente "Capodanno" ed "Epifania" nei rispettivi giorni... ma questo non per tutte le festività! Solo per quelle con il numero "1" accanto alla data della festività nella scheda "Festività" (vedi il mio post precedente)

    Citazione Originariamente Scritto da cromagno Visualizza Messaggio
    Ho tolto l' "unione celle" sia perchè complicava i riferimenti per il codice ma anche perchè alla fine le cella "disunite" sotto il numero del giorno non hanno alcuna utilità pratica, almeno per come hai spiegato quello che ti serviva. Non so se "l'unione" complichi di molto il codice (non ci ho proprio provato, al primo errore del codice mi è sembrato più pratico togliere l'unione celle), se proprio ti servono unite ci si può provare.
    Mi servirebbero unite in modo che ci sia più spazio per scrivere all'interno di ogni riga... lo so... è una sottigliezza :167:

  10. #10
    L'avatar di zio_tom
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Veneto
    Messaggi
    526
    Versione Office
    2010 - Win10
    Likes ricevuti
    64
    Likes dati
    17
    se può interessare questo è un mio paziente e lungo lavoro
    stampo le schermate per le 53 settimane e le rilego, è la mia agenda per gli appuntamenti

    Un calendario settimanale con segni zodiacali, fasi lunari, alba e tramonto in funzione di latitudine e longitudine, ora legale
    gestisce le festività, santo patrono, calcola la Pasqua, Santi del giorno, complenni ed onomastici
    spero che piaccia, io ne sono orgoglioso

    bisogna installare i fonts allegati
    http://dropcanvas.com/f7jgk

    :299:
    n°3 - Win10pro + Office 2010 ----- n°1 - Win7pro + Office 2010 ----- n°1 - WinXPpro + Office 2010

  11. I seguenti 4 utenti hanno dato un "Like" a zio_tom per questo post:


  12. #11

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Ciao,
    Per il secondo punto, invece di utilizzare l'unione celle (che guadagneresti solo un paio di caratteri) ti conviene adattare l'altezza della riga alla lunghezza del testo.

    Per il primo e il secondo punto, basta aggiungere un paio di righe nel codice....
    Le parti aggiunte sono evidenziate in rosso:

    Codice: 
                        With Cells(i + x, j + 1)
                            .Value = cella.Offset(0, -3).Value
                            .HorizontalAlignment = xlCenter
                            .VerticalAlignment = xlCenter
                            .WrapText = True
                            .Rows.AutoFit
                            .Font.ColorIndex = 3
                            If cella.Offset(0, 1) = 1 Then
                                .Interior.ColorIndex = 6
                            End If
                        End With
    Il file lo puoi scaricare da qui:
    http://dropcanvas.com/7lhkp

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  13. #12

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Ciao zio_tom,
    non avevo visto la tua risposta...
    Adesso ti "rubo" il file :32:

    Scherzo... Grazie per la condivisione :246:

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  14. #13
    L'avatar di Trial4life
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Roma
    Età
    24
    Messaggi
    59
    Versione Office
    Excel 2007
    Likes ricevuti
    0
    Likes dati
    2
    Citazione Originariamente Scritto da cromagno Visualizza Messaggio
    Ciao,
    Per il secondo punto, invece di utilizzare l'unione celle (che guadagneresti solo un paio di caratteri) ti conviene adattare l'altezza della riga alla lunghezza del testo.

    Per il primo e il secondo punto, basta aggiungere un paio di righe nel codice....
    Le parti aggiunte sono evidenziate in rosso:

    Codice: 
                        With Cells(i + x, j + 1)
                            .Value = cella.Offset(0, -3).Value
                            .HorizontalAlignment = xlCenter
                            .VerticalAlignment = xlCenter
                            .WrapText = True
                            .Rows.AutoFit
                            .Font.ColorIndex = 3
                            If cella.Offset(0, 1) = 1 Then
                                .Interior.ColorIndex = 6
                            End If
                        End With
    Il file lo puoi scaricare da qui:
    http://dropcanvas.com/7lhkp
    Ok, però così facendo si evidenzia solo la casella che contiene il nome della festività... mentre io vorrei fare in modo che si evidenziasse TUTTO il giorno!


    Per il primo punto invece non ho capito bene cosa intendi..

  15. #14
    L'avatar di zio_tom
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Veneto
    Messaggi
    526
    Versione Office
    2010 - Win10
    Likes ricevuti
    64
    Likes dati
    17
    x cromagno
    gradirei un tuo riscontro sul mio lavoro... elogi e critiche.... consigli e dimmi se... "Mi Piace" :59: :251:
    :299:
    n°3 - Win10pro + Office 2010 ----- n°1 - Win7pro + Office 2010 ----- n°1 - WinXPpro + Office 2010

  16. #15

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    @Trial4life
    scusa, che senso avrebbe evidenziare tutta la casella che magari contiene 3 festività e una di questa non ha il valore "1" nel foglio "Festività"? :171:

    Il Primo punto era questo (l'evidenziazione).
    Il Secondo punto riguarda il tuo voler "unire le celle" per guadagnare 3 o 4 caratteri in più da poter evidenziare. Ti ho semplicemente detto che è meglio adattare l'altezza della riga (è già integrato nel codice) in modo che ti possa visualizzare per intero anche una frase intera e più...

    Il codice come hai visto non è cambiato di molto, ma se continuo a modificarlo io non imparerai mai a gestirlo da solo.
    Prova ad evidenziare tutta la casella seguendo la logica con cui adesso evidenzia la singola cella (anche se come ho detto... per me è sbagliato).

    Se non dovessi riuscirci allora vedremo di trovare una soluzione insieme. :32:

    @zio_tom
    L'ho aperto frettolosamente ma dovevo ancora installare i Font che hai allegato.
    Di primo acchito sembra un bel lavoro... che sicuramente ti avrà portato via un bel pò di tempo.
    Appena possibile ti dirò sicuramente la mia :32:

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  17. #16

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    @ zio_tom
    con i font installati è tutta un'altra cosa


    Stavo iniziando a guardare i codici per le varie function (sarebbe un ottimo esercizio vedere se si poteva fare solo con le formule native di excel....anche se ne dubito).

    Per quanto riguarda il foglio "LatLong" dovrei mettere le coordinate della mia posizione,giusto?

    Comunque il tuo file va sicuramente tra i miei "preferiti" e mi sa che lo userò :246:

    CONGRATULATIONS

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  18. #17
    L'avatar di Trial4life
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Roma
    Età
    24
    Messaggi
    59
    Versione Office
    Excel 2007
    Likes ricevuti
    0
    Likes dati
    2
    Citazione Originariamente Scritto da cromagno Visualizza Messaggio
    @Trial4life
    scusa, che senso avrebbe evidenziare tutta la casella che magari contiene 3 festività e una di questa non ha il valore "1" nel foglio "Festività"? :171:
    In realtà avevo dato per scontato che non ci potesse essere più di una festività per giorno, perché tutte le altre righe le utlizzo per scriverci altro! Per questo preferirei evidenziare tutta la giornata...

    Sto provando a modificare il codice, ma mi sono reso conto che con l'ultimo che hai postato, quando cambio l'anno le celle restano evidenziate! Dove andrebbe inserito il comando per resettarle?

  19. #18

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Ciao,
    si, per l'evidenziazione che rimane hai ragione.
    Comunque, il giorno di Pasqua (come quello di Pasquetta) può cadere anche il 25 Aprile (che è un'altra festività).
    In ogni caso il file è tuo... ma aspetto ancora un pò per farti fare qualche prova da solo.

    Mentre per resettare le formattazioni, devi aggiungere questa riga in questa parte del codice (parte in rosso):

    Codice: 
    With awks
        For i = 3 To 15 Step 2
            .Range(Cells(5, i), Cells(40, i)).ClearContents
            .Range(Cells(5, i), Cells(40, i)).Interior.ColorIndex = 2
        Next i
    End With
    [EDIT]
    anche se in questo caso non è un "reset" visto che applichi il colore bianco (.ColorIndex = 2)

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  20. #19
    L'avatar di Trial4life
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Roma
    Età
    24
    Messaggi
    59
    Versione Office
    Excel 2007
    Likes ricevuti
    0
    Likes dati
    2
    Ok grazie mille, ha funzionato.
    Invece, per evidenziare l'intera giornata (so che non è del tutto corretto, ma a me torna più comodo così..), ho provato a inserire il comando in rosso all'interno del ciclo for:

    Codice: 
    For i = 5 To 35 Step 6
        For j = 2 To 14 Step 2
        x = 0
            If Cells(i, j).Value <> "" Then
                giorno = Day(Cells(i, j).Value)
                data_confronto = DateSerial(anno, mese, giorno)
                For Each cella In holiday
                    If data_confronto = cella.Value And x <= 6 Then
                        With Cells(i + x, j + 1)
                            .Value = cella.Offset(0, -3).Value
                            .HorizontalAlignment = xlLeft
                            .VerticalAlignment = xlCenter
                            .WrapText = True
                            .Rows.AutoFit
                            .Font.ColorIndex = 9
                            If cella.Offset(0, 1) = 1 Then
                               .Range(Cells(i, j), Cells(i + 5, j + 1)).Interior.ColorIndex = 19
                            End If
                            If cella.Offset(0, 1) = 2 Then
                               .Font.ColorIndex = 10
                            End If
                        End With
                        x = x + 1
                    End If
                Next
            End If
        Next j
    Next i
    .. ma non sembra funzionare. Avevo pensato "invece che evidenziare solo la cella, evidenzia quel range", ma non capisco cosa non va...

  21. #20

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Ho modificato un pò il codice per evidenziare tutta la casella (se c'è almeno una festività che abbia valore "1").

    Prova se va bene:
    Codice: 
    Option Explicit
     
    Sub feste()
    Dim anno As Integer, holiday As Range, wkfeste As Worksheet, riga_feste As Long
    Dim data_confronto As Date, i As Integer, j As Integer, mese As Integer, giorno As Integer
    Dim x As Integer, cella As Range, awks As Worksheet, conta_feste As Integer
    Set wkfeste = Worksheets("Festività")
    Set awks = ActiveSheet
    riga_feste = wkfeste.Range("D2").End(xlDown).Row
    Set holiday = wkfeste.Range("D3:D" & riga_feste)
    anno = Worksheets("Gennaio").Range("C2").Value
    mese = Application.WorksheetFunction.Match(ActiveSheet.Name, wkfeste.Range("K2:K13"), 0)
     
    With awks
        For i = 3 To 15 Step 2
            For j = 5 To 35 Step 6
                .Cells(j, i).ClearContents
                .Range(Cells(j + 1, i - 1), Cells(j + 5, i)).ClearContents
                .Range(Cells(j, i - 1), Cells(j + 5, i)).Interior.ColorIndex = 2
            Next j
        Next i
    End With
     
    For i = 5 To 35 Step 6
        For j = 2 To 14 Step 2
        x = 0
            If Cells(i, j).Value <> "" Then
                giorno = Day(Cells(i, j).Value)
                data_confronto = DateSerial(anno, mese, giorno)
                For Each cella In holiday
                    If data_confronto = cella.Value And x <= 6 Then
                        With Cells(i + x, j + 1)
                            .Value = cella.Offset(0, -3).Value
                            .HorizontalAlignment = xlCenter
                            .VerticalAlignment = xlCenter
                            .WrapText = True
                            .Rows.AutoFit
                            .Font.ColorIndex = 3
                            If cella.Offset(0, 1) = 1 Then
                                Range(Cells(i, j), Cells(i + 5, j + 1)).Interior.ColorIndex = 6
                            End If
                        End With
                        x = x + 1
                    End If
                Next
            End If
        Next j
    Next i
     
    Set wkfeste = Nothing
    Set awks = Nothing
    Set holiday = Nothing
    End Sub
    File da scaricare:
    http://dropcanvas.com/0q7g0

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  22. I seguenti 2 utenti hanno dato un "Like" a cromagno per questo post:


  23. #21
    L'avatar di Trial4life
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Roma
    Età
    24
    Messaggi
    59
    Versione Office
    Excel 2007
    Likes ricevuti
    0
    Likes dati
    2
    Perfetto, mi era sfuggito qualcosa all'interno di "With awks".

    Direi che ora è completo al 100%, ti devo ringraziare infinitamente per l'aiuto tempestivo che mi hai dato in questi giorni! :127:

  24. #22

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4019
    Versione Office
    2013
    Likes ricevuti
    1227
    Likes dati
    923
    Ti ringrazio io perchè essendo agli inizi col VBA mi hai dato modo di esercitarmi :286:

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  25. #23
    L'avatar di MauroS
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Abruzzo
    Età
    40
    Messaggi
    56
    Versione Office
    2007 WIN
    Likes ricevuti
    1
    Ciao Zio_tom,
    ho scaricato il tuo file ed è eccezionale!!
    Grazie per la condivisione.

    Mauro.

  26. #24
    L'avatar di GiuseppeMN
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    Mantova
    Messaggi
    864
    Versione Office
    2000 - 2013
    Likes ricevuti
    285
    Likes dati
    160
    Buon pomeriggio a Tutti.
    Confidando nella Vostra clemenza, dopo una lunga assenza da Forum, mi permetto di proporre una possibile soluzione senza VBA.

    A disposizione

    Buona serata a Tutti.

    Giuseppe
    Windows XP Excel 2000 - Windows 10 Excel 2013

Discussioni Simili

  1. Template per un calendario annuale con festività
    Di Trial4life nel forum Domande su Excel VBA e MACRO
    Risposte: 7
    Ultimo Messaggio: 03/01/17, 19:57
  2. Estarre tutti i nomi delle persone che compioni il compleanno oggi
    Di klaudios nel forum Domande su Excel in generale
    Risposte: 14
    Ultimo Messaggio: 17/07/16, 16:49
  3. evidenziare festività in calendario perpetuo
    Di silvia70 nel forum Domande su Excel in generale
    Risposte: 37
    Ultimo Messaggio: 16/02/16, 16:17
  4. Calendario dinamico
    Di ges nel forum Domande su Excel in generale
    Risposte: 3
    Ultimo Messaggio: 05/07/15, 00:38
  5. come posso ottenere i nomi dei fogli di una cartella su delle righe?
    Di Francesco nel forum Domande su Excel in generale
    Risposte: 14
    Ultimo Messaggio: 03/07/15, 03:29

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •