Risultati da 1 a 4 di 4

Discussione: Popolare la TextBox



  1. #1
    L'avatar di dautattmaui
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    Bari
    Messaggi
    116
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    0

    Popolare la TextBox

    Buonasera,


    sono a chiedere un'aiuto per risolvere un problema su un foglio di lavoro.


    Ho tre colonne dove sono inseriti circa 30-40 voci e due UserForm.

    Nella prima UserForm vi è ListBox e n. 3 TextBox dove vengono visualizzate tutte le voci,

    cliccando su una voce la medesima viene visualizzata sulla TextBox.


    Nella seconda UserForm sono inseriti n. 3 TextBox con i seguenti bottoni:

    > 1° bottone: avanzamento rapido alla prima voce;
    > 2° bottone: avanzamento rapido all'ultima voce;
    > 3° bottone: avanzamento graduale delle voci in sù;
    > 4° bottone: avanzamento graduale delle voci in giù.

    All'apertura dell'UserForm, riesco a visualizzare le prime voci inserite sulla prima cella
    e purtroppo non riesco a completare e sono a chiederVi se è possibile un Vostro intervento.

    Vi allego il file.

    Grazie come sempre anticipatamente,

    Mauro
    File Allegati File Allegati

  2. #2

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    Località
    Sardegna
    Età
    37
    Messaggi
    4046
    Versione Office
    2013
    Likes ricevuti
    1239
    Likes dati
    931

    Re: Popolare la TextBox

    Ciao dautattmaui,

    io dichiarerei 3 variabili pubbliche alle quali assegnerei i primi valori all'inizializzazione della userform:
    • Riga = riga attuale
    • iRiga = prima riga dell'elenco
    • uRiga = ultima riga dell'elenco


    Quindi i codici per quella userform e relativi oggetti saranno:

    Codice: 
    Option Explicit
    Public Riga As Long, iRiga As Long, uRiga As Long
    
    
    Private Sub Cmd_Prima_Voce_Click()
    Txt_Prodotti.Value = Range("G" & iRiga).Value
    Txt_Frutta.Value = Range("H" & iRiga).Value
    Txt_Verdura.Value = Range("I" & iRiga).Value
    Riga = iRiga
    End Sub
    
    
    Private Sub Cmd_Ultima_Voce_Click()
    Txt_Prodotti.Value = Range("G" & uRiga).Value
    Txt_Frutta.Value = Range("H" & uRiga).Value
    Txt_Verdura.Value = Range("I" & uRiga).Value
    Riga = uRiga
    End Sub
    
    
    Private Sub Cmd_Voce_giù_Click()
    If Riga < uRiga Then
        Txt_Prodotti.Value = Range("G" & Riga + 1).Value
        Txt_Frutta.Value = Range("H" & Riga + 1).Value
        Txt_Verdura.Value = Range("I" & Riga + 1).Value
        Riga = Riga + 1
    End If
    End Sub
    
    
    Private Sub Cmd_Voce_sù_Click()
    If Riga > iRiga Then
        Txt_Prodotti.Value = Range("G" & Riga - 1).Value
        Txt_Frutta.Value = Range("H" & Riga - 1).Value
        Txt_Verdura.Value = Range("I" & Riga - 1).Value
        Riga = Riga - 1
    End If
    End Sub
    
    
    Private Sub UserForm_Initialize()
    Txt_Prodotti.Value = Range("G6").Value
    Txt_Frutta.Value = Range("H6").Value
    Txt_Verdura.Value = Range("I6").Value
    iRiga = 6
    Riga = iRiga
    uRiga = Worksheets("Voci").Range("G" & Rows.Count).End(xlUp).Row
    Label1.Caption = "Voci inserite: " & Range("M3").Value
    End Sub
    File Allegati File Allegati

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."

  3. #3
    L'avatar di rollis13
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Cordenons
    Messaggi
    823
    Versione Office
    2016 64bit
    Likes ricevuti
    150
    Likes dati
    55

    Re: Popolare la TextBox

    Vabbè, è venuta simile a quella di cromagno ma visto che ho perso tempo la pubblico lo stesso. Da mettere al posto dell'attuale codice nel modulo Frm_TextBox.
    Codice: 
    Option Explicit
    Public attuale As Long
    Public lr As Long
    
    
    Private Sub Cmd_Prima_Voce_Click()
    
        attuale = 6
        Txt_Prodotti.Value = Range("G" & attuale).Value
        Txt_Frutta.Value = Range("H" & attuale).Value
        Txt_Verdura.Value = Range("I" & attuale).Value
        
    End Sub
    
    Private Sub Cmd_Ultima_Voce_Click()
    
        attuale = lr
        Txt_Prodotti.Value = Range("G" & attuale).Value
        Txt_Frutta.Value = Range("H" & attuale).Value
        Txt_Verdura.Value = Range("I" & attuale).Value
        
    End Sub
    
    Private Sub Cmd_Voce_giù_Click()
    
        If attuale < lr Then
            attuale = attuale + 1
        End If
        Txt_Prodotti.Value = Range("G" & attuale).Value
        Txt_Frutta.Value = Range("H" & attuale).Value
        Txt_Verdura.Value = Range("I" & attuale).Value
    
    End Sub
    
    Private Sub Cmd_Voce_sù_Click()
    
        If attuale > 6 Then
            attuale = attuale - 1
        End If
        Txt_Prodotti.Value = Range("G" & attuale).Value
        Txt_Frutta.Value = Range("H" & attuale).Value
        Txt_Verdura.Value = Range("I" & attuale).Value
      
    End Sub
    
    Private Sub UserForm_Initialize()
    
        lr = Range("G" & Rows.Count).End(xlUp).Row
        attuale = 6
        Txt_Prodotti.Value = Range("G" & attuale).Value
        Txt_Frutta.Value = Range("H" & attuale).Value
        Txt_Verdura.Value = Range("I" & attuale).Value
        Label1.Caption = "Voci inserite: " & Range("M3").Value
        
    End Sub

  4. #4
    L'avatar di dautattmaui
    Clicca e Apri
    Data Registrazione
    Jan 2016
    Località
    Bari
    Messaggi
    116
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    0

    Re: Popolare la TextBox

    Grazie mille dell'aiuto ..... :246: va benissimo.

Discussioni Simili

  1. [Risolto] Popolare ComboBox a due colonne
    Di dautattmaui nel forum Domande su Excel VBA e MACRO
    Risposte: 9
    Ultimo Messaggio: 14/03/17, 11:16
  2. Popolare combobox
    Di lucas22f nel forum Domande su Excel VBA e MACRO
    Risposte: 2
    Ultimo Messaggio: 03/12/16, 22:19
  3. Come popolare una ListBox
    Di aurelio125 nel forum Domande su Excel VBA e MACRO
    Risposte: 9
    Ultimo Messaggio: 11/11/16, 01:24
  4. Come popolare i campi di TextBox in base a una ListBox
    Di ges nel forum Domande su Excel VBA e MACRO
    Risposte: 13
    Ultimo Messaggio: 14/09/16, 15:31
  5. Popolare ListBox dal ComboBox
    Di Pacifico437 nel forum Domande su Excel VBA e MACRO
    Risposte: 4
    Ultimo Messaggio: 11/09/16, 20:07

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •