Risultati da 1 a 14 di 14

Discussione: Come popolare i campi di TextBox in base a una ListBox



  1. #1

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7122
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Come popolare i campi di TextBox in base a una ListBox

    Ciao a tutti,
    sto trovando qualche problema a fare questa cosa che vi spiego di seguito.

    Ho un elenco di dati (nome, cognome, tel. CF, ecc) nel Foglio1

    Mi sono creato una UserForm con una ListBox che si popola in base a una ricerca inserita in una TexBox effettuata con l'operatore Like. In pratica basta cercare anche una sola lettera e la ListBox si popola con tutti i nomi in cui è presente quella lettera (esempio, cerco "ros" e mi viene fuori "Rossi Mario, Grigi Rossana, Rossi Marco")

    Volevo però trovare un modo che se seleziono un nome nella ListBox mi si riempiono le TextBox con i dati corrispondenti.

    Esempio se nella ricerca che ho citato sopra clicco su Rossi Mario le TextBox si riempiono con i dati di Rossi Mario (tel, CF, Nr. Via, ecc)

    Normalmente per pololare la ListBox con i nomi del foglio presenti nella ListBox si usa di solito questo metodo
    Codice: 
    Private Sub ListBox1_Change()
        TextBox1.Value = Cells(ListBox1.ListIndex + 2, 1)
    End Sub
    Ma qui non può funzionare perchè il foglio non è filtrato ma contiene tutti i nomi e quini non va bene.

    Pertanto, la domanda è:

    C'è un sistema che utilizzando l'operatore Like posso popolare le TextBox con i nomi selezionati? Oppure devo per forza usare un filtro ".AutoFilter Field:=5, Criteria1:= criterio"

    Oppure attendo altri suggerimenti.

    Questo è il codice che ho usato:
    Codice: 
    Private Sub CommandButton1_Click()
        Dim wks1 As Worksheet, CL As Object
        Set wks1 = Worksheets("Foglio1")
        uRiga = wks1.Range("D" & Rows.Count).End(xlUp).Row
        ListBox1.Clear
            For Each CL In wks1.Range("D1:D" & uRiga)
                If UCase(CL.Value) Like UCase("*" & TextBox9 & "*") Then
                    ListBox1.AddItem CL.Value
                End If
            Next
        Set wks1 = Nothing
    End Sub
    Allego il file
    File Allegati File Allegati
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  2. I seguenti utenti hanno dato un "Like"


  3. #2
    L'avatar di Marius44
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Catania
    Età
    73
    Messaggi
    3208
    Versione Office
    Excel2010
    Likes ricevuti
    625
    Likes dati
    155

    Re: Come popolare i campi di TextBox in base a una ListBox

    Ciao ges
    due modestissimi suggerimenti:
    1°) la TextBox10 non scrive i dati man mano che inserisci. Metti questa macro (che è la tua associata al pulsante Cerca)
    Codice: 
    Private Sub TextBox9_Change()
        Dim wks1 As Worksheet, CL As Object
        Set wks1 = Worksheets("Foglio1")
        uriga = wks1.Range("D" & Rows.Count).End(xlUp).Row
        ListBox1.Clear
            For Each CL In wks1.Range("D1:D" & uriga)
                If UCase(CL.Value) Like UCase("*" & TextBox9 & "*") Then
                    ListBox1.AddItem CL.Value
                End If
            Next
        Set wks1 = Nothing
    End Sub
    Poi aggiungi questo codice (che non mancherà a te di migliorare):
    Codice: 
    Private Sub ListBox1_Click()
        uriga = Cells(Rows.Count, 1).End(xlUp).Row
        rg = Application.WorksheetFunction.Match(ListBox1.Text, Range("D1:D" & uriga), 0) 'individua la riga
        TextBox10 = Range("D" & rg)
        TextBox2 = Range("A" & rg)
        TextBox3 = Range("B" & rg)
        TextBox4 = Range("C" & rg)
        TextBox5 = Range("E" & rg)
        TextBox6 = Range("F" & rg)
        TextBox7 = Range("G" & rg)
        TextBox8 = Range("H" & rg)
    End Sub
    Fai sapere se è quello che volevi.
    Ciao,
    Mario

  4. I seguenti 4 utenti hanno dato un "Like" a Marius44 per questo post:


  5. #3

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7122
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: Come popolare i campi di TextBox in base a una ListBox

    Ciao Mario,
    ottimo intuito di usare la funzione CONFRONTA come non averci pensato? Pensa che nelle formule insieme a INDICE è la mia più usata!

    Per la sub "Private Sub TextBox9_Change" posso non metterla altrimenti a che serve il pulsante cerca? Oppure la metto cambio il pulsante Cerca in Cancella la Texbox9 per una nuova ricerca.... vedo di pensarci ... comunque era quello che volevo, grazie.

    Se qualcuno ha altri suggerimenti, sempre ben accetti.

    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  6. #4

    L'avatar di Rubik72
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Cosenza
    Età
    45
    Messaggi
    2807
    Versione Office
    Excel 2013
    Likes ricevuti
    1020
    Likes dati
    978

    Re: Come popolare i campi di TextBox in base a una ListBox

    Un'alternativa al codice di Mario (che saluto)
    Codice: 
    Option Compare Text
    
    
    Private Sub CommandButton1_Click()
        Dim wks1 As Worksheet, CL As Object
        Set wks1 = Worksheets("Foglio1")
        uRiga = wks1.Range("D" & Rows.Count).End(xlUp).Row
        
        ListBox1.Clear
            For Each CL In wks1.Range("D1:D" & uRiga)
                If InStr(1, CL, TextBox9) > 0 Then
                    With ListBox1
                        .AddItem
                        .List(i, 0) = CL.Value
                        .List(i, 1) = CL.Offset(0, -3)
                        .List(i, 2) = CL.Offset(0, -2)
                        .List(i, 3) = CL.Offset(0, -1)
                        .List(i, 4) = CL.Offset(0, 1)
                        .List(i, 5) = CL.Offset(0, 2)
                        .List(i, 6) = CL.Offset(0, 3)
                        .List(i, 7) = CL.Offset(0, 4)
                        i = i + 1
                    End With
                End If
            Next
        Set wks1 = Nothing
    End Sub
    
    
    Private Sub CommandButton3_Click()
        Unload Me
    End Sub
    
    
    Private Sub UserForm_Initialize()
    ListBox1.ColumnCount = 8
    ListBox1.ColumnWidths = "200;0;0;0;0;0;0;0"
    End Sub
    
    
    Private Sub ListBox1_Click()
        
        With ListBox1
            TextBox10 = .List(.ListIndex, 0)
            TextBox2 = .List(.ListIndex, 1)
            TextBox3 = .List(.ListIndex, 2)
            TextBox4 = .List(.ListIndex, 3)
            TextBox5 = .List(.ListIndex, 4)
            TextBox6 = .List(.ListIndex, 5)
            TextBox7 = .List(.ListIndex, 6)
            TextBox8 = .List(.ListIndex, 7)
        End With
    End Sub

  7. I seguenti 2 utenti hanno dato un "Like" a Rubik72 per questo post:


  8. #5
    L'avatar di dracoscrigno
    Clicca e Apri
    Data Registrazione
    May 2016
    Località
    ferrara
    Età
    41
    Messaggi
    2074
    Versione Office
    office pro 2010
    Likes ricevuti
    440
    Likes dati
    241

    Re: Come popolare i campi di TextBox in base a una ListBox

    Mi sono sbizzarrito anche io


    P.s. Ho utilizzato Find ed è solo abbozzato... Non mi ricordo ma credo che vada aggiunto qualcosa per far si che non abbia qualche rimasuglio delle ricerche passate...

    Codice: 
    Option Explicit
    
    
    'Variabile globale per contenere il range di celle di cui si occupa questo form
    Private ColonnaInEsame As Range
    
    
    
    
    'INIZIALIZZAZIONE
    Private Sub UserForm_Initialize()
        With Foglio1
            Set ColonnaInEsame = .Range(.Range("D2").Address, .Range("D1").End(xlDown).Address)
        End With
        With Me.SpinButton1
            .Min = -1
            .Max = ColonnaInEsame.Rows.Cells.Count
            .SmallChange = -1
        End With
        
        PopolaListbox
        PopolaDettagli 0
    End Sub
    
    
    
    
    'SPINBUTTON della listbox
    Private Sub SpinButton1_Change()
        With SpinButton1
            If .Value > ListBox1.ListCount - 1 Then
                .Value = 0
            ElseIf .Value < 0 Then
                .Value = ListBox1.ListCount - 1
            End If
                ListBox1.Selected(.Value) = True
                PopolaDettagli .Value
        End With
    End Sub
    
    
    'LISTBOX
    
    
    Private Sub ListBox1_Click()
        Me.SpinButton1.Value = ListBox1.ListIndex
    End Sub
    
    
    Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
        ListBox1_Click
        CmdIns_Mod_Click
    End Sub
    
    
    'Casella di RICERCA
    
    
    Private Sub TextBox9_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
        PopolaListbox (TextBox9.Text)
    End Sub
    
    
    'Pulsante CHIUSURA
    Private Sub CmdCHIUDI_Click()
        If MsgBox("DAvvero vuoi chiudere?", vbYesNo) = vbYes Then
            Unload Me
        End If
    End Sub
    
    
    'INSERIMENTO E MODIFICA
    Private Sub CmdIns_Mod_Click()
        MsgBox "Vai alla modifica..."
    End Sub
    
    
    
    
    ' Popolamento della listbox
    Private Sub PopolaListbox(Optional ByVal Testo As String)
        ListBox1.Clear
        Dim Cella As Range
        For Each Cella In ColonnaInEsame.Cells
            If UCase(Cella.Value) Like UCase("*" & Trim(Testo) & "*") Then
                ListBox1.AddItem Cella.Value
            End If
        Next
        With ListBox1
            If .ListCount > 0 Then
                .Selected(0) = True
            End If
        End With
    End Sub
    'popolamento dei dettagli
    Private Sub PopolaDettagli(ByVal IndexDellaLista As Long)
        Dim CellaBuona As Range
        Set CellaBuona = ColonnaInEsame.Find(ListBox1.List(IndexDellaLista))
        With Me
            .TextAnno = CellaBuona.Offset(0, -3).Value
            .TextN1 = CellaBuona.Offset(0, -2).Value
            .TextN2 = CellaBuona.Offset(0, -1).Value
            .textNomeCognome = CellaBuona.Value
            .TextRes = CellaBuona.Offset(0, 1).Value
            .TextCF = CellaBuona.Offset(0, 2).Value
            .TextTel = CellaBuona.Offset(0, 3).Value
            .TextNote = CellaBuona.Offset(0, 4).Value
        End With
    End Sub
    File Allegati File Allegati

  9. I seguenti 2 utenti hanno dato un "Like" a dracoscrigno per questo post:


  10. #6

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7122
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: Come popolare i campi di TextBox in base a una ListBox

    Ciao Enzo,
    questa è veramente una grande intuizione
    Codice: 
    ...
    If InStr(1, CL, TextBox9) > 0 Then
    ..
    ma questa però me la dovresti spiegare
    Codice: 
    Private Sub UserForm_Initialize()
    ListBox1.ColumnCount = 8
    ListBox1.ColumnWidths = "200;0;0;0;0;0;0;0"
    End Sub
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  11. #7

    L'avatar di Rubik72
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Cosenza
    Età
    45
    Messaggi
    2807
    Versione Office
    Excel 2013
    Likes ricevuti
    1020
    Likes dati
    978

    Re: Come popolare i campi di TextBox in base a una ListBox

    Creo una listbox multicolonna, la prima larghezza 200 (visibile) le altre colonne larghezza zero (invisibili)

    Inviato dal mio Nexus 7 utilizzando Tapatalk

  12. #8

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7122
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: Come popolare i campi di TextBox in base a una ListBox

    Citazione Originariamente Scritto da Rubik72 Visualizza Messaggio
    Creo una listbox multicolonna, la prima larghezza 200 (visibile) le altre colonne larghezza zero (invisibili)

    Inviato dal mio Nexus 7 utilizzando Tapatalk
    Grazie
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  13. #9

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7122
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: Come popolare i campi di TextBox in base a una ListBox

    Citazione Originariamente Scritto da dracoscrigno Visualizza Messaggio
    Mi sono sbizzarrito anche io
    Grazie anche a te Dragoscrigno ... ho visto che hai previsto una serie di avvisi prima di ogni operazione ... gli indecisi entreranno in difficoltà!
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  14. #10
    L'avatar di dracoscrigno
    Clicca e Apri
    Data Registrazione
    May 2016
    Località
    ferrara
    Età
    41
    Messaggi
    2074
    Versione Office
    office pro 2010
    Likes ricevuti
    440
    Likes dati
    241

    Re: Come popolare i campi di TextBox in base a una ListBox

    Citazione Originariamente Scritto da Rubik72 Visualizza Messaggio
    ...
    Codice: 
    If InStr(1, CL, TextBox9) > 0 Then
    ...
    Anche a me piace questa cosa.
    Mi ha stuzzicato una domanda della quale, forse, conoscevo anche la risposta ma che ora non ricordo più:

    E' più veloce ciclare le celle con una struttura del genere oppure è più veloce una funzione come FIND() o ... cos' era quella proposta da... Fammi andare a vedere che non mi ricordo...
    Ecco...
    Proposta da Marius:
    Application.WorksheetFunction.Match()

    si. la domanda è: Quale è la strada migliore? quali i pregi e i difetti?

  15. #11

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    53
    Messaggi
    7122
    Versione Office
    2011MAC 2016WIN
    Likes ricevuti
    2060
    Likes dati
    1298

    Re: Come popolare i campi di TextBox in base a una ListBox

    Bella domanda Draco, io per ora non ho risposta .. vediamo se qualcuno ci dice qualcosa al riguardo.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  16. I seguenti utenti hanno dato un "Like"


  17. #12
    L'avatar di Marius44
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Catania
    Età
    73
    Messaggi
    3208
    Versione Office
    Excel2010
    Likes ricevuti
    625
    Likes dati
    155

    Re: Come popolare i campi di TextBox in base a una ListBox

    Buongiorno a tutti
    La proposta di Draco è molto intrigante. Ho provato a mettere in un Foglio 20000 sostantivi ed ho cercato di applicare le, diciamo così, proposte, cioè il sistema utilizzato da Rubik, quello da me utilizzato ed ho aggiunto una ricerca con Find (come dice Draco) ed altra con VLOOKUP.

    Nel Foglio basta selezionare una cella del Range F2:F4 che, a fianco, viene indicato il tempo impiegato.

    Due cose da aggiungere:
    - alcune volte il tempo impiegato è pari a 0 (e mi pare impossibile visto che la cella ha 15 decimali)
    - non sono riuscito a "cancellare" quanto memorizzato col metodo Find (dalla Guida di VBA: Le impostazioni di LookIn, LookAt, SearchOrder e MatchByte vengono salvate ogni volta che si utilizza questo metodo. Se non si specificano valori per questi argomenti quando si richiama il metodo la volta successiva, verranno utilizzati i valori salvati).

    Allego il file e aspetto vostre notizie.
    Ciao,
    Mario
    File Allegati File Allegati

  18. #13

    L'avatar di scossa
    Clicca e Apri
    Data Registrazione
    Jul 2015
    Località
    Verona Provincia
    Età
    57
    Messaggi
    1011
    Versione Office
    .
    Likes ricevuti
    365
    Likes dati
    0

    Re: Come popolare i campi di TextBox in base a una ListBox

    Citazione Originariamente Scritto da Marius44 Visualizza Messaggio

    Due cose da aggiungere:
    - alcune volte il tempo impiegato è pari a 0 (e mi pare impossibile visto che la cella ha 15 decimali)
    - non sono riuscito a "cancellare" quanto memorizzato col metodo Find (dalla Guida di VBA: Le impostazioni di LookIn, LookAt, SearchOrder e MatchByte vengono salvate ogni volta che si utilizza questo metodo. Se non si specificano valori per questi argomenti quando si richiama il metodo la volta successiva, verranno utilizzati i valori salvati).
    Ciao.

    Per misurare operazioni così veloci devi usare ben altro "cronometro". In questi casi consiglio di usare MicroTimer (vedi codici sotto).


    Una considerazione sui risultati (su 40.000 righe - ho copiato le 20.000 sotto e messo dosolino11 in A39974): è ovvio che le routine più veloci siano quelle che utilizzano una funzione nativa di Excel evitando qualsiasi ciclo.
    Ovviamente il tempo del metodo Find è legato alla posizione della cella che contiene il valore cercato: se fosse in A1 impiegherebbe 1 millesimo di secondo, se fosse in fondo arriva a quasi un centesimo di secondo.

    F
    G
    H
    I
    1
    found
    0,000000031866853739
    tempo in mm:ss,sss (al millesimo di secondo)
    2
    Marius44
    39974
    0,000000031917741210
    ******0:00,003
    3
    Metodo Find dosolino11
    0,000000684396660370
    ******0:00,059
    4
    Cerca.vert dosolino11
    0,000000031866853739
    ******0:00,003
    5
    Rubitk72 found
    0,000011895173900935
    ******0:01,028



    MicroTimer:
    Codice: 
    Option Explicit
    
    '-------------- copy & paste in a standard module ---------------
    '
    'MicroTimer function
    'Found on the net
    '
    #If VBA7 Then
    
      Private Declare PtrSafe Function getFrequency _
                  Lib "kernel32" _
                  Alias "QueryPerformanceFrequency" ( _
                  cyFrequency As Currency) _
                  As Long
      
      
      Private Declare PtrSafe Function getTickCount _
                  Lib "kernel32" _
                  Alias "QueryPerformanceCounter" _
                  (cyTickCount As Currency) _
                  As Long
    #Else
      Private Declare Function getFrequency _
                  Lib "kernel32" _
                  Alias "QueryPerformanceFrequency" ( _
                  cyFrequency As Currency) _
                  As Long
      
      
      Private Declare Function getTickCount _
                  Lib "kernel32" _
                  Alias "QueryPerformanceCounter" _
                  (cyTickCount As Currency) _
                  As Long
    #End If
    
    
    
    Public Function MicroTimer() As Double
        Dim cyTicks1 As Currency
        Static cyFrequency As Currency
        MicroTimer = 0
        If cyFrequency = 0 Then getFrequency cyFrequency
        getTickCount cyTicks1
        If cyFrequency Then MicroTimer = cyTicks1 / cyFrequency
    End Function
    
    '------------------- end copy ----------------
    le routine, con le variabili dichiarate e adattate a MicroTimer:
    Codice: 
    Sub Rubik()
        Dim sTime As Double, eTime As Double
        Dim uriga As Long, rg As Variant
        Dim CL As Range
        uriga = Cells(Rows.Count, 1).End(xlUp).Row
        sTime = MicroTimer
            For Each CL In Sheets("Foglio1").Range("A1:A" & uriga)
                If InStr(1, CL, Cells(1, 3)) > 0 Then
                    rg = "found"
                    Exit For
                End If
            Next
        eTime = MicroTimer
        ActiveCell.Offset(0, 1).Value = rg
        ActiveCell.Offset(0, 2).Value = (eTime - sTime) / 86400
        ActiveCell.Offset(0, 3).Value = (eTime - sTime) / 86400
        ActiveCell.Offset(0, 3).NumberFormat = "[m]:ss.000"
    End Sub
    Sub Marius()
        Dim sTime As Double, eTime As Double
        Dim uriga As Long, rg As Variant
        uriga = Cells(Rows.Count, 1).End(xlUp).Row
        sTime = MicroTimer
        rg = Application.WorksheetFunction.Match(Cells(1, 3), Range("A1:A" & uriga), 0)
        eTime = MicroTimer
        ActiveCell.Offset(0, 1).Value = rg
        ActiveCell.Offset(0, 2).Value = (eTime - sTime) / 86400
        ActiveCell.Offset(0, 3).Value = (eTime - sTime) / 86400
        ActiveCell.Offset(0, 3).NumberFormat = "[m]:ss.000"
        
    End Sub
    Sub VLook()
      Dim sTime As Double, eTime As Double
        Dim uriga As Long, rg As Variant
        uriga = Cells(Rows.Count, 1).End(xlUp).Row
        sTime = MicroTimer
        rg = Application.WorksheetFunction.VLookup(Cells(1, 3), Range("A1:A" & uriga), 1, 0)
        eTime = MicroTimer
        ActiveCell.Offset(0, 1).Value = rg
        ActiveCell.Offset(0, 2).Value = (eTime - sTime) / 86400
        ActiveCell.Offset(0, 3).Value = (eTime - sTime) / 86400
        ActiveCell.Offset(0, 3).NumberFormat = "[m]:ss.000"
    End Sub
    Sub Draco()
      Dim sTime As Double, eTime As Double
        Dim uriga As Long, rg As Variant
        uriga = Cells(Rows.Count, 1).End(xlUp).Row
        sTime = MicroTimer
        rg = Range("A1:A" & uriga).Find(Cells(1, 3), after:=Cells(uriga, 1), LookIn:=xlValues, lookat:=xlWhole)
        eTime = MicroTimer
        ActiveCell.Offset(0, 1).Value = rg
        ActiveCell.Offset(0, 2).Value = (eTime - sTime) / 86400
        ActiveCell.Offset(0, 3).Value = (eTime - sTime) / 86400
        ActiveCell.Offset(0, 3).NumberFormat = "[m]:ss.000"
        
    End Sub
    Bye!
    scossa
    scossa's web site
    ___
    Se tu hai una mela, e io ho una mela, e ce le scambiamo, allora tu ed io abbiamo sempre una mela per uno. Ma se tu hai un'idea, ed io ho un'idea, e ce le scambiamo, allora abbiamo entrambi due idee. (George Bernard Shaw)

  19. I seguenti utenti hanno dato un "Like"


  20. #14
    L'avatar di Marius44
    Clicca e Apri
    Data Registrazione
    Sep 2015
    Località
    Catania
    Età
    73
    Messaggi
    3208
    Versione Office
    Excel2010
    Likes ricevuti
    625
    Likes dati
    155

    Re: Come popolare i campi di TextBox in base a una ListBox

    Salve a tutti

    @scossa
    grazie per le "chicche".
    Ho portato a 100.000 il numero di righe ed ho fatto cercare l'ultimo sostantivo.

    CERCA.VERT batte tutti con tempo pari a 0.00,010
    poi MATCH che fa segnare poco di più 0.00,011
    poi c'è FIND che fa segnare 0.00,127
    e infine InSTR che fa segnare 0.02,476

    Ovviamente tempi segnati col mio PC.
    Ottima palestra. Immagino che Draco possa ritenersi soddisfatto.

    Ciao a tutti,
    Mario

  21. I seguenti utenti hanno dato un "Like"

    ges

Discussioni Simili

  1. [Risolto] Popolare la ListBox da Combobox
    Di Pacifico437 nel forum Domande su Excel VBA e MACRO
    Risposte: 9
    Ultimo Messaggio: 08/03/17, 08:49
  2. Come popolare una ListBox
    Di aurelio125 nel forum Domande su Excel VBA e MACRO
    Risposte: 9
    Ultimo Messaggio: 11/11/16, 01:24
  3. Popolare ListBox dal ComboBox
    Di Pacifico437 nel forum Domande su Excel VBA e MACRO
    Risposte: 4
    Ultimo Messaggio: 11/09/16, 20:07
  4. Popolare la TextBox
    Di dautattmaui nel forum Domande su Excel VBA e MACRO
    Risposte: 3
    Ultimo Messaggio: 04/05/16, 20:42
  5. popolare una listbox con più colonneuest
    Di Baloon_50 nel forum Domande su Excel VBA e MACRO
    Risposte: 16
    Ultimo Messaggio: 21/11/15, 22:17

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •