Risultati da 1 a 27 di 27

Discussione: Aiuto correzione macro



  1. #1
    L'avatar di lala10
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    N/D
    Messaggi
    68
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    16

    Aiuto correzione macro

    Ciao a tutti,
    ho provato a scrivere una macro ma quando provo a farla girare mi restituisce solo il primo dei risultati cercati e poi un altro che non c'entra niente con ciò che voglio.
    Sicuramente c'è molto di sbagliato nella mia macro ma ho bisogno del vostro aiuto per capirlo.
    Vi spiego, nel foglio RIENTRO LAV nella colonna F voglio ottenere una serie di date tenendo conto di:
    -se il cartellino (colonna B) del foglio RIENTRO LAV è presente anche nel foglio LAVORAZIONI allora mi restituisci la data scritta nel foglio lavorazioni aumentata di 12 giorni lavorativi (sono tutti scritti nella colonna K del foglio DISTINTA BASE)
    -se invece il cartellino è presente solo nel foglio RIENTRO LAV allora mi restituisci la data scritta in RIENTRO LAV

    Non è una cosa difficile ma non riesco proprio a risolverla.
    Grazie mille per l'aiuto
    In allegato il file excel di prova con la macro che ho provato a scrivere
    File Allegati File Allegati

  2. #2
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1102
    Versione Office
    2010
    Likes ricevuti
    141
    Likes dati
    1

    Re: Aiuto correzione macro

    prova questa

    Codice: 
    Sub aggiorna_rientrolavorazioni()
    Dim Wks1 As Worksheet, Wks2 As Worksheet, uRiga1 As Long, uRiga2 As Long
    Dim i As Long, j As Long, Riga As Long, dt1 As Date, dt2 As Date
    Dim uRig2 As Long, a As Long, dt As Long, num As Long
    
    Set Wks1 = Worksheets("LAVORAZIONI")
    Set Wks2 = Worksheets("RIENTRO LAV")
    uRiga1 = Wks1.Range("B" & Rows.Count).End(xlUp).Row
    uRiga2 = Wks2.Range("B" & Rows.Count).End(xlUp).Row
    Riga = 3
    uRig2 = Sheets("Distinta base").Cells(Rows.Count, 11).End(xlUp).Row
    With Wks2
        For i = 3 To uRiga2                   'NEL FOGLIO R.LAV MI PRENDI IL PRIMO CARTELLINO
            For j = 3 To uRiga1               'PER OGNI CARTELLINO DEL FOGLIO R.LAV MI CONTROLLI I CARTELLINI DEL FOGLIO LAV
                If .Range("B" & i).Value = Wks1.Range("B" & j).Value Then         'SE HO TROVATO IL CARTELLINO UGUALE
                    dt1 = Wks1.Range("F" & j).Value    'assume la data
                        For a = 2 To uRig2                    'cerca fra i giorni lavorativi
                            dt2 = Sheets("Distinta base").Cells(a, 11).Value
                            If dt2 = dt1 Then dt = a: Exit For        'se ho trovato la data nel calensario imposto la riga dt e esco dal ciclo for e gli toglgo 12 giorni in modo da avere la nuova data
                        Next a
                        'serve per analizzare tutto il calendario finchènon trovo la data che mi interessa
                        num = dt - 12                      'diminuisce la riga individuata di 12 perchè è il numero di giorni per il rientro lav.
                        dt2 = Sheets("Distinta base").Range("K" & num).Value   'assume la nuova data aggiornata
                       .Range("F" & Riga).Value = dt2 'scrive la nuova data individuata nella colonna di data aggiornata del r.lav
                       Riga = Riga + 1
                       Exit For '<<<<<<<<<<<<<<<<<<
                Else
                     dt1 = .Range("D" & j).Value  'SE NON HO TROVATO IL CARTELLINO UGUALE SIGNIFICA CHE LA SUA PRIMA FASE è IL R.LAV QUINDI IMPOSTO IL PUNTATORE SULLA DATA DI R.LAV
                     Riga = Riga + 1
                End If
            Next j
        Next i
    End With
    End Sub
    Districarsi tra 3 cicli for non è facile, io ne farei uno solo urilizzando il metodo find per trovare quello che ti serve, guadagni in velocità e leggibilità del codice

  3. #3
    L'avatar di lala10
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    N/D
    Messaggi
    68
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    16

    Re: Aiuto correzione macro

    Ciao Patel ti ringrazio moltissimo per la risposta e vorrei chiederti, se non ti crea troppo disturbo, di modificare la mia VBA con il metodo find, voglio seguire il tuo consiglio :)
    Grazie mille ancora sei stato di grandissimo aiuto!

  4. #4
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1102
    Versione Office
    2010
    Likes ricevuti
    141
    Likes dati
    1

    Re: Aiuto correzione macro

    mi sembra comunque che non funzioni, sbaglio o ne manca soltanto uno (quello evidenziato in giallo) ?
    prova questa
    Codice: 
    Sub aggiorna()
    Dim dt1 As Date
    Set WksRientro = Worksheets("RIENTRO LAV")
    urLav = Worksheets("LAVORAZIONI").Range("B" & Rows.Count).End(xlUp).Row
    uRiga = WksRientro.Range("B" & Rows.Count).End(xlUp).Row
    uRbase = Sheets("Distinta base").Cells(Rows.Count, "K").End(xlUp).Row
    Set RngBase = Sheets("Distinta base").Range("K2:K" & uRbase)
    Set RngLav = Sheets("LAVORAZIONI").Range("B2:B" & urLav)
    
    Riga = 3
    
    With WksRientro
        For i = 3 To uRiga                   'NEL FOGLIO R.LAV MI PRENDI IL PRIMO CARTELLINO
          Cartellino = .Range("B" & i).Value
          Set c = RngLav.Find(Cartellino, LookIn:=xlValues)
          If Not c Is Nothing Then
             dt1 = c.Offset(0, 4)
             Set cc = RngBase.Find(dt1, LookIn:=xlFormulas)
             If Not cc Is Nothing Then
               dt = cc.Row
               num = dt - 12                      'diminuisce la riga individuata di 12 perchè è il numero di giorni per il rientro lav.
               dt2 = Sheets("Distinta base").Range("K" & num).Value   'assume la nuova data aggiornata
               .Range("F" & i).Value = dt2 'scrive la nuova data individuata nella colonna di data aggiornata del r.lav
             End If
           End If
        Next i
    End With
    End Sub

  5. #5
    L'avatar di lala10
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    N/D
    Messaggi
    68
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    16

    Re: Aiuto correzione macro

    si hai ragione manca quello! e poi dopo l'ho provata sul file che ho con moltissimi dati e non andava bene.. ora provo questa e ti faccio sapere graziee

    -----------Post aggregato-------

    Dove usi Find mi dice "impossibile trovare il metodo o il membro dei dati" un errore di compilazione, cosa può essere?

  6. #6
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1102
    Versione Office
    2010
    Likes ricevuti
    141
    Likes dati
    1

    Re: Aiuto correzione macro

    a me funziona bene, prova a riallegare il file

  7. #7
    L'avatar di lala10
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    N/D
    Messaggi
    68
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    16

    Re: Aiuto correzione macro

    Ok ho risolto il problema che ti dicevo ma quando attivo la macro mi restituisce la cella vuota per il cartellino che si trova solo in LAVORAZIONI mentre invece mi dovrebbe restituire la data presente in colonna F dello stesso foglio.
    Lo fa anche a te?

  8. #8
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1102
    Versione Office
    2010
    Likes ricevuti
    141
    Likes dati
    1

    Re: Aiuto correzione macro

    lo fa anche a me, quale data dovrebbe restituire ? quella che c'è in colonna D ? 28/07/2016 ?
    se è così
    Codice: 
    Sub aggiorna()
    Dim dt1 As Date
    Set WksRientro = Worksheets("RIENTRO LAV")
    urLav = Worksheets("LAVORAZIONI").Range("B" & Rows.Count).End(xlUp).Row
    uRiga = WksRientro.Range("B" & Rows.Count).End(xlUp).Row
    uRbase = Sheets("Distinta base").Cells(Rows.Count, "K").End(xlUp).Row
    Set RngBase = Sheets("Distinta base").Range("K2:K" & uRbase)
    Set RngLav = Sheets("LAVORAZIONI").Range("B2:B" & urLav)
    
    Riga = 3
    
    With WksRientro
        For i = 3 To uRiga                   'NEL FOGLIO R.LAV MI PRENDI IL PRIMO CARTELLINO
          Cartellino = .Range("B" & i).Value
          Set c = RngLav.Find(Cartellino, LookIn:=xlValues)
          If Not c Is Nothing Then
             dt1 = c.Offset(0, 4)
             Set cc = RngBase.Find(dt1, LookIn:=xlFormulas)
             If Not cc Is Nothing Then
               dt = cc.Row
               num = dt - 12                      'diminuisce la riga individuata di 12 perchè è il numero di giorni per il rientro lav.
               dt2 = Sheets("Distinta base").Range("K" & num).Value   'assume la nuova data aggiornata
               .Range("F" & i).Value = dt2 'scrive la nuova data individuata nella colonna di data aggiornata del r.lav
             End If
           Else
               .Range("F" & i).Value = .Range("D" & i).Value
           End If
        Next i
    End With
    End Sub

  9. #9
    L'avatar di lala10
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    N/D
    Messaggi
    68
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    16

    Re: Aiuto correzione macro

    Si si esatto scusami ma prima ho sbagliato e ho scritto colonna F. Intendevo colonna D!

  10. #10
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1102
    Versione Office
    2010
    Likes ricevuti
    141
    Likes dati
    1

    Re: Aiuto correzione macro

    ti ho messo le modifiche nel post precedente

  11. #11
    L'avatar di lala10
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    N/D
    Messaggi
    68
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    16

    Re: Aiuto correzione macro

    Ciao sul foglio che ho allegato qui funziona perfettamente ma se provo a copiarla nel mio progetto non funziona cioè mi dice che le variabili non sono definite e molte altre cose. Non riesco a capire perché funziona solo su quella cartella excel. Hai qualche suggerimento?

  12. #12
    L'avatar di Rubik83
    Clicca e Apri
    Data Registrazione
    May 2016
    Località
    Sant'Agata Bolognese
    Messaggi
    17
    Versione Office
    Excel 2011
    Likes ricevuti
    10
    Likes dati
    0

    Re: Aiuto correzione macro

    Ciao Lala,

    se vuoi si può fare il tutto anche senza macro.Ti allego il file che ho creato.






    Ciao
    File Allegati File Allegati

  13. I seguenti utenti hanno dato un "Like"


  14. #13
    L'avatar di lala10
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    N/D
    Messaggi
    68
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    16

    Re: Aiuto correzione macro

    Ciao Rubik ti ringrazio molto ma purtroppo devo utilizzare le macro :(

  15. #14
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1102
    Versione Office
    2010
    Likes ricevuti
    141
    Likes dati
    1

    Re: Aiuto correzione macro

    io ho visto soltanto il file che hai allegato ed ho fatto la macro di conseguenza, nel tuo probabilmente hai in testa la direttiva option explicit che obbliga a dichiarare tutte le variabili, cosa che io non ho fatto.
    prova a toglierla o a dichiarare tutte le variabili

  16. #15
    L'avatar di lala10
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    N/D
    Messaggi
    68
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    16

    Re: Aiuto correzione macro

    si è proprio così..

  17. #16
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1102
    Versione Office
    2010
    Likes ricevuti
    141
    Likes dati
    1

    Re: Aiuto correzione macro

    e quindi togliendo option explicit funziona ?

  18. #17
    L'avatar di lala10
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    N/D
    Messaggi
    68
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    16

    Re: Aiuto correzione macro

    non posso toglierlo perchè in quel foglio ci sono tante altre VBA che hanno bisogno di Option explicit :(

  19. #18
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1102
    Versione Office
    2010
    Likes ricevuti
    141
    Likes dati
    1

    Re: Aiuto correzione macro

    lo puoi togliere tranquillamente, serve solo a ricordarti di dichiarare le variabili, non influenza il funzionamento delle macro già funzionanti
    Basta provare, ci vuole poco a rimetterlo, devi osare un po' di più se vuoi imparare

  20. #19
    L'avatar di lala10
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    N/D
    Messaggi
    68
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    16

    Re: Aiuto correzione macro

    Hai ragione l'ho tolto e per le altre macro non è cambiato nulla solo che appena provo a far partire la tua macro mi compare l'errore 400 e mi riporta alla pagina della VBA senza evidenziare niente ...poi se torno sul foglio rientro lav vedo che alcune date me le ha scritte ma da un certo punto in poi non scrive più nulla. Ti viene in mente qualche errore? è strano perchè sul foglio di prova che ho allegato qui funziona benissimo, nel mio ho moltissimi dati ma non credo sia un problema..

  21. #20
    L'avatar di lala10
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    N/D
    Messaggi
    68
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    16

    Re: Aiuto correzione macro

    Ho fatto un copia e incolla dei miei dati e ho allegato il file così puoi vedere l'errore spero che si riesca a risolvere :(
    File Allegati File Allegati

  22. #21
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1102
    Versione Office
    2010
    Likes ricevuti
    141
    Likes dati
    1

    Re: Aiuto correzione macro

    mi dovresti spiegare questo punto
    Codice: 
    num = dt - 12                      'diminuisce la riga individuata di 12 perchè è il numero di giorni per il rientro lav.
    dt2 = Sheets("Distinta base").Range("K" & num).Value   'assume la nuova data aggiornata
    l'errore nasce se num è negativo, nel punto in cui avviene l'errore dt = 9, il cartellino è 82834
    cosa si deve fare in questi casi ?
    io propongo
    Codice: 
    Sub aggiorna()
    Dim WksRientro As Worksheet, urLav As Long, uRiga As Long, uRbase As Long
    Dim RngBase As Range, RngLav As Range
    Dim dt1 As Date, Riga As Long, i As Long
    Set WksRientro = Worksheets("RIENTRO LAV")
    urLav = Worksheets("LAVORAZIONI").Range("B" & Rows.Count).End(xlUp).Row
    uRiga = WksRientro.Range("B" & Rows.Count).End(xlUp).Row
    uRbase = Sheets("Distinta base").Cells(Rows.Count, "K").End(xlUp).Row
    Set RngBase = Sheets("Distinta base").Range("K2:K" & uRbase)
    Set RngLav = Sheets("LAVORAZIONI").Range("B3:B" & urLav)
    
    With WksRientro
        .Range("F3:F" & uRiga).ClearContents 
        For i = 3 To uRiga                   'NEL FOGLIO R.LAV MI PRENDI IL PRIMO CARTELLINO
            Cartellino = .Range("B" & i).Value
            Set c = RngLav.Find(Cartellino, LookIn:=xlValues)
            If Not c Is Nothing Then
               dt1 = c.Offset(0, 4)
               Set cc = RngBase.Find(dt1, LookIn:=xlFormulas)
               If Not cc Is Nothing Then
                  dt = cc.Row
                  num = dt - 12                      'diminuisce la riga individuata di 12 perchè è il numero di giorni per il rientro lav.
                  If num > 1 Then
                     dt2 = Sheets("Distinta base").Range("K" & num).Value   'assume la nuova data aggiornata
                     .Range("F" & i).Value = dt2 'scrive la nuova data individuata nella colonna di data aggiornata del r.lav
                  End If 
               End If
            Else
               .Range("F" & i).Value = .Range("D" & i).Value
            End If
        Next i
    End With
    End Sub

  23. #22
    L'avatar di lala10
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    N/D
    Messaggi
    68
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    16

    Re: Aiuto correzione macro

    ciao allora ti spiego quel punto: se il cartellino cercato è presente anche nel foglio LAVORAZIONI allora mi prendi la rispettiva data scritta in colonna F (rappresenta la data in cui il cartellino è andato in lavorazione), a questo punto devo scrivere la data in cui RIENTRA dalla lavorazione aggiungendogli dunque 12 giorni lavorativi (giorni necessari per passare da lav. a rientro lav.). Dato che parlo di giorni lavorativi vado in colonna K del foglio DISTINTA BASE e individuo la riga in cui è presente la data della lavorazione e ad essa sottraggo 12 righe (sottraggo perchè le date sono scritte in ordine decrescente) e individuo la data di Rientro lav.
    Nel caso del cartellino 82834 la data da cercare è 29/02/2016 e aggiungendo 12 gg lavorativi viene fuori 16/03/2016 (che in questo caso coincide anche con la data stimata di rientro lavorazione)

  24. #23
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1102
    Versione Office
    2010
    Likes ricevuti
    141
    Likes dati
    1

    Re: Aiuto correzione macro

    non funziona bene il find, nella ricerca della data 29/02/2016 da per buona anche la 29/12/2016 e quindi nasce l'errore

  25. #24
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1102
    Versione Office
    2010
    Likes ricevuti
    141
    Likes dati
    1

    Re: Aiuto correzione macro

    forse ho trovato il modo
    Codice: 
    Sub aggiorna()
    Dim WksRientro As Worksheet, urLav As Long, uRiga As Long, uRbase As Long
    Dim RngBase As Range, RngLav As Range
    Dim dt1 As Date, Riga As Long, i As Long
    Set WksRientro = Worksheets("RIENTRO LAV")
    urLav = Worksheets("LAVORAZIONI").Range("B" & Rows.Count).End(xlUp).Row
    uRiga = WksRientro.Range("B" & Rows.Count).End(xlUp).Row
    uRbase = Sheets("Distinta base").Cells(Rows.Count, "K").End(xlUp).Row
    Set RngBase = Sheets("Distinta base").Range("K2:K" & uRbase)
    Set RngLav = Sheets("LAVORAZIONI").Range("B3:B" & urLav)
    
    With WksRientro
        .Range("F3:F" & uRiga).ClearContents
        For i = 3 To uRiga                   'NEL FOGLIO R.LAV MI PRENDI IL PRIMO CARTELLINO
            Cartellino = .Range("B" & i).Value
            Set c = RngLav.Find(Cartellino, LookIn:=xlValues)
            If Not c Is Nothing Then
               dt1 = c.Offset(0, 4)
               Set cc = RngBase.Find(dt1, LookIn:=xlFormulas, LookAt:=xlWhole, searchDirection:=xlPrevious)
               If Not cc Is Nothing Then
                  dt = cc.Row
                  num = dt - 12                      'diminuisce la riga individuata di 12 perchè è il numero di giorni per il rientro lav.
                  If num > 1 Then
                     dt2 = Sheets("Distinta base").Range("K" & num).Value   'assume la nuova data aggiornata
                     .Range("F" & i).Value = dt2 'scrive la nuova data individuata nella colonna di data aggiornata del r.lav
                  End If
               End If
            Else
               .Range("F" & i).Value = .Range("D" & i).Value
            End If
        Next i
    End With
    End Sub

  26. I seguenti utenti hanno dato un "Like"


  27. #25
    L'avatar di lala10
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    N/D
    Messaggi
    68
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    16

    Re: Aiuto correzione macro

    Funziona alla perfezione!!! ti ringrazio moltissimoooo
    un'ultima cosa ...mi spiegheresti il funzionamento di OFFSET? non capisco perché c'è scritto (0,4)
    :18:

  28. #26
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1102
    Versione Office
    2010
    Likes ricevuti
    141
    Likes dati
    1

    Re: Aiuto correzione macro

    dato un range, ad es. Range("A4") Range("A4").offset(0,4) significa stessa riga (0) e 4 colonne più a destra, quindi E4

  29. I seguenti utenti hanno dato un "Like"


  30. #27
    L'avatar di lala10
    Clicca e Apri
    Data Registrazione
    Apr 2016
    Località
    N/D
    Messaggi
    68
    Versione Office
    Excel 2010
    Likes ricevuti
    0
    Likes dati
    16

    Re: Aiuto correzione macro

    Scusa il ritardo ma riesco a collegarmi solo ora. Ti scrivo un grandissimo GRAZIE perché mi hai aiutata moltissimo la macro funziona perfettamente e l'ho adattata a tutto ciò che mi serviva imparando nuovi comandi.
    Come sempre il forum non delude

Discussioni Simili

  1. [Risolto] Correzione macro salva file
    Di Vincenzo Damiani nel forum Domande su Excel VBA e MACRO
    Risposte: 3
    Ultimo Messaggio: 24/02/17, 08:24
  2. [Risolto] Correzione Macro registra pagamento
    Di Vincenzo Damiani nel forum Domande su Excel VBA e MACRO
    Risposte: 9
    Ultimo Messaggio: 11/01/17, 09:58
  3. Aiuto ottimizzazione Macro
    Di MiCaM nel forum Domande su Excel VBA e MACRO
    Risposte: 10
    Ultimo Messaggio: 04/12/16, 08:27
  4. aiuto per macro
    Di rgianluc nel forum Domande su Excel VBA e MACRO
    Risposte: 31
    Ultimo Messaggio: 31/08/16, 22:51
  5. Correzione macro per creare tabelle riassuntive
    Di Lino Albanese nel forum Domande su Excel in generale
    Risposte: 16
    Ultimo Messaggio: 01/05/16, 23:39

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •