Risultati da 1 a 29 di 29

Discussione: Macro cancella



  1. #1
    L'avatar di Ciro72
    Clicca e Apri
    Data Registrazione
    Aug 2016
    LocalitÓ
    Napoli
    EtÓ
    45
    Messaggi
    30
    Versione Office
    2007 student
    Likes ricevuti
    1

    Macro cancella

    Ciao a tutti,
    ho ancora bisogno di Voi.
    Nel file allegato necessito che lÓ dove la colonna quantitÓ restituisca una cella vuota, vengano cancellate le stringhe di testo delle 4 righe precedenti alla cella vuota. Ovvero le colonne "E;F;G;H". Il tutto per 15 blocchi (carichi).
    Spero di essere stato comprensibile.
    Un saluto a tutti.
    File Allegati File Allegati

  2. #2

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    LocalitÓ
    Como
    EtÓ
    53
    Messaggi
    7121
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: Macro cancella

    Ciao,
    se ho ben capito:
    Codice: 
    Sub cancella()
    Dim cl As Object
        With Sheets(1)
        uRiga = .Range("I" & Rows.Count).End(xlUp).Row
            For Each cl In Range("I6:I" & uRiga)
                If cl = "" Then
                    cl.Offset(0, -1) = ""
                    cl.Offset(0, -2) = ""
                    cl.Offset(0, -3) = ""
                    cl.Offset(0, -4) = ""
                End If
            Next
        End With
    End Sub
    File Allegati File Allegati
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se pu˛ sembrare improbabile, non pu˛ che essere quella giusta!

  3. #3
    L'avatar di Gianfranco55
    Clicca e Apri
    Data Registrazione
    Nov 2015
    LocalitÓ
    Vicenza
    EtÓ
    62
    Messaggi
    2070
    Versione Office
    2016
    Likes ricevuti
    552
    Likes dati
    117

    Re: Macro cancella

    ciao Ges
    fatta l'ho fatta

    Codice: 
    Sub Elimina_righe_vuote()
        UR = Range("I" & Rows.Count).End(xlUp).Row
        Application.ScreenUpdating = False
        For I = UR To 6 Step -1
        For C = 5 To 8
            If Cells(I, "I") = "" Then
             Cells(I, C) = ""
              End If
        Next
        Next
        Application.ScreenUpdating = True
     
    End Sub

  4. I seguenti utenti hanno dato un "Like"

    ges

  5. #4
    L'avatar di Ciro72
    Clicca e Apri
    Data Registrazione
    Aug 2016
    LocalitÓ
    Napoli
    EtÓ
    45
    Messaggi
    30
    Versione Office
    2007 student
    Likes ricevuti
    1

    Re: Macro cancella

    Grazie Ges, Grazie Gianfranco, per˛ a me servirebbe che la macro funzioni per tutto il foglio, ovvero fino al carico 15.
    Allego il file rivisto. Cancellare le stringhe di testo all'interno delle colonne:"lotto data arrivo scadenza u.m. conforme reso" qualora la cella quantitÓ risulti vuota.
    Il file allegato riporta 10 carichi, mi spiegate anche come incrementare o riformulare la macro in modo che funzioni pur ampliando il file?
    Grazie ma mi sto impegnando tanto seguendo voi..........
    File Allegati File Allegati

  6. #5

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    LocalitÓ
    Como
    EtÓ
    53
    Messaggi
    7121
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: Macro cancella

    Ciao Ciro,
    eccoti una possibile soluzione.
    Codice: 
    Sub cancella()
    Dim y As Long, i As Long
        With Sheets(1)
            Application.ScreenUpdating = False
            Application.Calculation = xlCalculationManual
            uRiga = .Cells(Rows.Count, 5).End(xlUp).Row
            uCol = .Cells(5, Columns.Count).End(xlToLeft).Column
                For y = 6 To uRiga
                    For i = 11 To uCol Step 9
                        If .Cells(y, i) = "" Then
                           .Cells(y, i - 2) = ""
                           .Cells(y, i - 3) = ""
                           .Cells(y, i - 4) = ""
                           .Cells(y, i - 5) = ""
                           .Cells(y, i - 6) = ""
                        End If
                    Next
                Next
            Application.ScreenUpdating = True
          Application.Calculation = xlCalculationAutomatic
        End With
    End Sub
    Funziona anche se ampli il file.

    Infatti, trovo l'ultima cella piena della riga 5 (uCol) e l'ultima cella piena della colonna F (uRiga)

    Poi uso un ciclo per spazzolare (controllare) tutte le celle dalla riga 6 fino all'ultima ( For y = 6 To uRiga) e un altro ciclo per spazzolare tutte le colonne dalla colonna K (in cui c'Ŕ il valore QUANTITA' CARICO) fino all'ultima piena saltandone di volta in volta 9 (For i = 11 To uCol Step 9) - Questo Ŕ possibile perchŔ nella struttura del tuo foglio il valore QUANTITA' CARICO si alterna dopo ogni 9 colonne.

    Se trova che questa colonna e la rispettiva riga sono vuote allora mi cancella le rispettive celle 2, 3, 4, 5 e 6 righe pi¨ a sinistra (E,F,G,H,I)
    File Allegati File Allegati
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se pu˛ sembrare improbabile, non pu˛ che essere quella giusta!

  7. I seguenti utenti hanno dato un "Like"


  8. #6
    L'avatar di Ciro72
    Clicca e Apri
    Data Registrazione
    Aug 2016
    LocalitÓ
    Napoli
    EtÓ
    45
    Messaggi
    30
    Versione Office
    2007 student
    Likes ricevuti
    1

    Re: Macro cancella

    Fenomenale Ges, grazie mille, siccome serviva cancellare anche la prima colonna a destra della quantitÓ ho aggiunto alla macro: .Cells(y, i - 1) = "" e funziona.
    Dai che sto cominciando ad imparare
    .
    Ti allego cmq il file con la modifica.
    Grazie e buona serata
    File Allegati File Allegati

  9. #7

    L'avatar di Rubik72
    Clicca e Apri
    Data Registrazione
    Dec 2015
    LocalitÓ
    Cosenza
    EtÓ
    45
    Messaggi
    2807
    Versione Office
    Excel 2013
    Likes ricevuti
    1020
    Likes dati
    978

    Re: Macro cancella

    routine di @ges con piccola modifica che impiega meno tempo:
    Codice: 
    Sub cancella()
    Dim y As Long, i As Long
        
        With Sheets(1)
            Application.ScreenUpdating = False
            Application.Calculation = xlCalculationManual
            uRiga = .Cells(Rows.Count, 5).End(xlUp).Row
            uCol = .Cells(5, Columns.Count).End(xlToLeft).Column
                For y = 6 To uRiga
                    For i = 11 To uCol Step 9
                        If .Cells(y, i) = "" Then
                           .Range(.Cells(y, i - 2), .Cells(y, i - 6)) = ""
                           '.Cells(y, i - 2) = ""
                           '.Cells(y, i - 3) = ""
                           '.Cells(y, i - 4) = ""
                           '.Cells(y, i - 5) = ""
                           '.Cells(y, i - 6) = ""
                        End If
                    Next
                Next
            Application.ScreenUpdating = True
          Application.Calculation = xlCalculationAutomatic
        End With
    
    
    End Sub

  10. I seguenti utenti hanno dato un "Like"

    ges

  11. #8

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    LocalitÓ
    Como
    EtÓ
    53
    Messaggi
    7121
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: Macro cancella

    Citazione Originariamente Scritto da Ciro72 Visualizza Messaggio
    Fenomenale Ges, grazie mille, siccome serviva cancellare anche la prima colonna a destra della quantitÓ ho aggiunto alla macro: .Cells(y, i - 1) = "" e funziona.
    Dai che sto cominciando ad imparare
    .
    Ti allego cmq il file con la modifica.
    Grazie e buona serata
    Ottimo Ciro,
    stai andando alla grande!
    Continua cosý.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se pu˛ sembrare improbabile, non pu˛ che essere quella giusta!

  12. #9
    L'avatar di Ciro72
    Clicca e Apri
    Data Registrazione
    Aug 2016
    LocalitÓ
    Napoli
    EtÓ
    45
    Messaggi
    30
    Versione Office
    2007 student
    Likes ricevuti
    1

    Re: Macro cancella

    Grazie anche a te Rubik.
    Ma se aggiungo una colonna all'inizio quale parametro devo modificare?
    File Allegati File Allegati

  13. #10

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    LocalitÓ
    Como
    EtÓ
    53
    Messaggi
    7121
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: Macro cancella

    Il ciclo delle colonne Ŕ:

    For i = 11 To uCol Step

    Se aggiungi una colonna prima dei 15 intervalli devi aumentare di 1 l'inizio del ciclo quindi:

    For i = 12 To uCol Step 9

    Se invece aggiungi una colonna in ciascuno dei 15 intervalli devi aumentare il salto di colonne, cosý:

    For i = 11 To uCol Step 10
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se pu˛ sembrare improbabile, non pu˛ che essere quella giusta!

  14. #11
    L'avatar di Cuc¨^_^
    Clicca e Apri
    Data Registrazione
    Jun 2016
    LocalitÓ
    TrentoGallipoliTaranto
    EtÓ
    46
    Messaggi
    309
    Versione Office
    2010
    Likes ricevuti
    57
    Likes dati
    17

    Re: Macro cancella

    Domanda perchŔ cancellare cella per cella ben 6 celle anzichŔ l'intero range???

  15. #12

    L'avatar di Rubik72
    Clicca e Apri
    Data Registrazione
    Dec 2015
    LocalitÓ
    Cosenza
    EtÓ
    45
    Messaggi
    2807
    Versione Office
    Excel 2013
    Likes ricevuti
    1020
    Likes dati
    978

    Re: Macro cancella

    Citazione Originariamente Scritto da Cuc¨^_^ Visualizza Messaggio
    Domanda perchŔ cancellare cella per cella ben 6 celle anzichŔ l'intero range???
    A chi Ŕ diretta la domanda?

    Ti ricordo che si pu˛ utilizzare il tasto "Rispondi Citando" altrimenti non si capisce a chi Ŕ diretta la domanda.

    Comunque giÓ corretto al post #7

  16. #13
    L'avatar di Cuc¨^_^
    Clicca e Apri
    Data Registrazione
    Jun 2016
    LocalitÓ
    TrentoGallipoliTaranto
    EtÓ
    46
    Messaggi
    309
    Versione Office
    2010
    Likes ricevuti
    57
    Likes dati
    17

    Re: Macro cancella

    Sorry

    non avevo notato la correzione!

    Citazione Originariamente Scritto da Rubik72 Visualizza Messaggio
    A chi Ŕ diretta la domanda?

    Ti ricordo che si pu˛ utilizzare il tasto "Rispondi Citando" altrimenti non si capisce a chi Ŕ diretta la domanda.

    Comunque giÓ corretto al post #7

  17. #14

    L'avatar di Rubik72
    Clicca e Apri
    Data Registrazione
    Dec 2015
    LocalitÓ
    Cosenza
    EtÓ
    45
    Messaggi
    2807
    Versione Office
    Excel 2013
    Likes ricevuti
    1020
    Likes dati
    978

    Re: Macro cancella

    Citazione Originariamente Scritto da Cuc¨^_^ Visualizza Messaggio
    Sorry

    non avevo notato la correzione!
    (bentornato, era da un po' che non ti sentivi)

  18. #15
    L'avatar di Ciro72
    Clicca e Apri
    Data Registrazione
    Aug 2016
    LocalitÓ
    Napoli
    EtÓ
    45
    Messaggi
    30
    Versione Office
    2007 student
    Likes ricevuti
    1

    Re: Macro cancella

    Grazie Ges, ma non mi funziona.
    Ti allego il file.
    File Allegati File Allegati

  19. #16

    L'avatar di Rubik72
    Clicca e Apri
    Data Registrazione
    Dec 2015
    LocalitÓ
    Cosenza
    EtÓ
    45
    Messaggi
    2807
    Versione Office
    Excel 2013
    Likes ricevuti
    1020
    Likes dati
    978

    Re: Macro cancella

    la variabile uRiga conteggia l'ultima riga piena della colonna E.
    Se questa Ŕ vuota (ll'ultima riga piena Ŕ 5) il ciclo
    Codice: 
    For y = 6 To uRiga
    non inizia mai.
    Fai la prova con i dati inseriti nella colonna E

    Edit: E' meglio usare la modifica del post #7

  20. #17

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    LocalitÓ
    Como
    EtÓ
    53
    Messaggi
    7121
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: Macro cancella

    Citazione Originariamente Scritto da Ciro72 Visualizza Messaggio
    Grazie Ges, ma non mi funziona.
    Ti allego il file.
    Effettivamente, come dice Rubik, che saluto, ho messo il conteggio delle colonne piene facendo riferimento alla colonna E che ora Ŕ stata svuotata.
    Bisogna trovare una colonna che Ŕ sempre piena fino all'ultima oppure assegniamo come ultima riga una fuori range che si ritiene non possa essere superata (esempio 1000)

    Codice: 
    Sub cancella()
    Dim y As Long, i As Long, uCol As Long
        With Sheets(1)
            Application.ScreenUpdating = False
            Application.Calculation = xlCalculationManual
             uCol = .Cells(5, Columns.Count).End(xlToLeft).Column
                For y = 6 To 1000
                    For i = 12 To uCol Step 9
                        If .Cells(y, i) = "" Then
                           .Range(.Cells(y, i - 1), Cells(y, i - 6)) = ""
                        End If
                    Next
                Next
            Application.ScreenUpdating = True
          Application.Calculation = xlCalculationAutomatic
        End With
    End Sub
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se pu˛ sembrare improbabile, non pu˛ che essere quella giusta!

  21. #18
    L'avatar di Ciro72
    Clicca e Apri
    Data Registrazione
    Aug 2016
    LocalitÓ
    Napoli
    EtÓ
    45
    Messaggi
    30
    Versione Office
    2007 student
    Likes ricevuti
    1

    Re: Macro cancella

    Perfetto Rubik,

    risolto e grazie tante.
    Buonanotte

  22. #19

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    LocalitÓ
    Verona Provincia
    EtÓ
    57
    Messaggi
    1011
    Versione Office
    .
    Likes ricevuti
    365
    Likes dati
    0

    Re: Macro cancella

    Ciao,

    arrivo tardi, ma propongo anche questa variante, che utilizza un solo ciclo di 5 iterazioni:

    Codice: 
    Sub cancella()
      'by scossa
      Dim nLR As Long, j As Long
      Dim rEmptyCells As Range
        
      With ThisWorkbook.Worksheets("CARICO")
        nLR = .Cells(Rows.Count, 12).End(xlUp).Row
        On Error Resume Next
        Set rEmptyCells = .Range("L6:L" & nLR).SpecialCells(xlCellTypeBlanks)
        On Error Goto 0
        If Not rEmptyCells Is Nothing Then
          Application.ScreenUpdating = False
          Application.Calculation = xlCalculationManual
          Set rEmptyCells = rEmptyCells.Offset(0, -6)
          For j = 0 To 4
            rEmptyCells.Offset(0, j).ClearContents
          Next
          Application.ScreenUpdating = True
          Application.Calculation = xlCalculationAutomatic
        End If
      End With
      Set rEmptyCells = Nothing
    End Sub
    Ultima modifica fatta da:scossa; 31/08/16 alle 23:05 Motivo: aggiunta riga On Error Goto 0
    Bye!
    scossa
    scossa's web site
    ___
    Se tu hai una mela, e io ho una mela, e ce le scambiamo, allora tu ed io abbiamo sempre una mela per uno. Ma se tu hai un'idea, ed io ho un'idea, e ce le scambiamo, allora abbiamo entrambi due idee. (George Bernard Shaw)

  23. #20

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    LocalitÓ
    Como
    EtÓ
    53
    Messaggi
    7121
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: Macro cancella

    Ciao scossa,
    tu non arrivi mai tardi .. Ŕ sempre un piacere in qualunque momento arrivi.
    Ho provato la tua sub Ŕ velocissima! Per˛, non so se ho male interpretato il tuo codice, ma Ciro non vuole cancellare solo le celle della colonna L ma di tutte i 10 range CARICO, quindi fino alla colonna CQ.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se pu˛ sembrare improbabile, non pu˛ che essere quella giusta!

  24. #21

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    LocalitÓ
    Verona Provincia
    EtÓ
    57
    Messaggi
    1011
    Versione Office
    .
    Likes ricevuti
    365
    Likes dati
    0

    Re: Macro cancella

    Citazione Originariamente Scritto da ges Visualizza Messaggio
    Per˛, non so se ho male interpretato il tuo codice, ma Ciro non vuole cancellare solo le celle della colonna L ma di tutte i 10 range CARICO, quindi fino alla colonna CQ.
    Hai ragione, mi era sfuggito (avevo letto la prima richiesta e pensavo a quella, senza prestare attenzione al resto del foglio).

    Comunque basta ripetere il codice per gli altri 9 carichi:
    Codice: 
    Sub cancella()
      Dim nLR As Long, j As Long, k As Long
      Dim rEmptyCells As Range
      
      Application.ScreenUpdating = False
      Application.Calculation = xlCalculationManual
      
      With ThisWorkbook.Worksheets("CARICO")
        For k = 12 To 93 Step 9
          nLR = .Cells(Rows.Count, k).End(xlUp).Row
          On Error Resume Next
          Set rEmptyCells = .Range(.Cells(6, k), .Cells(nLR, k)).SpecialCells(xlCellTypeBlanks)
          On Error GoTo 0
          If Not rEmptyCells Is Nothing Then
            Set rEmptyCells = rEmptyCells.Offset(0, -6)
            For j = 0 To 4
              rEmptyCells.Offset(0, j).ClearContents
            Next
          End If
        Next k
      End With
      Set rEmptyCells = Nothing
      Application.ScreenUpdating = True
      Application.Calculation = xlCalculationAutomatic
    
    
    End Sub
    Ultima modifica fatta da:scossa; 31/08/16 alle 23:35 Motivo: sistemato codice
    Bye!
    scossa
    scossa's web site
    ___
    Se tu hai una mela, e io ho una mela, e ce le scambiamo, allora tu ed io abbiamo sempre una mela per uno. Ma se tu hai un'idea, ed io ho un'idea, e ce le scambiamo, allora abbiamo entrambi due idee. (George Bernard Shaw)

  25. I seguenti 2 utenti hanno dato un "Like" a scossa per questo post:


  26. #22

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    LocalitÓ
    Como
    EtÓ
    53
    Messaggi
    7121
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: Macro cancella

    Ottimo!
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se pu˛ sembrare improbabile, non pu˛ che essere quella giusta!

  27. #23

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    LocalitÓ
    Verona Provincia
    EtÓ
    57
    Messaggi
    1011
    Versione Office
    .
    Likes ricevuti
    365
    Likes dati
    0

    Re: Macro cancella

    Una correzione necessaria (vedi riga nLR = ........)
    Codice: 
    Sub cancella()
      Dim nLR As Long, j As Long, k As Long
      Dim rEmptyCells As Range
      
      Application.ScreenUpdating = False
      Application.Calculation = xlCalculationManual
      
      With ThisWorkbook.Worksheets("CARICO")
        nLR = .Cells.SpecialCells(xlCellTypeLastCell).Row '<---- legge l'ultima riga effettiva
        For k = 12 To 93 Step 9
          On Error Resume Next
          Set rEmptyCells = .Range(.Cells(6, k), .Cells(nLR, k)).SpecialCells(xlCellTypeBlanks)
          On Error GoTo 0
          If Not rEmptyCells Is Nothing Then
            Set rEmptyCells = rEmptyCells.Offset(0, -6)
            For j = 0 To 4
              rEmptyCells.Offset(0, j).ClearContents
            Next
          End If
        Next k
      End With
      Set rEmptyCells = Nothing
      Application.ScreenUpdating = True
      Application.Calculation = xlCalculationAutomatic
    End Sub
    Bye!
    scossa
    scossa's web site
    ___
    Se tu hai una mela, e io ho una mela, e ce le scambiamo, allora tu ed io abbiamo sempre una mela per uno. Ma se tu hai un'idea, ed io ho un'idea, e ce le scambiamo, allora abbiamo entrambi due idee. (George Bernard Shaw)

  28. I seguenti utenti hanno dato un "Like"


  29. #24
    L'avatar di Ciro72
    Clicca e Apri
    Data Registrazione
    Aug 2016
    LocalitÓ
    Napoli
    EtÓ
    45
    Messaggi
    30
    Versione Office
    2007 student
    Likes ricevuti
    1

    Re: Macro cancella

    Grazie Scossa, ma sul foglio che allego non riesco a farla funzionare......
    Dovrei cancellare anche le colonne "RESO"...

    Grazie
    File Allegati File Allegati

  30. #25
    L'avatar di Ciro72
    Clicca e Apri
    Data Registrazione
    Aug 2016
    LocalitÓ
    Napoli
    EtÓ
    45
    Messaggi
    30
    Versione Office
    2007 student
    Likes ricevuti
    1

    Re: Macro cancella

    Scusami Scossa, ho risolto, bisognava variare l'intervallo delle colonne....
    Ma la macro non mi cancella la prima riga a destra (reso) della colonna " QuantitÓ". Per tutti gli intervalli.
    Potete aiutarmi?

    Grazie
    File Allegati File Allegati

  31. #26

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    LocalitÓ
    Verona Provincia
    EtÓ
    57
    Messaggi
    1011
    Versione Office
    .
    Likes ricevuti
    365
    Likes dati
    0

    Re: Macro cancella

    Citazione Originariamente Scritto da Ciro72 Visualizza Messaggio
    Ma la macro non mi cancella la prima riga a destra (reso) della colonna " QuantitÓ". Per tutti gli intervalli.
    correggi in: 0 To 4 in 0 to 5
    Codice: 
            For j = 0 To 5
              rEmptyCells.Offset(0, j).ClearContents
            Next
    Bye!
    scossa
    scossa's web site
    ___
    Se tu hai una mela, e io ho una mela, e ce le scambiamo, allora tu ed io abbiamo sempre una mela per uno. Ma se tu hai un'idea, ed io ho un'idea, e ce le scambiamo, allora abbiamo entrambi due idee. (George Bernard Shaw)

  32. #27
    L'avatar di Ciro72
    Clicca e Apri
    Data Registrazione
    Aug 2016
    LocalitÓ
    Napoli
    EtÓ
    45
    Messaggi
    30
    Versione Office
    2007 student
    Likes ricevuti
    1

    Re: Macro cancella

    Grazie scossa risolto, siete tutti gentilissimi.
    Ottimo sito, Ottima gente.

    Buona giornata.

  33. #28
    L'avatar di ggratis
    Clicca e Apri
    Data Registrazione
    Sep 2015
    LocalitÓ
    Lecce - Pisa
    EtÓ
    45
    Messaggi
    737
    Versione Office
    Excel 2010
    Likes ricevuti
    257
    Likes dati
    215

    Re: Macro cancella

    giusto per partecipare...
    Codice: 
    Sub CercaCancella_EFGHIJ()
    Dim C As Range
    Dim nRighe As Long
    Dim firstAddress As String
    Application.ScreenUpdating = False
    Application.Calculation = xlCalculationManual
    Application.EnableEvents = False
        With ThisWorkbook.ActiveSheet.Rows("5:5")
        nRighe = .CurrentRegion.Rows.Count
                Set C = .Find("QUANTITA' CARICO", LookIn:=xlValues)
                If Not C Is Nothing Then
                    firstAddress = C.Address
                    Do
                        .AutoFilter Field:=C.Column, Criteria1:=""
                        With C
                            Range(.Offset(1, -6), .Offset(nRighe, -1)).SpecialCells(xlCellTypeVisible).ClearContents
                        End With
                        .AutoFilter
                        Set C = .FindNext(C)
                    Loop While Not C Is Nothing And C.Address <> firstAddress
                End If
        Range("B5").Select
        End With
    Application.Calculation = xlCalculationAutomatic
    Application.EnableEvents = True
    Application.ScreenUpdating = True
    End Sub
    saluti
    gg

  34. #29
    L'avatar di Ciro72
    Clicca e Apri
    Data Registrazione
    Aug 2016
    LocalitÓ
    Napoli
    EtÓ
    45
    Messaggi
    30
    Versione Office
    2007 student
    Likes ricevuti
    1

    Re: Macro cancella

    grazie Gg,

    buona serata.

Discussioni Simili

  1. [Risolto] Pulsante macro "cancella" che imposti il men¨ a tendina (convalida) a un valore default
    Di vittorio99 nel forum Domande su Excel VBA e MACRO
    Risposte: 8
    Ultimo Messaggio: 31/01/17, 17:04
  2. Macro cancella
    Di Ciro72 nel forum Domande su Excel VBA e MACRO
    Risposte: 14
    Ultimo Messaggio: 30/08/16, 16:21
  3. Cancella celle con una Macro
    Di Giovanni Sauk nel forum Domande su Excel in generale
    Risposte: 5
    Ultimo Messaggio: 07/04/16, 10:26
  4. Pulsante Macro Cancella ed esportazione in XML
    Di James nel forum Domande su Excel VBA e MACRO
    Risposte: 8
    Ultimo Messaggio: 03/03/16, 11:08
  5. cancella riga
    Di avenuti nel forum Domande su Excel in generale
    Risposte: 2
    Ultimo Messaggio: 20/12/15, 06:30

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •