Risultati da 1 a 21 di 21

Discussione: importare 1 txt per ogni foglio in un unico file excel



  1. #1
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31

    importare 1 txt per ogni foglio in un unico file excel

    Ciao a tutti!!

    Vorrei automatizzare l’importazione di file txt (1 file per ogni foglio) ed alcune operazioni.

    Operazioni che si dovrebbero effettuare dopo l’importazione di ciascun txt:
    - nel foglio 1, nella colonna C, dalla cella C6 e fino alla fine della colonna sostituire la virgola con il punto;
    - nel foglio 1, nella cella H3 eseguire la media di tutta la colonna C
    - nel foglio1, in colonna D, cella D6 inserire la differenza “C6-$H$3 e così via per tutta la colonna”
    - nel foglio1, crea un grafico dei valori della colonna D.

    e poi si procede uguale per importare un altro txt nel foglio 2.

    Sto procedendo manualmente importando ogni txt ed effettuando le operazioni su indicate…è abbastanza semplice… ma dovendo importare oltre 100 file txt speravo in qualcosa di più veloce.

    Potete darmi qualche suggerimento/aiuto?

    Grazie mille!!!

    in allegato ho inserito esempio di txt e di come lo vorrei importare in excel.

    il file txt è del tipo:
    dati
    R.M.
    citta
    LIVELLO (m)
    DATA;ORA;VALORE
    20100401;00:00;-0,27
    20100401;01:00;-0,22
    20100401;02:00;-0,19
    20100401;03:00;-0,19
    20100401;04:00;-0,20
    20100401;05:00;-0,21
    20100401;06:00;-0,26
    20100401;07:00;-0,31
    20100401;08:00;-0,34
    ecc.....
    File Allegati File Allegati

  2. #2
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1108
    Versione Office
    2010
    Likes ricevuti
    143
    Likes dati
    1

    Re: importare 1 txt per ogni foglio in un unico file excel

    quindi vuoi importare tutti i txt di una cartella, uno per foglio

    ----------Post unito in automatico----------

    se è così prova questa macro
    Codice: 
    Sub importafolder()
      Set wb = ThisWorkbook
      CSVfolder = "F:\Download\dise\" ' <<<<<<<<<<< da modificare
      Application.ScreenUpdating = False
      If Right(CSVfolder, 1) <> "\" Then CSVfolder = CSVfolder & "\"
      CSVfile = Dir(CSVfolder & "*.txt")
      While CSVfile <> ""
        Workbooks.OpenText Filename:=CSVfolder & CSVfile, DataType:=xlDelimited, semicolon:=True
        Set wbNew = ActiveWorkbook
        Sheets(1).Copy After:=wb.Sheets(Sheets.Count)
        wbNew.Close False
        CSVfile = Dir()
      Wend
      Set wbNew = Nothing
      Set wb = Nothing
      Application.ScreenUpdating = True
    End Sub

  3. #3
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31

    Re: importare 1 txt per ogni foglio in un unico file excel

    ciao patel,
    grazie ma sembra non funzionare..

  4. #4
    L'avatar di ggratis
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Lecce - Pisa
    Età
    45
    Messaggi
    737
    Versione Office
    Excel 2010
    Likes ricevuti
    257
    Likes dati
    215

    Re: importare 1 txt per ogni foglio in un unico file excel

    Citazione Originariamente Scritto da Loretta Visualizza Messaggio
    ciao patel,
    grazie ma sembra non funzionare..
    ...probabilmente hai di default l'istruzione "option explicit" che ti impone di definire tutte le variabili

    ho integrato la macro di @patel (che saluto), ti manca di inserire il grafico, ma dovresti precisare meglio i valori che vorresti in ascissa e ordinata, perché a mio avviso non sono molto chiari

    saluti
    GG

    Codice: 
    Option Explicit
    
    
    Sub importafolder()
    Dim Wb As Workbook, WbNew As Workbook, CSVfolder As String, CSVfile As String
    Dim nRiga As Long, Intervallo As String
    
    
      Set Wb = ThisWorkbook
      CSVfolder = ThisWorkbook.Path '"F:\Download\dise\" ' <<<<<<<<<<< da modificare
      Application.ScreenUpdating = False
      If Right(CSVfolder, 1) <> "\" Then CSVfolder = CSVfolder & "\"
      CSVfile = Dir(CSVfolder & "*.txt")
      While CSVfile <> ""
        Workbooks.OpenText Filename:=CSVfolder & CSVfile, DataType:=xlDelimited, semicolon:=True
        Set WbNew = ActiveWorkbook
        Sheets(1).Copy After:=Wb.Sheets(Sheets.Count)
    
        nRiga = Range("C" & Rows.Count).End(xlUp).Row
        Range("G4").Value = "media="
        Intervallo = Range("C6:C" & nRiga).AddressLocal
        Range("H4").Formula = "=average(" & Intervallo & ")"
        Range("D6").Formula = "=C6-$H$4"
        Range("D6").AutoFill Destination:=Range("D6:D" & nRiga)
    
        WbNew.Close False
        CSVfile = Dir()
      Wend
    
      Set WbNew = Nothing
      Set Wb = Nothing
      Application.ScreenUpdating = True
    End Sub

  5. #5
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31

    Re: importare 1 txt per ogni foglio in un unico file excel

    grazie GG, ora funziona e ho importato tutti i vari txt..
    però non vengono effettuate le altre operazioni che invece leggo essere scritte nel codice...ho solo l'importazione del file testo..

    il grafico ha come ascisse il numero di riga e come ordinate i valori da D6 in poi
    (D6=C6-$H$3 e H3=media da C6 fino a fine colonna)

  6. #6
    L'avatar di ggratis
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Lecce - Pisa
    Età
    45
    Messaggi
    737
    Versione Office
    Excel 2010
    Likes ricevuti
    257
    Likes dati
    215

    Re: importare 1 txt per ogni foglio in un unico file excel

    Citazione Originariamente Scritto da Loretta Visualizza Messaggio
    grazie GG, ora funziona e ho importato tutti i vari txt..
    però non vengono effettuate le altre operazioni che invece leggo essere scritte nel codice...ho solo l'importazione del file testo..

    il grafico ha come ascisse il numero di riga e come ordinate i valori da D6 in poi
    (D6=C6-$H$3 e H3=media da C6 fino a fine colonna)

    ...ho integrato il codice con l'inserimento del grafico!
    il codice può essere scritto decisamente meglio, ma dovrebbe funzionare.

    allega il file con le tue prove...

    saluti
    GG

    Codice: 
    Option Explicit
    
    
    Sub importafolder()
    Dim Wb As Workbook, WbNew As Workbook, CSVfolder As String, CSVfile As String
    Dim nRiga As Long, Intervallo As String
    
    
      Set Wb = ThisWorkbook
      CSVfolder = ThisWorkbook.Path '"F:\Download\dise\" ' <<<<<<<<<<< da modificare
      Application.ScreenUpdating = False
      If Right(CSVfolder, 1) <> "\" Then CSVfolder = CSVfolder & "\"
      CSVfile = Dir(CSVfolder & "*.txt")
      While CSVfile <> ""
        Workbooks.OpenText Filename:=CSVfolder & CSVfile, DataType:=xlDelimited, semicolon:=True
        Set WbNew = ActiveWorkbook
        Sheets(1).Copy After:=Wb.Sheets(Sheets.Count)
        
        nRiga = Range("C" & Rows.Count).End(xlUp).Row
        Range("G4").Value = "media="
        Intervallo = Range("C6:C" & nRiga).AddressLocal
        Range("H4").Formula = "=average(" & Intervallo & ")"
        Range("D6").Formula = "=C6-$H$4"
        Range("D6").AutoFill Destination:=Range("D6:D" & nRiga)
          
        ActiveSheet.Shapes.AddChart2(227, xlLine).Select
        ActiveChart.SetSourceData Source:=Range(Intervallo).Offset(0, 1)
        ActiveChart.Parent.Cut
        Range("G6").Select
        ActiveSheet.Paste
    
    
        
        WbNew.Close False
        CSVfile = Dir()
      Wend
    
    
      
      Set WbNew = Nothing
      Set Wb = Nothing
      Application.ScreenUpdating = True
    End Sub

  7. #7
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31

    Re: importare 1 txt per ogni foglio in un unico file excel

    buongiorno, ho provato ad eseguire il codice ma compare "Errore nel metodo Select per la classe Range"..

    ho allegato il file excel
    un esempio di file txt l'ho allegato all'inizio.

    grazie
    File Allegati File Allegati

  8. #8
    L'avatar di ggratis
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Lecce - Pisa
    Età
    45
    Messaggi
    737
    Versione Office
    Excel 2010
    Likes ricevuti
    257
    Likes dati
    215

    Re: importare 1 txt per ogni foglio in un unico file excel

    Citazione Originariamente Scritto da Loretta Visualizza Messaggio
    buongiorno, ho provato ad eseguire il codice ma compare "Errore nel metodo Select per la classe Range"..

    ho allegato il file excel
    un esempio di file txt l'ho allegato all'inizio.

    grazie
    Domanda: ma il codice vba come lo hai eseguito se non è allegato al file? Il codice vba va inserito in un modulo standard e, una volta fatto, il file va salvato come *.xlsm
    ...prova con il file in allegato elimina pure i due fogli di prova che ho lasciato.

    saluti
    GG

    PS: Per come è scritta la macro i file txt devono stare nella stessa cartella del file excel.
    File Allegati File Allegati

  9. #9
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31

    Re: importare 1 txt per ogni foglio in un unico file excel

    ora funziona !!!
    unica cosa: è possibile inserire nel codice la sostituzione della virgola con il punto per le celle da C6 fino a fine colonna ??
    in quanto nel mio excel uso il punto come separatore.
    se non è possibile non fa niente, faccio manualmente la sostituzione
    grazie mille

    saluti
    loretta

  10. #10
    L'avatar di ggratis
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Lecce - Pisa
    Età
    45
    Messaggi
    737
    Versione Office
    Excel 2010
    Likes ricevuti
    257
    Likes dati
    215

    Re: importare 1 txt per ogni foglio in un unico file excel

    Ora ti posso solo rispondere al volo, se poi non lo fa nessun altro ti risponderò con calma.
    Per la sostituzione delle virgole con i punti prova a registrare una macro ed eventualmente ad integrare il codice in quella che ti abbiamo dato.

    Saluti
    GG

    Inviato dal mio GT-I9105P utilizzando Tapatalk

  11. I seguenti utenti hanno dato un "Like"


  12. #11
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1108
    Versione Office
    2010
    Likes ricevuti
    143
    Likes dati
    1

    Re: importare 1 txt per ogni foglio in un unico file excel

    Codice: 
    Sub importafolder()
    Dim Wb As Workbook, WbNew As Workbook, CSVfolder As String, CSVfile As String
    Dim nRiga As Long, Intervallo As String
    
      Set Wb = ThisWorkbook
      CSVfolder = ThisWorkbook.Path '"F:\Download\dise\" ' <<<<<<<<<<< da modificare
      Application.ScreenUpdating = False
      If Right(CSVfolder, 1) <> "\" Then CSVfolder = CSVfolder & "\"
      CSVfile = Dir(CSVfolder & "*.txt")
      While CSVfile <> ""
        Workbooks.OpenText Filename:=CSVfolder & CSVfile, DataType:=xlDelimited, semicolon:=True
        Set WbNew = ActiveWorkbook
        Sheets(1).Copy After:=Wb.Sheets(Sheets.Count)
        nRiga = Range("C" & Rows.Count).End(xlUp).Row
        Range("C6:C" & nRiga).Replace What:=",", Replacement:=".", LookAt:=xlPart, _
            SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
            ReplaceFormat:=False
        
        Range("G4").Value = "media="
        Intervallo = Range("C6:C" & nRiga).AddressLocal
        Range("H4").Formula = "=average(" & Intervallo & ")"
        Range("D6").Formula = "=C6-$H$4"
        Range("D6").AutoFill Destination:=Range("D6:D" & nRiga)
          
        ActiveSheet.Shapes.AddChart2(227, xlLine).Select
        ActiveChart.SetSourceData Source:=Range(Intervallo).Offset(0, 1)
        ActiveChart.Parent.Cut
        Range("G6").Select
        ActiveSheet.Paste
    
        
        WbNew.Close False
        CSVfile = Dir()
      Wend
    
      
      Set WbNew = Nothing
      Set Wb = Nothing
      Application.ScreenUpdating = True
    End Sub

  13. I seguenti utenti hanno dato un "Like"


  14. #12
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31

    Re: importare 1 txt per ogni foglio in un unico file excel

    ciao patel,
    ho provato il codice e funziona...compare un messaggio di errore alla fine...ma ho controllato e importa tutti i file testo unica cosa è che ogni tanto non fa un grafico..
    ma va benissimo così.

    grazie mille

    saluti
    loretta

  15. #13
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31

    Re: importare 1 txt per ogni foglio in un unico file excel

    sto usando il codice per importare vari file txt...ma spesso compare il messaggio:

    "Errore di runtime '1004'
    Errore nel metodo Paste per la classe Worksheet"

    e poi smette di importare i file...

  16. #14
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1108
    Versione Office
    2010
    Likes ricevuti
    143
    Likes dati
    1

    Re: importare 1 txt per ogni foglio in un unico file excel

    Codice: 
    Sub importafolder()
    Dim Wb As Workbook, WbNew As Workbook, CSVfolder As String, CSVfile As String
    Dim nRiga As Long, Intervallo As String
    
      Set Wb = ThisWorkbook
      CSVfolder = ThisWorkbook.Path '"F:\Download\dise\" ' <<<<<<<<<<< da modificare
      Application.ScreenUpdating = False
      If Right(CSVfolder, 1) <> "\" Then CSVfolder = CSVfolder & "\"
      CSVfile = Dir(CSVfolder & "*.txt")
      While CSVfile <> ""
        Workbooks.OpenText Filename:=CSVfolder & CSVfile, DataType:=xlDelimited, semicolon:=True
        Set WbNew = ActiveWorkbook
        Sheets(1).Copy After:=Wb.Sheets(Sheets.Count)
        nRiga = Range("C" & Rows.Count).End(xlUp).Row
        Range("C6:C" & nRiga).Replace What:=",", Replacement:=".", LookAt:=xlPart, _
            SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
            ReplaceFormat:=False
        
        Range("G4").Value = "media="
        Intervallo = Range("C6:C" & nRiga).AddressLocal
        Range("H4").Formula = "=average(" & Intervallo & ")"
        Range("D6").Formula = "=C6-$H$4"
        Range("D6").AutoFill Destination:=Range("D6:D" & nRiga)
          
        ActiveSheet.Shapes.AddChart2(227, xlLine).Select
        ActiveChart.SetSourceData Source:=Range(Intervallo).Offset(0, 1)
        ActiveChart.Parent.Cut
        Range("G6").Select
        ActiveSheet.Paste
        Application.CutCopyMode = False
        
        WbNew.Close False
        CSVfile = Dir()
      Wend
    
      
      Set WbNew = Nothing
      Set Wb = Nothing
      Application.ScreenUpdating = True
    End Sub

  17. I seguenti utenti hanno dato un "Like"


  18. #15
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31

    Re: importare 1 txt per ogni foglio in un unico file excel

    continua a comparire sempre lo stesso messaggio di errore..
    File Allegati File Allegati

  19. #16
    L'avatar di tanimon
    Clicca e Apri
    Data Registrazione
    Oct 2015
    Località
    _
    Messaggi
    258
    Versione Office
    Excel 2007
    Likes ricevuti
    36
    Likes dati
    4

    Re: importare 1 txt per ogni foglio in un unico file excel

    ciao
    prova a sostituire la riga con

    Codice: 
    ActiveSheet.Paste

    con questa

    Codice: 
    ActiveSheet.PasteSpecial
    alla riga prima del
    Codice: 
    Application.CutCopyMode = False
    che ti h indicato Patel (ciao )

    ciao
    Frank
    Excel 2007 win7 - Ogni Progetto è composto da Micro Progetti: PRIMA risolvi quelli, e PRIMA raggiungi il completamento del Progetto!
    Domanda: "Come avranno fatto gli utilizzatori di Excel VBA, quando non esisteva il registratore di macro?"

  20. I seguenti utenti hanno dato un "Like"


  21. #17
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1108
    Versione Office
    2010
    Likes ricevuti
    143
    Likes dati
    1

    Re: importare 1 txt per ogni foglio in un unico file excel

    se non risolvi prova rallentare l'esecuzione con questa modifica
    Codice: 
         
        ActiveSheet.Paste
        Application.Wait (Now + TimeValue("0:00:01"))
         Application.CutCopyMode = False
        WbNew.Close False
        CSVfile = Dir()
    in modo da rallentare l'esecuzione

  22. I seguenti utenti hanno dato un "Like"


  23. #18
    L'avatar di ggratis
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Lecce - Pisa
    Età
    45
    Messaggi
    737
    Versione Office
    Excel 2010
    Likes ricevuti
    257
    Likes dati
    215

    Re: importare 1 txt per ogni foglio in un unico file excel

    Citazione Originariamente Scritto da Loretta Visualizza Messaggio
    continua a comparire sempre lo stesso messaggio di errore..
    ...ho dato un'occhiata al file, ho visto che hai inserito il codice anche nel modulo di classe del foglio, perché?
    saluti
    GG

    ----------Post unito in automatico----------

    un saluto ai naviganti...

    @Loretta
    ho duplicato 100 volte il file *.txt che hai allegato ed ho importato i file, sia facendo eseguire l'istruzione Application.Wait (Now + TimeValue("0:00:01")) sia commentandola (mettendo cioé il carattere ' che nn fa eseguire l'istruzione ) in entrambi i casi la macro ha eseguito fino in fondo il suo lavoro senza errori.
    Non ho testato l'istruzione replace, ma dubito possa essere causa di errori.
    In allegato il file testato.
    di seguito il codice (con qualche ulteriore perfezionamento)

    fai sapere ...e se hai risolto un mi piace a tutti !

    saluti
    GG

    Codice: 
    
    
    Sub importafolder()
    Dim Wb As Workbook, WbNew As Workbook, CSVfolder As String, CSVfile As String
    Dim nRiga As Long, Intervallo As String
    
    
      Set Wb = ThisWorkbook
      CSVfolder = ThisWorkbook.Path '"F:\Download\dise\" ' <<<<<<<<<<< da modificare
      Application.ScreenUpdating = False
      If Right(CSVfolder, 1) <> "\" Then CSVfolder = CSVfolder & "\"
      CSVfile = Dir(CSVfolder & "*.txt")
      While CSVfile <> ""
        Workbooks.OpenText Filename:=CSVfolder & CSVfile, DataType:=xlDelimited, semicolon:=True
        Set WbNew = ActiveWorkbook
        Sheets(1).Copy After:=Wb.Sheets(Sheets.Count)
        nRiga = Range("C" & Rows.Count).End(xlUp).Row
            'testata senza l'istruzione replace
            Range("C6:C" & nRiga).Replace What:=",", Replacement:=".", LookAt:=xlPart, _
            SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
            ReplaceFormat:=False
        
    Range("G4").Value = "media="
        Intervallo = Range("C6:C" & nRiga).AddressLocal
        Range("H4").Formula = "=average(" & Intervallo & ")"
        Range("D6:D" & nRiga).Formula = "=C6-$H$4"
          
        ActiveSheet.Shapes.AddChart2(227, xlLine, Range("G6").Left, Range("G6").Top, 750, 150).Select
        With ActiveChart
            .SetSourceData Source:=Range(Intervallo).Offset(0, 1)
            .Location Where:=xlLocationAsObject, Name:=ActiveSheet.Name
        End With
        'Application.Wait (Now + TimeValue("0:00:01")) 'serve per rallentare la macro, ma anche senza questa istruzione non mi ha dato errore
        
        WbNew.Close False
        CSVfile = Dir()
      Wend
     
      Set WbNew = Nothing
      Set Wb = Nothing
      Application.ScreenUpdating = True
    End Sub
    File Allegati File Allegati

  24. I seguenti utenti hanno dato un "Like"


  25. #19
    L'avatar di Loretta
    Clicca e Apri
    Data Registrazione
    Nov 2015
    Località
    Bari
    Età
    34
    Messaggi
    90
    Versione Office
    2013
    Likes ricevuti
    0
    Likes dati
    31

    Re: importare 1 txt per ogni foglio in un unico file excel

    Ragazzi funzionaaaa!!!
    ora procede benissimo...nessun errore e mi ha importato tutti i file !!!

    mi avete fatto risparmiare ore di noiosissimo lavoro
    grazie mille a tutti!!!!

    loretta

  26. #20
    L'avatar di patel
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Livorno
    Età
    72
    Messaggi
    1108
    Versione Office
    2010
    Likes ricevuti
    143
    Likes dati
    1

    Re: importare 1 txt per ogni foglio in un unico file excel

    qual'è il miglioramento risolutivo ?

  27. #21
    L'avatar di ggratis
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Lecce - Pisa
    Età
    45
    Messaggi
    737
    Versione Office
    Excel 2010
    Likes ricevuti
    257
    Likes dati
    215

    Re: importare 1 txt per ogni foglio in un unico file excel

    @patel

    ...come te, ho pensato che il problema potesse risiedere nella velocità dell'esecuzione del codice, rispetto alla creazione del grafico.
    ...considerando questa eventuale causa, potrebbe essere che creando il grafico direttamente nella posizione voluta abbia velocizzato l'esecuzione evitando l'eventuale errore.
    Errore che, comunque, io non ho riscontrato con i precedenti codici, sebbene non li abbia testati con i 100 file...
    ...non saprei cosa altro pensare! Salvo @loretta non abbia fatto qualche altra marachella che non ci ha detto, come quella di scrivere il codice nel modulo di classe ;-).

    Saluti
    GG

    Inviato dal mio GT-I9105P utilizzando Tapatalk

Discussioni Simili

  1. unire file (cartelle) excel in un unico file
    Di Nhio82 nel forum Domande su Excel in generale
    Risposte: 13
    Ultimo Messaggio: 11/11/17, 21:12
  2. [Risolto] Importare in un foglio Excel dati da file XML
    Di skattolo nel forum Domande su Excel VBA e MACRO
    Risposte: 10
    Ultimo Messaggio: 15/03/17, 23:30
  3. [Risolto] Importare tanti file csv in un unico file excel
    Di gianluca26 nel forum Domande su Excel VBA e MACRO
    Risposte: 15
    Ultimo Messaggio: 12/11/16, 18:37
  4. [Risolto] Creare un nuovo file per ogni colonna presente in un file excel
    Di gianluca26 nel forum Domande su Excel VBA e MACRO
    Risposte: 10
    Ultimo Messaggio: 10/11/16, 18:50
  5. Stampa stessa riga di ogni foglio su unico foglio a4
    Di fefemusic nel forum Domande su Excel in generale
    Risposte: 6
    Ultimo Messaggio: 23/09/16, 19:44

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •