Risultati da 1 a 15 di 15

Discussione: cercare valore in un secondo foglio



  1. #1
    L'avatar di lucas22f
    Clicca e Apri
    Data Registrazione
    Jul 2016
    Località
    Ravenna
    Età
    27
    Messaggi
    17
    Versione Office
    2010
    Likes ricevuti
    0
    Likes dati
    3

    cercare valore in un secondo foglio

    Ciao, ho cercato in giro ma essendo alle prime armi in vba non sono riuscito a trovare quello che cerco.

    io ho un valore nella cella "A1" del "foglio1", ad esempio 'pippo'.
    devo andare a cercare la parola 'pippo' nella colonna "B" del "foglio2" e restituirmi il valore della colonna "A" del "foglio2"

    Grazie

  2. #2

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7121
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: cercare valore in un secondo foglio

    Ciao luca,
    allega un file excel come esempio di ciò che vuoi ottenere, bastano pochissimi dati.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  3. #3
    L'avatar di lucas22f
    Clicca e Apri
    Data Registrazione
    Jul 2016
    Località
    Ravenna
    Età
    27
    Messaggi
    17
    Versione Office
    2010
    Likes ricevuti
    0
    Likes dati
    3

    Re: cercare valore in un secondo foglio

    nel foglio1 devo far comparire nella seconda colonna il numero che è presente nel foglio2 in corrispondenza al nome

    grazie
    File Allegati File Allegati

  4. #4

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7121
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: cercare valore in un secondo foglio

    Visto che vuoi il vba, una soluzione è questa:

    Codice: 
    Sub trova()
        Dim sh1 As Worksheet, sh2 As Worksheet, uRiga As Long, y As Long
            Set sh1 = Worksheets("Foglio1")
            Set sh2 = Worksheets("Foglio2")
                Application.ScreenUpdating = False
                    On Error Resume Next
                    uRiga = sh2.Cells(Rows.Count, 1).End(xlUp).Row
                        For y = 1 To uRiga
                            sh1.Cells(y, 2) = Application.WorksheetFunction.Index(sh2.Range("A1" & ":A" & uRiga), _
                            Application.WorksheetFunction.Match(sh1.Cells(y, 1), sh2.Range("B1" & ":B" & uRiga), 0))
                        Next
                Application.ScreenUpdating = True
            Set sh1 = Nothing
            Set sh2 = Nothing
    End Sub
    ----------Post unito in automatico----------

    Con le formule in B1 da trascinare in basso:

    =INDICE(Foglio2!$A$1:$A$3;CONFRONTA(Foglio1!A1;Foglio2!$B$1:$B$3;0))
    File Allegati File Allegati
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  5. I seguenti utenti hanno dato un "Like"


  6. #5

    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Napoli
    Età
    64
    Messaggi
    6770
    Versione Office
    2013
    Likes ricevuti
    715
    Likes dati
    164

    Re: cercare valore in un secondo foglio

    Ciao Luca

    Prova questa function che va inserita in un modulo standard.

    Codice: 
    Function MioCerca(a as Range)
    Dim ur as long
    Dim rng as Range
    Dim cel as Range
    ur = Worksheets("Foglio2").Cells(Rows.Count, 2).End(xlUp).Row
    Set rng = Worksheets("Foglio2").Range("B1:B" & ur)
    For Each cel in rng
          If cel.Value = a.Value Then
                MioCerca = cel.Offset(cel.Row, -1).Value
          End If
    Next cel
    End Function
    In una cella del foglio1 scrivi

    Codice: 
    =MioCerca(A1)
    Alfredo

    P.s. Preciso che il codice l'ho scritto a memoria senza pc e senza Excel quindi non potendolo testare e sempre che abbia capito bene la domanda.

  7. I seguenti utenti hanno dato un "Like"


  8. #6

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7121
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: cercare valore in un secondo foglio

    Ciao Alfredo,
    secondo quanto ho capito io la tua Function da risultati differenti.

    Con l'occasione posto anche un codice alternativo a quello sopra:

    Codice: 
    Sub trova2()
    Dim x As Integer, y As Integer
        Application.ScreenUpdating = False
            uRiga = Sheets(2).Cells(Rows.Count, 1).End(xlUp).Row
            Application.Calculation = xlCalculationManual
                For x = 1 To uRiga
                For y = 1 To uRiga
                    If Sheets(1).Cells(x, 1) = Sheets(2).Cells(y, 2) Then
                        Sheets(1).Cells(x, 2) = Sheets(2).Cells(y, 1)
                    End If
                Next: Next
            Application.Calculation = xlCalculationAutomatic
        Application.ScreenUpdating = True
    End Sub
    File Allegati File Allegati
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  9. #7

    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Napoli
    Età
    64
    Messaggi
    6770
    Versione Office
    2013
    Likes ricevuti
    715
    Likes dati
    164

    Re: cercare valore in un secondo foglio

    Ciao Ges

    Da quello che ho capito io se in A1 c'è "pippo" la function dovrebbe restituire 2 che è il valore che è in colonna A del foglio2 in corrispondenza di "pippo".

    Ma può darsi che mi sia sbagliato e la function non posso testarla.

    Alfredo

  10. #8

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7121
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: cercare valore in un secondo foglio

    Citazione Originariamente Scritto da alfrimpa Visualizza Messaggio
    Ciao Ges

    Da quello che ho capito io se in A1 c'è "pippo" la function dovrebbe restituire 2 che è il valore che è in colonna A del foglio2 in corrispondenza di "pippo".

    Ma può darsi che mi sia sbagliato e la function non posso testarla.

    Alfredo
    Si, c'è un errore in questa riga (rosso)

    Codice: 
    Function MioCerca(a as Range)
    ....
                MioCerca = cel.Offset(cel.Row, -1).Value
    .....
    End Function
    Da sostituire con 0 (blu)

    Codice: 
    Function MioCerca(a as Range)
    Dim ur as long
    Dim rng as Range
    Dim cel as Range
    ur = Worksheets("Foglio2").Cells(Rows.Count, 2).End(xlUp).Row
    Set rng = Worksheets("Foglio2").Range("B1:B" & ur)
    For Each cel in rng
          If cel.Value = a.Value Then
                MioCerca = cel.Offset(0, -1).Value
          End If
    Next cel
    End Function
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  11. #9

    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Napoli
    Età
    64
    Messaggi
    6770
    Versione Office
    2013
    Likes ricevuti
    715
    Likes dati
    164

    Re: cercare valore in un secondo foglio

    Si Ges hai ragione; l'ora tarda mi ha indotto in errore e il non poter testare ha fatto il resto.

    Alfredo

  12. #10

    L'avatar di Rubik72
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Cosenza
    Età
    45
    Messaggi
    2807
    Versione Office
    Excel 2013
    Likes ricevuti
    1020
    Likes dati
    978

    Re: cercare valore in un secondo foglio

    Citazione Originariamente Scritto da ges Visualizza Messaggio
    [...]
    Con l'occasione posto anche un codice alternativo a quello sopra:

    Codice: 
    Sub trova2()
    Dim x As Integer, y As Integer
        Application.ScreenUpdating = False
            uRiga = Sheets(2).Cells(Rows.Count, 1).End(xlUp).Row
            Application.Calculation = xlCalculationManual
                For x = 1 To uRiga
                For y = 1 To uRiga
                    If Sheets(1).Cells(x, 1) = Sheets(2).Cells(y, 2) Then
                        Sheets(1).Cells(x, 2) = Sheets(2).Cells(y, 1)
                    End If
                Next: Next
            Application.Calculation = xlCalculationAutomatic
        Application.ScreenUpdating = True
    End Sub
    ci sarebbero delle modifiche da fare:
    Codice: 
    Sub trova2()
    Dim x As Integer, y As Integer
    Dim uRiga1 As Long
    Dim uRiga2 As Long
    
    
    
    Application.ScreenUpdating = False
    Application.Calculation = xlCalculationManual
    uRiga1 = Sheets(1).Cells(Rows.Count, 1).End(xlUp).Row
    uRiga2 = Sheets(2).Cells(Rows.Count, 1).End(xlUp).Row
    For x = 1 To uRiga1
        For y = 1 To uRiga2
            If Sheets(1).Cells(x, 1) = Sheets(2).Cells(y, 2) Then
                Sheets(1).Cells(x, 2) = Sheets(2).Cells(y, 1)
                Exit For ' inutile continuare il ciclo quando il valore è stato trovato
            End If
        Next
    Next
    Application.Calculation = xlCalculationAutomatic
    Application.ScreenUpdating = True
    End Sub

  13. #11

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7121
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: cercare valore in un secondo foglio

    Grazie Rubik delle precisazioni.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  14. #12

    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Napoli
    Età
    64
    Messaggi
    6770
    Versione Office
    2013
    Likes ricevuti
    715
    Likes dati
    164

    Re: cercare valore in un secondo foglio

    Enzo e Ges solo per curiosità (ho solo l'iPad e non posso verificare) ma la mia function fa quello che è stato richiesto?

    Alfredo

  15. #13

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7121
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: cercare valore in un secondo foglio

    Ciao Alfredo,
    si (con la correzione in blu che ho scritto sopra) la tua Function fa quello che è stato richiesto.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  16. #14

    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Napoli
    Età
    64
    Messaggi
    6770
    Versione Office
    2013
    Likes ricevuti
    715
    Likes dati
    164

    Re: cercare valore in un secondo foglio

    Grazie Ges e sono contento che anche "senza rete" (a parte la svista) qualcosa riesco a fare

    Alfredo

  17. #15
    L'avatar di lucas22f
    Clicca e Apri
    Data Registrazione
    Jul 2016
    Località
    Ravenna
    Età
    27
    Messaggi
    17
    Versione Office
    2010
    Likes ricevuti
    0
    Likes dati
    3

    Re: cercare valore in un secondo foglio

    grazie mille a tutti, con i vostri aiuti sono riuscito a completare la macro

Discussioni Simili

  1. Risposte: 4
    Ultimo Messaggio: 30/01/17, 16:31
  2. [Risolto] trovare posizione secondo e penultimo valore maggiore di zero
    Di Pietro733 nel forum Domande su Excel in generale
    Risposte: 8
    Ultimo Messaggio: 22/11/16, 13:52
  3. [Risolto] grafico che sceglie il range secondo il valore di una cella
    Di luca.donati nel forum Domande sui Grafici di Excel
    Risposte: 16
    Ultimo Messaggio: 12/10/16, 20:29
  4. Cercare valore per colonne
    Di robbiecs nel forum Domande su Excel in generale
    Risposte: 12
    Ultimo Messaggio: 24/07/16, 01:04
  5. Trovare nel secondo foglio dati presenti nel primo foglio
    Di antonysameli nel forum Domande su Excel in generale
    Risposte: 27
    Ultimo Messaggio: 12/02/16, 20:12

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •