Risolto Copiare riga se fatture pagate

Morronce

Utente junior
18 Settembre 2020
24
1
2007
0
Hai ragione, allora guardando sempre l'ultimo foglio allegato ora incollando in foglio1 l'ultima formula mandata mi copia solo le date superiori a 2021, ma a me servirebbe copiare non solo la colonna I ma bensi da colonna A fino a colonna I, se vedi nel foglio allegato oltre alle date si vede anche cliente, tot doc, importo ecc. a me serve anche copiare quei valori non sono la colonna I(date) ma anche quelle prima, in poche parole avere la formula da inserire in A3 e poi trascinarla in orizzontale e verticale.
 

Terio

Utente abituale
6 Gennaio 2021
328
30
50
Arce
2016, 2019
28
Allora è facile, la formula è la stessa, ma INDICE deve puntare a ciò che devi recuperare, per cui:
=SE.ERRORE(--ANNULLA.SPAZI(INDICE('Elenco Fatture'!$I$1:$I$2000;PICCOLO(SE(VAL.NUMERO(--ANNULLA.SPAZI('Elenco Fatture'!$I$3:$I$5000));SE(--ANNULLA.SPAZI('Elenco Fatture'!$I$3:$I$5000)>=$C$1;RIF.RIGA('Elenco Fatture'!$I$3:$I$5000)));RIGHE(I$3:I3))));"")
la parte evidenziata devi farla puntare alla colonna da cui vuoi recuperare i dati, se togli il blocco sulle colonne ( come esempio riferendola alla prima colonna diventerebbe 'Elenco Fatture'!A$1:A$2000) ti consente di trascinarla.

Spero di aver ben interpretato l'esigenza ;)
 

Terio

Utente abituale
6 Gennaio 2021
328
30
50
Arce
2016, 2019
28
ma mi da cella vuota
intanto modifica la formula:
=SE.ERRORE(SE(INDICE('Elenco Fatture'!A$1:A$2000;PICCOLO(SE(VAL.NUMERO(--ANNULLA.SPAZI('Elenco Fatture'!$I$3:$I$5000));SE((--ANNULLA.SPAZI('Elenco Fatture'!$I$3:$I$5000)>=$C$1)*('Elenco Fatture'!$A$3:$A$5000="✓");RIF.RIGA('Elenco Fatture'!$I$3:$I$5000)));RIGHE(I$3:I3)))=0;"";INDICE('Elenco Fatture'!A$1:A$2000;PICCOLO(SE(VAL.NUMERO(--ANNULLA.SPAZI('Elenco Fatture'!$I$3:$I$5000));SE((--ANNULLA.SPAZI('Elenco Fatture'!$I$3:$I$5000)>=$C$1)*('Elenco Fatture'!$A$3:$A$5000="✓");RIF.RIGA('Elenco Fatture'!$I$3:$I$5000)));RIGHE(I$3:I3))));"")
che va bene fino alla colonna H, quella delle date lasciala com'è.
Però se nel foglio Elenco Fatture non c'è scritto nulla, non puoi pretendere che ci sia del testo, infatti ho dovuto intercettare l'assenza di testo con un altro SE nidificato.
 

pkrome59

Utente assiduo
Expert
26 Settembre 2015
2.604
145
61
Reggio Calabria
Office 2019
178
Ciao, utilizzando i dati di colonna "I" del foglio "Elenco Fatture" per come ti arrivano (senza dover apportare modifiche), propongo le seguenti:

Foglio "Report":

In A3:
=SE.ERRORE(SE(O(COLONNE($A3:A3)=3;$I3="");"";INDICE('Elenco Fatture'!A$2:A$6000;PICCOLO(SE(VAL.NUMERO(SE(VAL.NUMERO('Elenco Fatture'!$I$2:$I$6000);'Elenco Fatture'!$I$2:$I$6000;SE.ERRORE(ANNULLA.SPAZI('Elenco Fatture'!$I$2:$I$6000)*1;'Elenco Fatture'!$I$2:$I$6000)))*(SE(VAL.NUMERO('Elenco Fatture'!$I$2:$I$6000);'Elenco Fatture'!$I$2:$I$6000;SE.ERRORE(ANNULLA.SPAZI('Elenco Fatture'!$I$2:$I$6000)*1;'Elenco Fatture'!$I$2:$I$6000))>=DATA(DESTRA($A$1;4);1;1))*('Elenco Fatture'!$A$2:$A$6000="✓");RIF.RIGA('Elenco Fatture'!$I$2:$I$6000)-1);CONTA.SE($I$3:$I3;$I3))));"")
formula matrice da attivare con i tasti ctrl+maiuscolo+invio, da trascinare verso destra fino alla cella H3 e poi da trascinare giù;

In I3:
=SE.ERRORE(INDICE(SE(VAL.NUMERO('Elenco Fatture'!$I$2:$I$6000);'Elenco Fatture'!$I$2:$I$6000;SE.ERRORE(ANNULLA.SPAZI('Elenco Fatture'!$I$2:$I$6000)*1;'Elenco Fatture'!$I$2:$I$6000));PICCOLO(SE(VAL.NUMERO(SE(VAL.NUMERO('Elenco Fatture'!$I$2:$I$6000);'Elenco Fatture'!$I$2:$I$6000;SE.ERRORE(ANNULLA.SPAZI('Elenco Fatture'!$I$2:$I$6000)*1;'Elenco Fatture'!$I$2:$I$6000)))*(SE(VAL.NUMERO('Elenco Fatture'!$I$2:$I$6000);'Elenco Fatture'!$I$2:$I$6000;SE.ERRORE(ANNULLA.SPAZI('Elenco Fatture'!$I$2:$I$6000)*1;'Elenco Fatture'!$I$2:$I$6000))>=DATA(DESTRA($A$1;4);1;1))*('Elenco Fatture'!$A$2:$A$6000="✓");RIF.RIGA('Elenco Fatture'!$I$2:$I$6000)-1);RIGHE(I$3:I3)));"")
formula matrice da attivare con i tasti ctrl+maiuscolo+invio, da trascinare giù.
Allego il file di prova, ciao.
 

Allegati

Ultima modifica:

Morronce

Utente junior
18 Settembre 2020
24
1
2007
0
ma te le scrivono sempre così le date?
vengono dall'Ufficio Complicazioni Affari Semplici Muoio_muoio
In che senso me "le scrivono cosi"? Se avete consigli vi ascolto PollicioneInSu .
Comunque grazie per l'aiuto fenomenale Terio @Terio funziona esattamente come volevo, non capisco come faccia a funzionare e a riportare la stessa riga anche se sono due formule diverse ma funziona.
Per quanto riguarda la soluzione di pkrome la proverò ma non ora ti ringrazio lo stesso.
Aspetto tua risposta per le date e poi posso mettere risoltoSaluto_saluto
 

Terio

Utente abituale
6 Gennaio 2021
328
30
50
Arce
2016, 2019
28
Era una battuta, Gianfranco55 @Gianfranco55 (saluto) aveva chiesto se te le passavano sempre così, cioè scritte con spazi, non formattate e che hanno reso complicate le formule per poterle adattare all'errore umano.
Le formule sono diverse perché fino alla colonna H non deve farsi i calcoli sulle date, ma recuperare il testo che, se non lo trova, con INDICE ti restituirebbe un antiestetico 0.

Spero di aver chiarito e soprattutto averti dato modo di approfondire l'uso di Excel,
ciao.
 

Morronce

Utente junior
18 Settembre 2020
24
1
2007
0
Ah ok ahaha eh purtroppo spesso si.
Vi ringrazio molto per la vs. soluzione.
Non riesco a visualizzare la coppa per mettere risolto, riesce a chiuderla qualche mod?
 

Berna11

Excel Expert
Moderatore
20 Febbraio 2016
10.006
1.445
Latina
Excel 2010
1.144
Un saluto
se vuoi trascinare la formula per avere anche le altre colonne
metti in A3 foglio1:

=SE.ERRORE(""&INDICE('Elenco Fatture'!A$1:A$5000;PICCOLO(SE(VAL.NUMERO(--ANNULLA.SPAZI('Elenco Fatture'!$I$3:$I$5000))*('Elenco Fatture'!$A$3:$A$5000="✓");SE(--ANNULLA.SPAZI('Elenco Fatture'!$I$3:$I$5000)>=$C$1;RIF.RIGA('Elenco Fatture'!$I$3:$I$5000)));RIGHE(A$3:A3)));"")

conferma ctrl+maiusc+invio trascina a destra fino a colonna H e poi in basso

mentre in I3 metti:

=SE.ERRORE(--ANNULLA.SPAZI(INDICE('Elenco Fatture'!I$1:I$5000;PICCOLO(SE(VAL.NUMERO(--ANNULLA.SPAZI('Elenco Fatture'!$I$3:$I$5000))*('Elenco Fatture'!$A$3:$A$5000="✓");SE(--ANNULLA.SPAZI('Elenco Fatture'!$I$3:$I$5000)>=$C$1;RIF.RIGA('Elenco Fatture'!$I$3:$I$5000)));RIGHE(I$3:I3))));"")

sempre ctrl+maiusc+invio e trascina in basso.
Sperando di aver capito e di aver sistemato la richiesta...
 
  • Like
Reactions: Terio

Terio

Utente abituale
6 Gennaio 2021
328
30
50
Arce
2016, 2019
28
Berna11 @Berna11 sei un grande, questo stratagemma ""&INDICE per intercettare i vuoti mi mancava...
 
  • Like
Reactions: Berna11

Morronce

Utente junior
18 Settembre 2020
24
1
2007
0
Scusa se ti disturbo Powerwin @Powerwin ti chiedo gentilmente se puoi applicare la coppa al post #25 poichè io non ne ho la possiblità, grazie.
 

Powerwin

VBA Expert
Supermoderatore
17 Marzo 2016
8.843
245
vicino a Milano
2019 e 365
301
Abbiamo messo il Risolto alla discussione senza peraltro poter assegnare la coppa in quanto questo post è stato creato in modo anomalo da una richiesta accodata in un altro post
 

Sostieni ForumExcel

Aiutaci a sostenere le spese e a mantenere online la community attraverso una libera donazione!