Risultati da 1 a 19 di 19

Discussione: Conteggio valori unici



  1. #1
    L'avatar di delusan
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Roma
    Età
    58
    Messaggi
    15
    Versione Office
    2010 WIN
    Likes ricevuti
    0
    Likes dati
    5

    Conteggio valori unici

    Buongiorno a tutti,
    chiedo cortesemente il vostro aiuto per risolvere un piccolo problema di lavoro.
    Ho una tabella così composta:

    A B C D
    1 DATA NOME
    ATT_1
    ATT_2
    2 1/2/2015 pippo X
    3 3/3/2015 pippo X
    4 3/3/2015 pluto X
    5 7/7/2015 pluto X
    6 8/7/2015
    7 15/8/2015 pluto X
    8 16/8/2015
    9 6/9/2015 paperino X


    da questa tabella devo conteggiare i soli valori unici e dovrei ottenere questo risultato:

    NOME: 3 (ricavato dal conteggio unico dei nomi pippo, pluto e paperino, escluse le celle vuote)
    ATT_1: 2
    (ricavato dal conteggio univoco di pippo X e pluto X, escluse le celle vuote)
    ATT_2: 3
    (ricavato dal conteggio univoco di pippo X, pluto X e paperino X, escluse le celle vuote)

    il primo risultato, utilizzando la formula =MATR.SOMMA.PRODOTTO(1/CONTA.SE(B2:B9;B2:B9&"");--(B2:B9<>""))
    riesco ad ottenerlo, ma gli altri due non so proprio come fare.

    Grazie a tutti.

    Sandro
    Ultima modifica fatta da:Canapone; 09/11/15 alle 14:44

  2. #2

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7121
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298
    Non ho capito bene la richiesta.
    Se vuoi valori unici, in base a quale criterio in ATT_1 si esclude paperino e invece in ATT_2 lo si include?

  3. #3
    L'avatar di delusan
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Roma
    Età
    58
    Messaggi
    15
    Versione Office
    2010 WIN
    Likes ricevuti
    0
    Likes dati
    5
    Ciao ges,
    chiarisco meglio la mia richiesta: dalla tabella che ho inviato devo ricavare quanti nomi ci sono (in questo caso 3: pippo, pluto e paperino); di queste le persone che hanno fatto attività 1 (in questo caso 2: pippo e pluto, anche se pluto l'attività 1 l'ha fatta due giorni diffenti, ma la mia finalità è contare solo le persone) e l'attività 2 (in questo caso 3; pippo, pluto e paperino).

    Grazie per l'interessamento.

    Un cordiale saluto
    Sandro

  4. #4
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1075
    Versione Office
    2010 su Win
    Likes ricevuti
    598
    Likes dati
    199
    Ciao,

    le tre formule:

    =SOMMA(SE(FREQUENZA(SE(B2:B1000<>"";CONFRONTA(B2:B1000;B2:B1000;0));RIF.RIGA(2:1000)-1);1))

    =SOMMA(SE(FREQUENZA(SE(B2:B1000<>"";SE(C2:C1000="X";CONFRONTA(B2:B1000;B2:B1000;0)));RIF.RIGA(2:1000)-1);1))

    =SOMMA(SE(FREQUENZA(SE(B2:B1000<>"";SE(D2:D1000="X";CONFRONTA(B2:B1000;B2:B1000;0)));RIF.RIGA(2:1000)-1);1))


    Tutte da confermare in forma matriciale.

  5. I seguenti 3 utenti hanno dato un "Like" a Canapone per questo post:


  6. #5
    L'avatar di delusan
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Roma
    Età
    58
    Messaggi
    15
    Versione Office
    2010 WIN
    Likes ricevuti
    0
    Likes dati
    5
    Grande Canapone!! :97:
    perfetto, proprio quello che mi occorreva.

    Grazie ancora

    Sandro

    PS. un saluto anche a ges e Baloon_50

  7. #6
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1075
    Versione Office
    2010 su Win
    Likes ricevuti
    598
    Likes dati
    199
    Ciao,

    grazie a te del cortese riscontro.

  8. #7

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7121
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298
    Ottimo, Canapone ha già risolto.
    Un saluto anche a te Sandro.

  9. #8

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4016
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Ciao a tutti,
    so che è risolto (complimenti per le formule Stefano), ma sono senza pc e mi chiedevo se un'alternativa non potesse essere la formula utilizzata da Sandro con il "conta.più.se" al posto del "conta.se"?!?:240:
    Ripeto, non posso provare quindi probabilmente è una castroneria :167:

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  10. #9
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1075
    Versione Office
    2010 su Win
    Likes ricevuti
    598
    Likes dati
    199

    "castroneria"

    Ciao Cromagno

    ora spero di non scrivere una castroneria

    Il segmento

    CONTA.SE(B2:B9;B2:B9&"")

    restituisce a denominatore un vettore di risultati sempre diversi da zero: è autoreferenziale.

    Se aggiungo altre condizioni e mi servo del conta.più.se( esempio c2:c9;"X") nel vettore comparirebbero degli zero a denominatore e la formula restituirebbe #div/0!.

    Aggiungo che per grossi volumi di dati la formula - sicuramente elegante - non è paragonabile a velocità a frequenza.

    Saluti
    Ultima modifica fatta da:Canapone; 10/11/15 alle 13:42

  11. I seguenti 2 utenti hanno dato un "Like" a Canapone per questo post:


  12. #10

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4016
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Grazie della spiegazione Stefano :246:
    Però essendo "testa dura" ci proverò ugualmente (diciamo alla "san Tommaso") :167::167:

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  13. #11
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1075
    Versione Office
    2010 su Win
    Likes ricevuti
    598
    Likes dati
    199
    Ciao,

    spero di essermi sbagliato.

  14. #12

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4016
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Ciao a tutti,
    ho fatto un paio di prove e sembrerebbe funzionare (forse mi ero spiegato male io)...
    Quindi (prendendo come base la formula di "Sandro") le tre formule sarebbero:

    =MATR.SOMMA.PRODOTTO(1/CONTA.SE(B2:B9;B2:B9&"");--(B2:B9<>""))

    =MATR.SOMMA.PRODOTTO(1/CONTA.PIÙ.SE(B2:B9;B2:B9&"";C2:C9;C2:C9&"");--(B2:B9<>"");--(C2:C9<>""))

    =MATR.SOMMA.PRODOTTO(1/CONTA.PIÙ.SE(B2:B9;B2:B9&"";D2:D9;D2:D9&"");--(B2:B9<>"");--(D2:D9<>""))

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  15. I seguenti 4 utenti hanno dato un "Like" a cromagno per questo post:


  16. #13
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1075
    Versione Office
    2010 su Win
    Likes ricevuti
    598
    Likes dati
    199
    Ciao Cromagno,

    ti eri spiegato bene.

    Ottime formule!

  17. #14

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4016
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Grazie Canapone,
    anche se alla fine il più grosso l'aveva già risolto "Sandro", mancava solo un'ulteriore condizione...

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  18. #15
    L'avatar di Canapone
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Firenze
    Messaggi
    1075
    Versione Office
    2010 su Win
    Likes ricevuti
    598
    Likes dati
    199
    Ciao,

    a me proprio il conta.più.se non era entrato e la mia spiegazione sebbene suonasse condivisibile era in buona parte una castroneria.

  19. #16
    L'avatar di delusan
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Roma
    Età
    58
    Messaggi
    15
    Versione Office
    2010 WIN
    Likes ricevuti
    0
    Likes dati
    5
    Bravo cromagno!!
    ho provato le tue formule sulla mia tabella e funzionano egregiamente.
    Quindi ora ho solo l'imbarazzo della scelta.
    Grazie mille anche a te del tempo dedicato a un mio problema.

    Un cordiale saluto

    Sandro

  20. #17
    L'avatar di ninai
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Barcellona P.G.
    Età
    55
    Messaggi
    1652
    Versione Office
    2010 PC
    Likes ricevuti
    889
    Likes dati
    183
    Bravo cromagno!!!
    avevo smanettato parecchio sulla formula iniziale , per trovare alternative alle formule di Canapone (ho una certa allergia per FREQUENZA()) ma non avevo ottenuto risultati validi.

  21. #18

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4016
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Grazie ninai e Sandro :185:
    (doveva essere una "faccina" per far capire che sono arrossito... :) )

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  22. #19
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1125
    Ciao a tutti
    giusto per la cronaca, le formule con il FREQUENZA sono di gran lunga più veloci di tutte le altre soluzioni simili, ovviamente in questo caso è di poco conto perché il database è molto piccolo, ma provate a testarlo su database con migliaia di righe e noterete un gran differenza....
    Un saluto a tutti
    :57:

Discussioni Simili

  1. Da tabella a colonna con valori unici
    Di Gianfranco55 nel forum Domande su Excel in generale
    Risposte: 6
    Ultimo Messaggio: 05/03/17, 20:00
  2. [Risolto] Contare gli unici valori contrassegnati
    Di Francesca77 nel forum Domande su Excel in generale
    Risposte: 8
    Ultimo Messaggio: 11/02/17, 23:07
  3. Conta Valori unici
    Di Gerardo Zuccalà nel forum Domande su Excel in generale
    Risposte: 7
    Ultimo Messaggio: 26/08/16, 13:12
  4. Conteggio valori unici
    Di delusan nel forum Domande su Excel in generale
    Risposte: 3
    Ultimo Messaggio: 09/11/15, 13:44
  5. Conta valori unici escludendo il dash
    Di Gerardo Zuccalà nel forum Domande su Excel in generale
    Risposte: 7
    Ultimo Messaggio: 01/08/15, 14:25

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •