Risultati da 1 a 19 di 19

Discussione: Invio mail con vba



  1. #1
    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Napoli
    Età
    63
    Messaggi
    2026
    Versione Office
    2007 - 2013
    Mi Piace ricevuti
    256
    Mi Piace dati
    39

    Invio mail con vba

    Ciao a tutti

    Premetto che con il 2007 funzionava tutto e con il 2013 ho problemi

    Nel file allegato ho due macro (la prima scritta da mee la seconda presa dal sito di Ron de Bruin)

    la prima è questa

    Codice: 
    Sub inviamail()
    Dim rng As Range
    Dim cel As Range
    Dim OutlookApp As Outlook.Application
    Dim MItem As Outlook.MailItem
    Dim Oggetto As String
    Dim IndirizzoMail As String
    Dim Testo As String
    Dim ur As Long
    ur = Cells(Rows.Count, 9).End(xlUp).Row
    Set rng = Range("I5:I" & ur)
    Set OutlookApp = New Outlook.Application
    For Each cel In rng
        If cel.Value = "SI" Then
            Oggetto = "Avviso scadenza"
            IndirizzoMail = cel.Offset(0, 1).Value
            Testo = "Egr. Sig. " & cel.Offset(0, -4) & Chr(10) & Chr(10) & _
            "La informiamo che il suo contratto è in scadenza." & Chr(10) & Chr(10) & "Firma"
            Set MItem = MItem.CreateItem(olMailItem)
            With MItem
            .To = IndirizzoMail
            .Subject = Oggetto
            .Body = Testo
            .Display
            '.Send
          End With
        End If
    Next
    End Sub
    Se la lancio mi va in debug su questa riga

    Codice: 
    Set MItem = MItem.CreateItem(olMailItem)
    dandomi l'errore: "Variabile oggetto o variabile del blocco With non impostata".

    La seconda macro è questa

    Codice: 
    Sub Mail_small_Text_Outlook()
        Dim OutApp As Object
        Dim OutMail As Object
        Dim strbody As String
        Set OutApp = CreateObject("Outlook.Application")
        Set OutMail = OutApp.CreateItem(0)
        strbody = "Hi there" & vbNewLine & vbNewLine & _
                  "This is line 1" & vbNewLine & _
                  "This is line 2" & vbNewLine & _
                  "This is line 3" & vbNewLine & _
                  "This is line 4"
        On Error Resume Next
        With OutMail
            .To = "ron@debruin.nl"
            .CC = ""
            .BCC = ""
            .Subject = "This is the Subject line"
            .Body = strbody
            .Display
        End With
        On Error GoTo 0
        Set OutMail = Nothing
        Set OutApp = Nothing
    End Sub
    va in debug su questa riga

    Codice: 
    Set OutMail = OutApp.CreateItem(0)
    dandomi l'errore: "Errore definito dall'applicazione o dall'oggetto".

    Ovviamente la Microsoft Outlook Object Library 15.0 è attivata.

    Chi riesce a darmi una mano?
    File Allegati File Allegati
    Alfredo

    "Non esistono cose facili o difficili; esistono cose che si sanno e cose che non si sanno"
    Cit. Berna11: "Se ti piace la risposta di qualcuno, oltre a ringraziarlo, puoi cliccare su "Mi Piace" in basso a sinistra del loro messaggio."

  2. #2

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    52
    Messaggi
    3700
    Versione Office
    2011/2016MAC
    Mi Piace ricevuti
    1104
    Mi Piace dati
    653

    Re: Invio mail con vba

    Ciao Alfredo,
    per ora non posso provare però per mandare mail uso questa:

    Codice: 
    Sub RoutineMail()
    Dim NewMail As Object
    EmaiDest = "ges6@libero.it"
     Set NewMail = CreateObject("Outlook.Application").CreateItem(oMailItem)
       With NewMail
          .To = EmaiDest
          .Subject = "prova"
          .Body = "prova"
          .Display
          .Send
       End With
     Set NewMail=Nothing
    End Sub
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  3. #3
    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Napoli
    Età
    63
    Messaggi
    2026
    Versione Office
    2007 - 2013
    Mi Piace ricevuti
    256
    Mi Piace dati
    39

    Re: Invio mail con vba

    Niente Ges mi dà sempre: "Errore definito dall'applicazione o dall'oggetto" su questa riga

    Codice: 
    Set NewMail = CreateObject("Outlook.Application").CreateItem(oMailItem)
    Ovviamente la libreria di Microsoft Outlook 15.0 è attivata.

    E dire che con il 2007 mai avuto problemi.
    Alfredo

    "Non esistono cose facili o difficili; esistono cose che si sanno e cose che non si sanno"
    Cit. Berna11: "Se ti piace la risposta di qualcuno, oltre a ringraziarlo, puoi cliccare su "Mi Piace" in basso a sinistra del loro messaggio."

  4. #4

    L'avatar di ges
    Clicca e Apri
    Data Registrazione
    Jun 2015
    Località
    Como
    Età
    52
    Messaggi
    3700
    Versione Office
    2011/2016MAC
    Mi Piace ricevuti
    1104
    Mi Piace dati
    653

    Re: Invio mail con vba

    A me l'errore come dici tu me lo da col Max che è incompatibile con gli Activex... sul Windows no.
    Quando si scartano tutte le ipotesi possibili, quella che resta, anche se può sembrare improbabile, non può che essere quella giusta!

  5. #5
    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Napoli
    Età
    63
    Messaggi
    2026
    Versione Office
    2007 - 2013
    Mi Piace ricevuti
    256
    Mi Piace dati
    39

    Re: Invio mail con vba

    Ma qui non c'è nessun ActiveX
    Alfredo

    "Non esistono cose facili o difficili; esistono cose che si sanno e cose che non si sanno"
    Cit. Berna11: "Se ti piace la risposta di qualcuno, oltre a ringraziarlo, puoi cliccare su "Mi Piace" in basso a sinistra del loro messaggio."

  6. #6
    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Napoli
    Età
    63
    Messaggi
    2026
    Versione Office
    2007 - 2013
    Mi Piace ricevuti
    256
    Mi Piace dati
    39

    Re: Invio mail con vba

    Anthony vedo che stai visualizzando questa discussione; spero che ti vengano delle idee.

    E comunque se qualcuno vuole provare il file che ho allegato e dirmi se funziona mi fa cosa gradita
    Alfredo

    "Non esistono cose facili o difficili; esistono cose che si sanno e cose che non si sanno"
    Cit. Berna11: "Se ti piace la risposta di qualcuno, oltre a ringraziarlo, puoi cliccare su "Mi Piace" in basso a sinistra del loro messaggio."

  7. #7
    L'avatar di Anthony
    Clicca e Apri
    Data Registrazione
    Sep 2016
    Località
    Ivrea (TO)
    Messaggi
    228
    Versione Office
    2003-2010-2016
    Mi Piace ricevuti
    166
    Mi Piace dati
    31

    Re: Invio mail con vba

    La prima di Alfredo richiede il riferimento alla libreria Microsoft Outlook, nel vba.
    "Ovviamente" si usera'
    Codice: 
           Set MItem = OutlookApp.CreateItem(olMailItem)
    (e non Set MItem = MItem.etc etc)

    La seconda non ha bisogno di quella impostazione.

    A me ambedue funzionano (dopo la correzione, la prima)

    Ricordo che senza il riferimento alla libreria Outlook non bisognerebbe utilizzare la costante olMailItem; aiuta che essendo considerata una variabile vuota il suo valore diventa "0", come richiede CreateItem per creare una nuova mail.

    Ciao
    Anthony

  8. #8
    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Napoli
    Età
    63
    Messaggi
    2026
    Versione Office
    2007 - 2013
    Mi Piace ricevuti
    256
    Mi Piace dati
    39

    Re: Invio mail con vba

    Niente ho provato a scrivere come mi hai indicato

    Codice: 
    Set MItem = OutlookApp.CreateItem(olMailItem)
    ma mi dà sempre errore definito dall'applicazione o dall'oggetto.

    E comunque a me non funzionano né la macro di Ges né quella di Ron De Bruin

    Ci sarà un motivo.

    La libreria di Outlook è attivata.
    Alfredo

    "Non esistono cose facili o difficili; esistono cose che si sanno e cose che non si sanno"
    Cit. Berna11: "Se ti piace la risposta di qualcuno, oltre a ringraziarlo, puoi cliccare su "Mi Piace" in basso a sinistra del loro messaggio."

  9. #9
    L'avatar di Powerwin
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Milano
    Messaggi
    439
    Versione Office
    2010
    Mi Piace ricevuti
    68
    Mi Piace dati
    27

    Re: Invio mail con vba

    Ciao Alfredo, un saluto ad Antonhy e Ges, faccio una prova pure io, ti ho modificato leggermente il codice del primo post

    Codice: 
    Sub inviamail()
    Dim rng As Range
    Dim cel As Range
    Dim OutlookApp As Object
    Dim MItem As Object
    Dim Oggetto As String
    Dim IndirizzoMail As String
    Dim Testo As String
    Dim ur As Long
    ur = Cells(Rows.Count, 9).End(xlUp).Row
    Set rng = Range("I5:I" & ur)
    Set OutlookApp = CreateObject("Outlook.Application")
    For Each cel In rng
        If cel.Value = "SI" Then
            Oggetto = "Avviso scadenza"
            IndirizzoMail = cel.Offset(0, 1).Value
            Testo = "Egr. Sig. " & cel.Offset(0, -4) & Chr(10) & Chr(10) & _
            "La informiamo che il suo contratto è in scadenza." & Chr(10) & Chr(10) & "Firma"
            Set MItem = OutlookApp.CreateItem(olMailItem)
            With MItem
            .To = IndirizzoMail
            .Subject = Oggetto
            .Body = Testo
            .Display
            '.Send
          End With
        End If
    Next
    End Sub
    provalo togliendo i riferimenti ad Outlook
    Flavio
    Non scrivetemi in MP per risolvere i problemi ed un grazie è sempre ben accetto quando ricevete degli aiuti

  10. #10
    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Napoli
    Età
    63
    Messaggi
    2026
    Versione Office
    2007 - 2013
    Mi Piace ricevuti
    256
    Mi Piace dati
    39

    Re: Invio mail con vba

    Mi sbaglierò ma credo d'aver fatto tutte le prove possibili. Appena torno a casa provo anche la tua (ma non ci credo molto)
    Alfredo

    "Non esistono cose facili o difficili; esistono cose che si sanno e cose che non si sanno"
    Cit. Berna11: "Se ti piace la risposta di qualcuno, oltre a ringraziarlo, puoi cliccare su "Mi Piace" in basso a sinistra del loro messaggio."

  11. #11
    L'avatar di Anthony
    Clicca e Apri
    Data Registrazione
    Sep 2016
    Località
    Ivrea (TO)
    Messaggi
    228
    Versione Office
    2003-2010-2016
    Mi Piace ricevuti
    166
    Mi Piace dati
    31

    Re: Invio mail con vba

    Citazione Originariamente Scritto da alfrimpa Visualizza Messaggio
    Mi sbaglierò ma credo d'aver fatto tutte le prove possibili. Appena torno a casa provo anche la tua (ma non ci credo molto)
    Che sistema operativo usi? e fa differenza se la macro viene eseguita avendo Outlook aperto o chiuso? Prova anche a fare il "Ripristino di Office" (scegli, se ti viene proposta, l'opzione Ripristino online: dura di piu' ma e' piu' completa).
    L'errore e' il criptico 1004, vero?
    Anthony

  12. #12
    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Napoli
    Età
    63
    Messaggi
    2026
    Versione Office
    2007 - 2013
    Mi Piace ricevuti
    256
    Mi Piace dati
    39

    Re: Invio mail con vba

    Allora Anthony ho Win7 ed Outlook è chiuso (ma ho sempre fatto così).

    Si l'errore è il 1004 ma mi dà anche Variabile oggetto o variabile del blocco With non impostata.

    Mi chiedo perché con il 2007 non ho mai avuto problemi
    Alfredo

    "Non esistono cose facili o difficili; esistono cose che si sanno e cose che non si sanno"
    Cit. Berna11: "Se ti piace la risposta di qualcuno, oltre a ringraziarlo, puoi cliccare su "Mi Piace" in basso a sinistra del loro messaggio."

  13. #13
    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Napoli
    Età
    63
    Messaggi
    2026
    Versione Office
    2007 - 2013
    Mi Piace ricevuti
    256
    Mi Piace dati
    39

    Re: Invio mail con vba

    Flavio non funziona neanche la tua

    Codice: 
    Set MItem = OutlookApp.CreateItem(olMailItem)
    Errore (1004) definito dall'applicazione o dall'oggetto.
    Alfredo

    "Non esistono cose facili o difficili; esistono cose che si sanno e cose che non si sanno"
    Cit. Berna11: "Se ti piace la risposta di qualcuno, oltre a ringraziarlo, puoi cliccare su "Mi Piace" in basso a sinistra del loro messaggio."

  14. #14
    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Napoli
    Età
    63
    Messaggi
    2026
    Versione Office
    2007 - 2013
    Mi Piace ricevuti
    256
    Mi Piace dati
    39

    Re: Invio mail con vba

    Flavio ma col 2010 funziona?
    Alfredo

    "Non esistono cose facili o difficili; esistono cose che si sanno e cose che non si sanno"
    Cit. Berna11: "Se ti piace la risposta di qualcuno, oltre a ringraziarlo, puoi cliccare su "Mi Piace" in basso a sinistra del loro messaggio."

  15. #15
    L'avatar di Anthony
    Clicca e Apri
    Data Registrazione
    Sep 2016
    Località
    Ivrea (TO)
    Messaggi
    228
    Versione Office
    2003-2010-2016
    Mi Piace ricevuti
    166
    Mi Piace dati
    31

    Re: Invio mail con vba

    Citazione Originariamente Scritto da alfrimpa Visualizza Messaggio
    Flavio ma col 2010 funziona?
    Io ho provato su OL2016

    Hai detto che hai due tipi di errori: quando l'uno e quando l'altro? Comunque per favore fai anche la prova con Outlook attivato (ovviamente per raccogliere informazion, non per suggerire "la" soluzione)

    Ciao
    Anthony

  16. #16
    L'avatar di Powerwin
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Milano
    Messaggi
    439
    Versione Office
    2010
    Mi Piace ricevuti
    68
    Mi Piace dati
    27

    Re: Invio mail con vba

    Citazione Originariamente Scritto da alfrimpa Visualizza Messaggio
    Flavio ma col 2010 funziona?
    2010 e 2007 sono praticamente identici, non l'ho provato visto che il problema lo hai su 2013 che io non ho
    Flavio
    Non scrivetemi in MP per risolvere i problemi ed un grazie è sempre ben accetto quando ricevete degli aiuti

  17. #17
    L'avatar di alfrimpa
    Clicca e Apri
    Data Registrazione
    Dec 2015
    Località
    Napoli
    Età
    63
    Messaggi
    2026
    Versione Office
    2007 - 2013
    Mi Piace ricevuti
    256
    Mi Piace dati
    39

    Re: Invio mail con vba

    Ciao a tutti

    Torno in argomento perché credo di aver capito (forse) il motivo del mancato funzionamento della macro per invio mail.

    Essendo passato da poco ad Office 2013 ed usando per la posta elettronica LiberoMail Outlook non è stato configurato (impostazione account etc) per cui penso sia questa la ragione dell'andata in debug del codice VBA.
    Alfredo

    "Non esistono cose facili o difficili; esistono cose che si sanno e cose che non si sanno"
    Cit. Berna11: "Se ti piace la risposta di qualcuno, oltre a ringraziarlo, puoi cliccare su "Mi Piace" in basso a sinistra del loro messaggio."

  18. #18
    L'avatar di Powerwin
    Clicca e Apri
    Data Registrazione
    Mar 2016
    Località
    Milano
    Messaggi
    439
    Versione Office
    2010
    Mi Piace ricevuti
    68
    Mi Piace dati
    27

    Re: Invio mail con vba

    Citazione Originariamente Scritto da alfrimpa Visualizza Messaggio
    Ciao a tutti

    Torno in argomento perché credo di aver capito (forse) il motivo del mancato funzionamento della macro per invio mail.

    Essendo passato da poco ad Office 2013 ed usando per la posta elettronica LiberoMail Outlook non è stato configurato (impostazione account etc) per cui penso sia questa la ragione dell'andata in debug del codice VBA.
    Flavio
    Non scrivetemi in MP per risolvere i problemi ed un grazie è sempre ben accetto quando ricevete degli aiuti

  19. #19
    L'avatar di iliomil
    Clicca e Apri
    Data Registrazione
    May 2016
    Località
    Siracusa
    Età
    52
    Messaggi
    32
    Versione Office
    2010 - 2013
    Mi Piace ricevuti
    9
    Mi Piace dati
    28

    Re: Invio mail con vba

    Citazione Originariamente Scritto da alfrimpa Visualizza Messaggio
    ...Essendo passato da poco ad Office 2013 ed usando per la posta elettronica LiberoMail Outlook non è stato configurato (impostazione account etc) per cui penso sia questa la ragione dell'andata in debug del codice VBA.
    Ciao Alfredo.
    Ho provato il tuo allegato e funziona perfettamente in Outlook 2013, ed i riferimenti alle librerie Office-Outlook sono selezionate.
    Probabilmente hai ragione nel pensare che la problematica nasce dalla mancata configurazione iniziale di Outlook.
    Se può essere utile, proprio per avere un riscontro per l'utente, la procedura sottostante aiuta in questa direzione, attraverso dei controlli in background.
    Premetto che il codice "nasce" da TheSpreadsheetGuru.com, con integrazioni personali e più complesse che, ripeto, in un contesto generale può essere di utilità per altri utenti (precompilazione Oggetto, Testo del messaggio).
    Ciao,
    Ilio
    Codice: 
    Sub EmailFoglioSelezionato()
    'PURPOSE: Create email message with only Selected Worksheets attached
    'SOURCE: www.TheSpreadsheetGuru.com
    
    
    Dim SourceWB As Workbook
    Dim DestinWB As Workbook
    Dim OutlookApp As Object
    Dim OutlookMessage As Object
    Dim TempFileName As Variant
    Dim ExternalLinks As Variant
    Dim TempFilePath As String
    Dim FileExtStr As String
    Dim DefaultName As String
    Dim UserAnswer As Long
    Dim x As Long
    Dim Mittente As String
    
    
    
    
    Mittente = Sheets("NOME_FOGLIO_DA_INVIARE").Range("D1").Value 'Determina il nome del foglio da inviare ed utilizza la cella di riferimento quale denominazione
    ActiveSheet.Unprotect
    
    
    
    
    'Ottimizzazione del codice
      Application.ScreenUpdating = False
      Application.EnableEvents = False
      Application.DisplayAlerts = False
    
    
    
    
    'Copia il foglio selezionato (in uso) in una nuova cartella
      Set SourceWB = ActiveWorkbook
      SourceWB.Windows(1).SelectedSheets.Copy
      Set DestinWB = ActiveWorkbook
    
    
    
    
    'Controlla la presenza di eventuali macro all'interno del foglio
      If Val(Application.Version) >= 12 Then
        If SourceWB.FileFormat = 51 And SourceWB.HasVBProject = True Then
          UserAnswer = MsgBox("C'è del codice VBA in questo file. " & _
            "Se procedi il codice non sarà incluso nell'allegato. " & _
            "Vuoi procedere comunque?", vbYesNo, "Trovato Codice VBA!")
    
    
    
    
        'Gestisce le scelte dell'utente
          If UserAnswer = vbNo Then
            DestinWB.Close SaveChanges:=False
            GoTo ExitSub
          End If
    
    
    
    
        End If
      End If
    
    
    
    
    'Determina il percorso temporaneo per il file
      TempFilePath = ThisWorkbook.Path & "\"
    
    
    
    
    'Determina il nome di Default del File attraverso una scelta da imputbox
      If SourceWB.Saved Then
        DefaultName = Application.GetSaveAsFilename(InitialFileName:=Mittente + "_NOME_FILE" & Format(Now(), "dd_MMM_yyyy"))
      Else
        DefaultName = SourceWB.Name
      End If
    
    
    
    
    ' Chiede all'utente se vuole lasciare il nome di default o rinominarlo,
    ' quale tipo di file utilizzare, il nome del file che sarà utilizzato,
    ' la data di creazione del file
    
    
    
    
      TempFileName = Application.InputBox("Vuoi rinominare il nome di default del file allegato? (Nessun carattere speciale!)", _
        "Nome di default dell'allegato", Type:=2, Default:=Mittente + "_NOME_FILE" & Format(Now(), "dd_MMM_yyyy"))
    
    
    
    
        If TempFileName = False Then GoTo ExitSub 'Handle if user cancels
    
    
    
    
    'Determina l'estensione del File, in questo caso xlsx
      If SourceWB.Saved = True Then
        FileExtStr = "." & LCase(Right(SourceWB.Name, Len(SourceWB.Name) - InStrRev(SourceWB.Name, ".", , 1)))
      Else
        FileExtStr = ".xlsx"
      End If
    
    
    
    
    'Blocca i link esterni
      ExternalLinks = DestinWB.LinkSources(Type:=xlLinkTypeExcelLinks)
    
    
    
    
        'Loop sui link esterni attivi nella cartella e li blocca
          On Error Resume Next
            For x = 1 To UBound(ExternalLinks)
              DestinWB.BreakLink Name:=ExternalLinks(x), Type:=xlLinkTypeExcelLinks
            Next x
          On Error GoTo 0
    
    
    
    
    'Salva la cartella temporanea
      DestinWB.SaveCopyAs TempFilePath & TempFileName & FileExtStr
    
    
    
    
    'Crea un Instanza per Outlook
      On Error Resume Next
        Set OutlookApp = GetObject(class:="Outlook.Application") 'Gestisce se Outlook è già aperto
      Err.Clear
        If OutlookApp Is Nothing Then Set OutlookApp = CreateObject(class:="Outlook.Application") 'Se no, apre Outlook
    
    
    
    
        If Err.Number = 429 Then
          MsgBox "Outlook non trovato, annullo l'operazione.", 16, "Outlook non trovato"
          GoTo ExitSub
        End If
      On Error GoTo 0
    
    
    
    
    'Crea una nuova email
      Set OutlookMessage = OutlookApp.CreateItem(0)
    
    
    
    
    'Crea un email Outlook con relativa allegato
      On Error Resume Next
        With OutlookMessage
         .To = ""
         .CC = ""
         .BCC = ""
         'precompila l'oggetto della mail con il nome del file che si sta inviando in allegato
         .Subject = TempFileName
         'precompila una parte del corpo del messaggio (body)
         .Body = "In allegato, si invia il file in formato Excel della situazione giornaliera " & "relativa al " + Mittente & "." & vbNewLine & vbNewLine & "Saluti." & vbNewLine & vbNewLine & "P.S.: è gradito un cortese riscontro dell'invio al " + Mittente & ". Grazie"
         .Attachments.Add TempFilePath & TempFileName & FileExtStr
         .Display
        End With
      On Error GoTo 0
    
    
    
    
    Application.ScreenUpdating = False
    ActiveSheet.Protect
    
    
    
    
    'Chiude ed elimina il file temporaneo
      DestinWB.Close SaveChanges:=False
      Kill TempFilePath & TempFileName & FileExtStr
    
    
    
    
    'Libera la memoria
      Set OutlookMessage = Nothing
      Set OutlookApp = Nothing
    
    
    
    
    'Imposta alcune funzionalità su vero o falso
    ActiveSheet.Protect _
                Password:="", _
                DrawingObjects:=False, _
                Contents:=True, _
                Scenarios:=True, _
                UserInterfaceOnly:=True, _
                AllowFormattingCells:=True, _
                AllowFormattingColumns:=True, _
                AllowFormattingRows:=True, _
                AllowInsertingColumns:=True, _
                AllowInsertingRows:=True, _
                AllowInsertingHyperlinks:=True, _
                AllowDeletingColumns:=True, _
                AllowDeletingRows:=True, _
                AllowSorting:=False, _
                AllowFiltering:=False, _
                AllowUsingPivotTables:=False
    
    
    
    
    
    
    
    
    'Ottimizzazione del codice
    ExitSub:
      Application.ScreenUpdating = True
      Application.EnableEvents = True
      Application.DisplayAlerts = True
    
    
    
    
    End Sub

  20. I seguenti 2 utenti hanno dato un MI Piace a iliomil per questo post:


Discussioni Simili

  1. Risposte: 9
    Ultimo Messaggio: 20/11/16, 15:54
  2. [Risolto] Invio mail con vba attraverso un dominio esterno
    Di alfrimpa nel forum Domande su Excel VBA e MACRO
    Risposte: 10
    Ultimo Messaggio: 18/10/16, 17:22
  3. Invio unico mail da DB
    Di tk71 nel forum Domande su Excel in generale
    Risposte: 0
    Ultimo Messaggio: 02/09/16, 11:04
  4. Macro invio Unica mail formato PDF di "n" fogli
    Di freepredator nel forum Domande su Excel VBA e MACRO
    Risposte: 6
    Ultimo Messaggio: 19/02/16, 20:00
  5. invio e mail
    Di cesare nel forum Domande su Excel VBA e MACRO
    Risposte: 5
    Ultimo Messaggio: 25/10/15, 07:38

Permessi di Scrittura

  • Tu non puoi inviare nuove discussioni
  • Tu non puoi inviare risposte
  • Tu non puoi inviare allegati
  • Tu non puoi modificare i tuoi messaggi
  •