Risultati da 1 a 13 di 13

Discussione: Quiz Natalizio



  1. #1
    L'avatar di Marius44
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Catania
    Età
    73
    Messaggi
    3209
    Versione Office
    Excel2010
    Likes ricevuti
    625
    Likes dati
    155

    Quiz Natalizio

    L'amico ninai (che saluto) ha proposto, nell'apposita sezione, un Quiz riguardante la classifica, tenendo conto delle celle vuote, di alcuni numeri.
    Poiché mi sono sentito (io che non ho un buon feeling con le formule) - ovviamente scherzo - un po' discriminato e, come me, penso anche altri che riversano le loro migliori energie principalmente su VBA, ho pensato di riproporre lo stesso Quiz per il quale, però, valgono SOLO LE SOLUZIONI CON VBA (non pensate che si semplice).

    Ecco a voi il Allegato 1372

    Buon lavoro a tutti
    Mario

  2. #2

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299
    Col vba per me questa è ardua!
    In teoria dovrebbe essere più facile col vba che con le formule ... e sempre in teoria non ci sarebbe differenza tra teoria e pratica, ma in pratica c'è! :127:
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  3. #3

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4018
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Ciao a tutti,
    in effetti non è semplice oppure sono io che ho sbagliato l'approccio iniziale e mi sono intestardito a voler finire ugualmente :292:

    Mario, per adesso ti posto solo il codice per la classifica crescente (normale e anomala), appena ho tempo provo anche la decrescente:

    Codice: 
    Option Explicit
    Dim Dati As Range, Ordinamenti(1 To 5, 1 To 12), i As Integer, cella As Range
    Dim x As Integer, y As Integer, z As Integer, confronto As Double
    
    
    Sub Classifiche()
    Set Dati = Range("A2:A13")
    
    
    Application.ScreenUpdating = False
    Dati.Copy
    Range("C2").Select
    ActiveCell.PasteSpecial xlPasteValues
    Range("C2:C13").Select
    ActiveWorkbook.Worksheets("Foglio1").Sort.SortFields.Clear
    ActiveWorkbook.Worksheets("Foglio1").Sort.SortFields.Add Key:=Range("C2"), _
    SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
    With ActiveWorkbook.Worksheets("Foglio1").Sort
        .SetRange Range("C2:C13")
        .Header = xlNo
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
    Application.CutCopyMode = False
    
    
    'Riempimento 1° colonna dell'Array
    z = 2
    For i = 2 To 13
        If Cells(i, 1) <> "" Then
            Ordinamenti(1, i - 1) = Cells(z, 3).Value
            z = z + 1
        Else
            Ordinamenti(1, i - 1) = ""
        End If
    Next i
    
    
    'Orinamento crescente Normale (2° colonna Array)
    x = 0
    y = 1
    z = 2
    For i = 2 To 13
        If Cells(i, 1) <> "" Then
            If Cells(z, 3).Value <> Cells(z - 1, 3).Value Then
                Ordinamenti(2, y) = x + 1
            Else
                Ordinamenti(2, y) = x
            End If
            x = x + 1
            z = z + 1
        Else
            Ordinamenti(2, y) = ""
        End If
         y = y + 1
    Next i
    
    
    'Orinamento crescente Anomalo (3° colonna Array)
    x = 0
    y = 1
    z = 2
    For i = 2 To 13
        If Cells(i, 1) <> "" Then
            If Cells(z, 3).Value <> Cells(z - 1, 3).Value Then
                Ordinamenti(3, y) = x + 1
                x = x + 1
            Else
                Ordinamenti(3, y) = x
            End If
            z = z + 1
        Else
            Ordinamenti(3, y) = ""
        End If
         y = y + 1
    Next i
    
    
    'Ricopio i dati nel foglio
    For i = 2 To 13
        For x = 1 To 12
            If Cells(i, 1).Value = Ordinamenti(1, x) Then
                Cells(i, 3).Value = Ordinamenti(2, x)
                Cells(i, 4).Value = Ordinamenti(3, x)
                GoTo prossimo
            End If
        Next x
    prossimo:
    Next i
    
    
    Range("A1").Select
    Application.ScreenUpdating = True
    Set Dati = Nothing
    End Sub

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  4. I seguenti utenti hanno dato un "Like"


  5. #4
    L'avatar di Gerardo Zuccalà
    Clicca e Apri
    Data Registrazione
    May 2015
    Località
    Milano, Italy
    Età
    49
    Messaggi
    4916
    Versione Office
    2013
    Likes ricevuti
    1117
    Likes dati
    1126
    Wooww!! :171::171::171: incredibile non abìvrei mai pensato fosse possibile!

    Comunque tutti dicono che le variabili ti aiutano, ma qui mi sa che ci rendono la vita molto più complicata
    l'unica variabile che ho capito è:

    Dim dati as a range
    Dati=Range("A2:A13")

    Tutto il resto :235:

  6. #5
    L'avatar di Marius44
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Catania
    Età
    73
    Messaggi
    3209
    Versione Office
    Excel2010
    Likes ricevuti
    625
    Likes dati
    155
    @cromagno
    Fin qui ottimo lavoro. Io ho usato un altro sistema ma sempre lì s'arriva.

    @gerardo
    L'avevo detto che sembrava facile ma ...

    Ciao,
    Mario

  7. #6

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Verona Provincia
    Età
    57
    Messaggi
    1017
    Versione Office
    .
    Likes ricevuti
    366
    Likes dati
    0
    Io ho partorito questo:

    Allegato 1381

    Qui il codice sottostante:

    Codice: 
    '---------------------------------------------------------------------------------------
    ' Procedure : Ordina
    ' Author    : scossa
    ' Date      : 18/12/2015
    ' Purpose   :
    '---------------------------------------------------------------------------------------
    '
    Public Sub Ordina(Optional ByVal nType As Integer = 1)
      Dim ws As Worksheet
      Dim rng As Range
      Dim rngAll As Range
      Dim cella As Range
      Dim j As Long
      Dim aDati As Variant
      Dim aDatiOrd As Variant
      Dim aDatiPos As Variant
      Dim nLR As Long
      Dim nPos As Long
      
      On Error GoTo Ordina_Error
      Set ws = ActiveSheet
      nLR = ws.Cells(Rows.Count, 1).End(xlUp).Row
      
      Set rngAll = ws.Range("A2:A" & nLR)
      Set rng = rngAll.SpecialCells(xlCellTypeConstants, 1)
      ReDim aDati(1 To rng.Cells.Count)
      ReDim aDatiPos(1 To rng.Cells.Count)
      ReDim aDatiOrd(1 To rng.Cells.Count)
      
      j = 0
      For Each cella In rng.Cells
        j = j + 1
        aDati(j) = cella.Value
        aDatiPos(j) = j
      Next
      aDatiOrd = BubbleSrtBi(aDati, nType)
      If nType = 1 Or nType = 2 Then
        For j = 2 To UBound(aDatiOrd)
          If aDatiOrd(j) = aDatiOrd(j - 1) Then
            aDatiPos(j) = j - 1
          End If
        Next
      Else
        If nType = 3 Then
          nPos = 1
          For j = 2 To UBound(aDatiOrd)
            If aDatiOrd(j) > aDatiOrd(j - 1) Then
              nPos = nPos + 1
            End If
            aDatiPos(j) = nPos
          Next
        ElseIf nType = 4 Then
          aDatiOrd = BubbleSrtBi(aDati, 1)
          nPos = 1
          For j = 1 To UBound(aDatiOrd) - 1
            If aDatiOrd(j + 1) > aDatiOrd(j) Then
              nPos = nPos + 1
            End If
          Next
          aDatiPos(1) = nPos
          For j = 2 To UBound(aDatiOrd)
            If aDatiOrd(j) > aDatiOrd(j - 1) Then
              nPos = nPos - 1
            End If
            aDatiPos(j) = nPos
          Next
        End If
      End If
      For Each cella In rngAll.Cells
        With Application
          nPos = .IfError(.Match(cella.Value, aDatiOrd, 0), 0)
          If nPos > 0 Then
            cella.Offset(0, 11 + nType).Value = aDatiPos(nPos)
          End If
        End With
      Next
      
      On Error GoTo 0
    Ordina_Error:
      If Err.Number <> 0 Then
        MsgBox "Error: " & Err.Description, vbCritical, "ERRORE"
      End If
      Set rng = Nothing
      Set rngAll = Nothing
      Set ws = Nothing
    End Sub
    
    Public Function BubbleSrtBi(ByVal ArrayIn As Variant, ByVal Order As Integer) As Variant
      Dim SrtTemp As Variant
      Dim i As Long
      Dim j As Long
      For i = LBound(ArrayIn) To UBound(ArrayIn)
        For j = i + 1 To UBound(ArrayIn)
          If Order = 1 Or Order = 3 Then
            If ArrayIn(i) > ArrayIn(j) Then
              SrtTemp = ArrayIn(j)
              ArrayIn(j) = ArrayIn(i)
              ArrayIn(i) = SrtTemp
            End If
          ElseIf Order = 2 Or Order = 4 Then
            If ArrayIn(i) < ArrayIn(j) Then
              SrtTemp = ArrayIn(j)
              ArrayIn(j) = ArrayIn(i)
              ArrayIn(i) = SrtTemp
            End If
          End If
        Next j
       Next i
      BubbleSrtBi = ArrayIn
    End Function
    
    Sub test()
      Call Ordina(1)
      Call Ordina(2)
      Call Ordina(3)
      Call Ordina(4)
    End Sub
    Bye!
    scossa
    scossa's web site
    ___
    Se tu hai una mela, e io ho una mela, e ce le scambiamo, allora tu ed io abbiamo sempre una mela per uno. Ma se tu hai un'idea, ed io ho un'idea, e ce le scambiamo, allora abbiamo entrambi due idee. (George Bernard Shaw)

  8. I seguenti utenti hanno dato un "Like"


  9. #7

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4018
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Buongiorno a tutti,
    contrariamente a quanto pensavo, la classifica che mi ha dato più problemi è stata la "Decrescente Normale" :251:

    Questo dovrebbe essere il codice completo (spero che non lo veda scossa... altro che tirata d'orecchie :1172: :127: )...

    Codice: 
    Option Explicit
    
    
    Sub Classifiche()
    Dim Dati As Range, Ordinamenti(1 To 5, 1 To 12), i As Integer, cella As Range
    Dim x As Integer, y As Integer, z As Integer, confronto As Double
    Dim MinNormale As Integer, MinAnomala As Integer
    
    
    Set Dati = Range("A2:A13")
    Application.ScreenUpdating = False
    Dati.Copy
    Range("C2").Select
    ActiveCell.PasteSpecial xlPasteValues
    Range("C2:C13").Select
    ActiveWorkbook.Worksheets("Foglio1").Sort.SortFields.Clear
    ActiveWorkbook.Worksheets("Foglio1").Sort.SortFields.Add Key:=Range("C2"), _
    SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
    With ActiveWorkbook.Worksheets("Foglio1").Sort
        .SetRange Range("C2:C13")
        .Header = xlNo
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
    Application.CutCopyMode = False
    
    
    'Riempimento 1° colonna dell'Array
    z = 2
    For i = 2 To 13
        If Cells(i, 1) <> "" Then
            Ordinamenti(1, i - 1) = Cells(z, 3).Value
            z = z + 1
        Else
            Ordinamenti(1, i - 1) = ""
        End If
    Next i
    
    
    'Orinamento crescente Normale (2° colonna Array)
    x = 0
    y = 1
    z = 2
    For i = 2 To 13
        If Cells(i, 1) <> "" Then
            If Cells(z, 3).Value <> Cells(z - 1, 3).Value Then
                Ordinamenti(2, y) = x + 1
            Else
                Ordinamenti(2, y) = x
            End If
            x = x + 1
            z = z + 1
        Else
            Ordinamenti(2, y) = ""
        End If
         y = y + 1
    Next i
    
    
    'Orinamento crescente Anomalo (3° colonna Array)
    x = 0
    y = 1
    z = 2
    For i = 2 To 13
        If Cells(i, 1) <> "" Then
            If Cells(z, 3).Value <> Cells(z - 1, 3).Value Then
                Ordinamenti(3, y) = x + 1
                x = x + 1
            Else
                Ordinamenti(3, y) = x
            End If
            z = z + 1
        Else
            Ordinamenti(3, y) = ""
        End If
         y = y + 1
    Next i
    
    
    'Recupero il rango più piccolo sia per la classifica normale che anomala
    MinAnomala = 0
    MinNormale = Application.WorksheetFunction.CountA(Dati)
    For i = 1 To 12
        If Ordinamenti(3, i) > MinAnomala Then
            MinAnomala = MinAnomala + 1
        End If
    Next i
    
    
    'Orinamento Decrescente Normale (4° colonna Array)
    y = 1
    z = 2
    For i = 2 To 13
        If Cells(i, 1) <> "" Then
            If Cells(i, 1) = Application.WorksheetFunction.Min(Dati) Then
                Ordinamenti(4, y) = MinNormale
            ElseIf Cells(z, 3).Value <> Cells(z - 1, 3).Value Then
                x = Application.WorksheetFunction.CountIf(Dati, Cells(z, 3))
                Ordinamenti(4, y) = MinNormale - x
                MinNormale = MinNormale - x
            Else
                Ordinamenti(4, y) = MinNormale
            End If
            z = z + 1
        Else
            Ordinamenti(4, y) = ""
        End If
         y = y + 1
    Next i
    
    
    'Orinamento Decrescente Anomalo (5° colonna Array)
    MinAnomala = MinAnomala + 1
    y = 1
    z = 2
    For i = 2 To 13
        If Cells(i, 1) <> "" Then
            If Cells(z, 3).Value <> Cells(z - 1, 3).Value Then
                Ordinamenti(5, y) = MinAnomala - 1
                MinAnomala = MinAnomala - 1
            Else
                Ordinamenti(5, y) = MinAnomala
            End If
            z = z + 1
        Else
            Ordinamenti(5, y) = ""
        End If
         y = y + 1
    Next i
    
    
    'Ricopio i dati nel foglio
    For i = 2 To 13
        For x = 1 To 12
            If Cells(i, 1).Value = Ordinamenti(1, x) Then
                Cells(i, 3).Value = Ordinamenti(2, x)
                Cells(i, 4).Value = Ordinamenti(3, x)
                Cells(i, 6).Value = Ordinamenti(4, x)
                Cells(i, 7).Value = Ordinamenti(5, x)
                GoTo prossimo
            End If
        Next x
    prossimo:
    Next i
    
    
    Range("A1").Select
    Application.ScreenUpdating = True
    Set Dati = Nothing
    End Sub
    [EDIT]
    @scossa
    ti ho nominato proprio adesso sperando che non vedessi il mio codice :288:

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  10. I seguenti utenti hanno dato un "Like"

    ges

  11. #8
    L'avatar di Marius44
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Catania
    Età
    73
    Messaggi
    3209
    Versione Office
    Excel2010
    Likes ricevuti
    625
    Likes dati
    155
    Buon giorno a tutti

    In primis lasciatemi dire che sono molto soddisfatto di me stesso: in un colpo solo, e con qualcosa che a prima vista sembrava banale, sono riuscito a scomodare "i vertici" (scossa, cromagno - che han dato una soluzione - Gerardo, ges). Non speravo tanto.

    Posto il mio codice (e, come dice cromagno, speriamo non lo veda scossa ... ) senza dubbio migliorabile ma, da quando ho ottenuto il risultato, non l'ho toccato per paura di ... rovinarlo.
    Codice: 
    Sub Classifiche()
    Dim cla(1 To 12) As Single
    Range("C2:G13").ClearContents
        For i = 2 To 13
            cla(i - 1) = Cells(i, 1)
        Next i
        For i = 1 To 11 'ordina la variabile crescente
        For j = i + 1 To 12
            If cla(i) <> 0 And cla(i) > cla(j) Then
                temp = cla(i)
                cla(i) = cla(j)
                cla(j) = temp
                temp = 0
            End If
        Next j
        Next i
        For i = 2 To 13 'crescente normale
            If Cells(i, 1) <> "" Then
                num = Cells(i, 1)
                For j = 1 To 12
                    If num = cla(j) Then
                        Cells(i, 3) = j - 2: Exit For
                    End If
                Next j
            End If
        Next i
        'crescente anomala 'crea una collection
        Dim NumColl As Collection
        Set NumColl = New Collection
        For i = 1 To 12
            If cla(i) > 0 Then
                NumColl.Add Item:=cla(i)
            End If
        Next i
        upnum = NumColl.Count 'elimina uguali
        For i = 1 To upnum - 1
            For j = i + 1 To upnum
                If NumColl.Item(i) = NumColl.Item(j) Then
                    NumColl.Remove i
                    i = i - 1
                    upnum = upnum - 1: Exit For
                End If
            Next j
        Next i
        For i = 2 To 13
            If Cells(i, 1) <> "" Then
                num = Cells(i, 1)
                For j = 1 To upnum
                    If num = NumColl(j) Then
                        Cells(i, 4) = j: Exit For
                    End If
                Next j
            End If
        Next i
        Set NumColl = Nothing
        For i = 1 To 11 'ordina la variabile decrescente
            For j = i + 1 To 12
                If cla(i) < cla(j) Then
                    temp = cla(i)
                    cla(i) = cla(j)
                    cla(j) = temp
                    temp = 0
                End If
            Next j
        Next i
        For i = 2 To 13 'decrescente normale
            If Cells(i, 1) <> "" Then
                num = Cells(i, 1)
                For j = 1 To 12
                    If num = cla(j) Then
                        Cells(i, 6) = j: Exit For
                    End If
                Next j
            End If
        Next i
        'decrescente anomala   'crea una collection
        Set NumColl = New Collection
        For i = 1 To 12
            If cla(i) > 0 Then
                NumColl.Add Item:=cla(i)
            End If
        Next i
        upnum = NumColl.Count 'elimina uguali
        For i = 1 To upnum - 1
            For j = i + 1 To upnum
                If NumColl.Item(i) = NumColl.Item(j) Then
                    NumColl.Remove i
                    i = i - 1
                    upnum = upnum - 1: Exit For
                End If
            Next j
        Next i
        For i = 2 To 13
            If Cells(i, 1) <> "" Then
                num = Cells(i, 1)
                For j = 1 To upnum
                    If num = NumColl(j) Then
                        Cells(i, 7) = j: Exit For
                    End If
                Next j
            End If
        Next i
        Set NumColl = Nothing
    End Sub
    Per quanto attiene le classifiche anomale ho utilizzato (cosa alquanto rara per me) le Collection.
    Auguri a tutti
    e ... buon proseguimento per chi volesse unirsi (penso a Baloon, a Rollis e a tanti che ora mi sfuggono) ai, come si potrebbe dire, ... VBA-Lovers
    Ciao,
    Mario

  12. I seguenti 2 utenti hanno dato un "Like" a Marius44 per questo post:


  13. #9

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4018
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Nella mia poca esperienza col VBA, questa è la prima volta in cui ho pensato: "Ma chi me lo fa fare ad usare il VBA al posto delle formule!:292: ".

    Buone Feste a tutti :246:



    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  14. #10

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Verona Provincia
    Età
    57
    Messaggi
    1017
    Versione Office
    .
    Likes ricevuti
    366
    Likes dati
    0
    Citazione Originariamente Scritto da cromagno Visualizza Messaggio
    Nella mia poca esperienza col VBA, questa è la prima volta in cui ho pensato: "Ma chi me lo fa fare ad usare il VBA al posto delle formule!:292: ".
    E perché mai?

    Basta VBAbizzare le formule di ninai :90:

    Codice: 
    Sub OrdinaFake(Optional ByVal nType As Integer = 1)
      Dim ws As Worksheet
      Dim rngAll As Range
      Dim cella As Range
      Dim nLR As Long
      
      On Error GoTo OrdinaFake_Error
      
      Set ws = ActiveSheet
      nLR = ws.Cells(Rows.Count, 1).End(xlUp).Row
      
      Set rngAll = ws.Range("A2:A" & nLR)
      Select Case nType
        Case 1
          For Each cella In rngAll
            cella.Offset(0, 11 + nType).Formula = Evaluate("IF(" & cella.Address & _
              ",SUMPRODUCT(((" & rngAll.Address & ">" & cella.Address & ")*(" & rngAll.Address & "<>"""")))+1,"""")")
          Next
        Case 2
          For Each cella In rngAll
            cella.Offset(0, 11 + nType).Formula = Evaluate("IF(" & cella.Address & _
              ",SUMPRODUCT(((" & rngAll.Address & "<" & cella.Address & ")*(" & rngAll.Address & "<>"""")))+1,"""")")
          Next
        Case 3
          For Each cella In rngAll
            cella.Offset(0, 11 + nType).Formula = Evaluate("IF(" & cella.Address & _
              ",SUMPRODUCT(((" & rngAll.Address & "<" & cella.Address & ")*(" & rngAll.Address & _
              "<>""""))/COUNTIF(" & rngAll.Address & "," & rngAll.Address & "&""""))+1,"""")")
          Next
        Case 4
          For Each cella In rngAll
          '"IF(" & cella.Address & ",SUMPRODUCT(((" & rngAll.Address & ">" & cella.Address & _ 
            ")*(" & rngAll.Address & "<>""""))/COUNTIF(" & rngAll.Address & "," & rngAll.Address & "&""""))+1,"""")"
            cella.Offset(0, 11 + nType).Formula = Evaluate("IF(" & cella.Address & _
              ",SUMPRODUCT(((" & rngAll.Address & ">" & cella.Address & ")*(" & rngAll.Address & _
              "<>""""))/COUNTIF(" & rngAll.Address & "," & rngAll.Address & "&""""))+1,"""")")
          Next
      End Select
      On Error GoTo 0
    OrdinaFake_Error:
      If Err.Number <> 0 Then
        MsgBox "Error: " & Err.Description, vbCritical, "ERRORE"
      End If
      Set rngAll = Nothing
      Set ws = Nothing
    End Sub
    
    
    Sub test()
      Call OrdinaFake(1)
      Call OrdinaFake(2)
      Call OrdinaFake(3)
      Call OrdinaFake(4)
    End Sub
    Bye!
    scossa
    scossa's web site
    ___
    Se tu hai una mela, e io ho una mela, e ce le scambiamo, allora tu ed io abbiamo sempre una mela per uno. Ma se tu hai un'idea, ed io ho un'idea, e ce le scambiamo, allora abbiamo entrambi due idee. (George Bernard Shaw)

  15. I seguenti 2 utenti hanno dato un "Like" a scossa per questo post:


  16. #11

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4018
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923
    Citazione Originariamente Scritto da scossa Visualizza Messaggio
    E perché mai?

    Basta VBAbizzare le formule di ninai :90:
    :246:
    Ci avevo pensato, ma penso che Mario mi avrebbe squalificato :275: :127:

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  17. #12

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7132
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2063
    Likes dati
    1299
    Ottimo ragazzi! :255:
    Lasciatemi il tempo di studiarmi le vostre soluzioni .... e intanto .... non pensate di proporre il quiz di capodanno!!!! :127::127::127:
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  18. #13
    L'avatar di Baloon_50
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Milano - Italy
    Età
    67
    Messaggi
    3340
    Versione Office
    2013 PC
    Likes ricevuti
    483
    Likes dati
    49
    Mario grazie per avermi annoverato tra i VBA-Lovers ma dopo l'intervento del buon Scossa :23: credo che non ci sia molto da fare comunque come dice anche Ges "Ottimo ragazzi! :255: Lasciatemi il tempo di studiarmi le vostre soluzioni".

    Nel frattempo ti ringrazio per gli auguri e li estendo anche a tutti gli altri che ormai considero degli ottimi amici



    BUON NATALE E FELICE ANNO NUOVO

    A volte basta usare parole inutili come “grazie” e “per favore” per rendere la vita più bella.
    (ELKonigsburg)
    Dice il saggio : "se vuoi essere aiutato devi metter l'allegato"
    (Nick Carter - Ten)

Discussioni Simili

  1. [Risolto] Quiz
    Di Anthony nel forum Domande su Excel in generale
    Risposte: 35
    Ultimo Messaggio: 22/11/16, 15:02
  2. Quiz
    Di Anthony nel forum Domande su Excel VBA e MACRO
    Risposte: 0
    Ultimo Messaggio: 19/11/16, 14:16
  3. Quiz
    Di Anthony nel forum Domande su Excel in generale
    Risposte: 59
    Ultimo Messaggio: 08/11/16, 02:18
  4. Quiz natalizio
    Di ninai nel forum Domande su Excel in generale
    Risposte: 20
    Ultimo Messaggio: 16/12/15, 00:28
  5. quiz su excel
    Di Stefano nel forum Problemi, suggerimenti e Novità del forum
    Risposte: 1
    Ultimo Messaggio: 05/06/15, 18:02

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •