Risultati da 1 a 9 di 9

Discussione: Somma valori dÓ listbox multiselect



  1. #1

    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    LocalitÓ
    Napoli
    EtÓ
    64
    Messaggi
    6795
    Versione Office
    2013
    Likes ricevuti
    719
    Likes dati
    164

    Somma valori dÓ listbox multiselect

    Ciao a tutti

    Avrei un quesito da porre: supponiamo di avere su un foglio una listbox (multiselect) con due colonne la prima contenente stringhe e la seconda importi.

    Che codice va scritto per sommare gli importi delle sole stringhe selezionate e mettere il totale nella cella attiva?

    Non avendo la listbox multiselect la proprietÓ Value presumo che si debba usare un ciclo per discriminare le voci selezionate e di queste prendere l'importo. ╚ quest'ultima cosa che non so fare; credo si debba utilizzare l'istruzione List ma non so come.

    Ora sono da cell e non posso allegare il file ma non credo che ve ne sia bisogno.

    Grazie

    Alfredo

  2. #2
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    LocalitÓ
    Livorno
    EtÓ
    72
    Messaggi
    1108
    Versione Office
    2010
    Likes ricevuti
    143
    Likes dati
    1

    Re: Somma valori dÓ listbox multiselect

    scusami alfredo, ma tu non sei inesperto, se non ci riesci tu che hai il file, come puoi pensare che per noi altri non ce ne sia bisogno ?

  3. #3
    L'avatar di Cuc¨^_^
    Clicca e Apri
    Data Registrazione
    Jun 2016
    LocalitÓ
    TrentoGallipoliTaranto
    EtÓ
    46
    Messaggi
    310
    Versione Office
    2010
    Likes ricevuti
    57
    Likes dati
    17

    Re: Somma valori dÓ listbox multiselect

    Codice: 
    Option Explicit
    
    Private Sub CommandButton1_Click()
    Dim Tot As Double
    Dim i As Integer
    
    
    Tot = 0
    For i = 1 To ListBox1.ListCount
        If ListBox1.Selected(i - 1) = True Then
            Tot = Tot + ListBox1.List(i - 1, 1)
        End If
    Next i
    MsgBox "Il totale selezionato Ŕ " & Tot
    
    End Sub
    File Allegati File Allegati

  4. I seguenti 2 utenti hanno dato un "Like" a Cuc¨^_^ per questo post:


  5. #4

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    LocalitÓ
    Sardegna
    EtÓ
    37
    Messaggi
    4017
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923

    Re: Somma valori dÓ listbox multiselect

    Ciao a tutti,

    acc... ci ho messo pi¨ tempo del previsto a creare il file
    inoltre non avevo capito che la listbox fosse in una userform, quindi l'ho creata direttamente sul foglio.

    Un inchino a Cuc¨ per la velocitÓ
    ma visto che ormai l'ho fatto, posto anche il mio.

    Codice: 
    Private Sub ListBox1_LostFocus()
    Dim somma As Double
    
    
    somma = 0
    With ListBox1
        For i = 0 To .ListCount - 1
            If .Selected(i) = True Then
                somma = somma + .List(i, 1)
            End If
        Next i
    End With
    
    
    ActiveCell.Value = somma
    End Sub
    La "somma" verrÓ scritta nella cella che selezioni quando "lasci" la listbox.
    File Allegati File Allegati

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno pu˛ immaginare."

  6. #5
    L'avatar di Cuc¨^_^
    Clicca e Apri
    Data Registrazione
    Jun 2016
    LocalitÓ
    TrentoGallipoliTaranto
    EtÓ
    46
    Messaggi
    310
    Versione Office
    2010
    Likes ricevuti
    57
    Likes dati
    17

    Re: Somma valori dÓ listbox multiselect

    Praticamente uguali
    PS Se posso permettermi volevo solo ricordare "Option Explicit" e quindi la dichiarazione della variabile "i"

  7. #6

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    LocalitÓ
    Sardegna
    EtÓ
    37
    Messaggi
    4017
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923

    Re: Somma valori dÓ listbox multiselect

    Citazione Originariamente Scritto da Cuc¨^_^ Visualizza Messaggio
    Praticamente uguali
    PS Se posso permettermi volevo solo ricordare "Option Explicit" e quindi la dichiarazione della variabile "i"
    Giustissimo, dopo i "richiami" di scossa, lo uso sempre

    La "i" l'ho dichiarata come pubblica, in quanto il codice completo (nel file) Ŕ questo:

    Codice: 
    Option Explicit
    Dim i As Long
    
    Private Sub ListBox1_GotFocus()
    
    With ListBox1
        .Clear
        For i = 2 To 13
            .AddItem
            .List(i - 2, 0) = Range("O" & i)
            .List(i - 2, 1) = Range("P" & i)
        Next i
        .MultiSelect = fmMultiSelectMulti
    End With
    End Sub
    
    
    Private Sub ListBox1_LostFocus()
    Dim somma As Double
    
    somma = 0
    With ListBox1
        For i = 0 To .ListCount - 1
            If .Selected(i) = True Then
                somma = somma + .List(i, 1)
            End If
        Next i
    End With
    
    ActiveCell.Value = somma
    End Sub
    Hai fatto comunque bene a ricordarlo

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno pu˛ immaginare."

  8. #7

    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    LocalitÓ
    Napoli
    EtÓ
    64
    Messaggi
    6795
    Versione Office
    2013
    Likes ricevuti
    719
    Likes dati
    164

    Re: Somma valori dÓ listbox multiselect

    Grazie a tutti per le risposte.


    @ Patel

    Non Ŕ che non volessi allegare un file ma, come detto, ero da cell e ritenevo che creare un file (che non aveva nessuna particolare caratteristica/struttura), fosse questione di un non pi¨ di un paio di minuti.

    Tengo a precisare che, oltre che per mia cultura personale, il quesito Ŕ stato posto per un utente di altro forum.

    Alfredo

    P.S. Solo un'ultima cosa: se al selezionare una cella volessi deselezionare tutti gli elementi selezionati in prcedenza della listbox come dovrei fare?

    Ho provato a modificare la routine di Tore in questo modo

    Codice: 
    Private Sub ListBox1_LostFocus()
    Dim somma As Double
    somma = 0
    With ListBox1
        For i = 0 To .ListCount - 1
            If .Selected(i) = True Then
                somma = somma + .List(i, 1)
            End If
        Next i
    End With
    ActiveCell.Value = somma
    With ListBox1
        For i = 0 To .ListCount - 1
            If .Selected(i) = True Then
                .Selected(i) = False
            End If
        Next i
    End With
    End Sub
    ma non funziona.

  9. #8

    L'avatar di cromagno
    Clicca e Apri
    Data Registrazione
    Aug 2015
    LocalitÓ
    Sardegna
    EtÓ
    37
    Messaggi
    4017
    Versione Office
    2013
    Likes ricevuti
    1225
    Likes dati
    923

    Re: Somma valori dÓ listbox multiselect

    Ciao Alfredo,
    a me funziona... non ho fatto alcuna modifica al tuo codice.

    Ti allego il file...

    ----------Post unito in automatico----------

    Comunque, potresti evitare il "doppio ciclo" :

    Codice: 
    Private Sub ListBox1_LostFocus()
    Dim somma As Double
    somma = 0
    With ListBox1
        For i = 0 To .ListCount - 1
            If .Selected(i) = True Then
                somma = somma + .List(i, 1)
                .Selected(i) = False
            End If
        Next i
    End With
    ActiveCell.Value = somma
    
    
    End Sub
    File Allegati File Allegati

    "Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno pu˛ immaginare."

  10. #9

    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    LocalitÓ
    Napoli
    EtÓ
    64
    Messaggi
    6795
    Versione Office
    2013
    Likes ricevuti
    719
    Likes dati
    164

    Re: Somma valori dÓ listbox multiselect

    Si scusami Tore funziona anche a me (e non poteva essere diversamente).

    Non so cosa ho combinato prima.

    Grazie ancora.

    Alfredo

Discussioni Simili

  1. [Risolto] somma valori per periodo
    Di ismet nel forum Domande su Excel in generale
    Risposte: 5
    Ultimo Messaggio: 03/03/17, 21:31
  2. [Risolto] Somma Valori Numerici
    Di Cirino nel forum Domande su Excel in generale
    Risposte: 4
    Ultimo Messaggio: 11/11/16, 12:10
  3. Ancora su listbox multiselect
    Di alfrimpa nel forum Domande su Excel VBA e MACRO
    Risposte: 6
    Ultimo Messaggio: 30/06/16, 12:08
  4. Risposte: 16
    Ultimo Messaggio: 18/05/16, 18:55
  5. somma valori per mese
    Di KARL184 nel forum Domande su Excel in generale
    Risposte: 6
    Ultimo Messaggio: 02/04/16, 16:20

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •