Risolto Inversione Ricerca con Convalida dati

[ClementeSan Felice]

Buon Pomeriggio a tutti
Sono rimasto meravigliato da cosa sono riuscito a fare con il Vostro aiuto
però adesso vorrei porre una domanda:
Ho fatto sì che con "Convalida Dati" riesco ad ottenere un codice da un elenco nella casella corrispondente
mi domando è possibile ottenere sempre sullo stesso foglio la Descrizione del prodotto partendo dal codice?
in effetti dovrebbe essere possibile tutte e due le opzioni
allego comunque il file che ho creato
grazie a tutti

 

[alfrimpa]

Scusa ma cosa ti serve la convalida per la descrizione quando con un CERCA.VERT() partendo dal codice puoi estrarla in automatico dalla tabella del foglio2 come puoi vedere nell'immagine?

 

[Terio]

Ho fatto si che con "Cnvalida Dati" riesco ad ottenere un codice da un elenco nella casella corrispondente
mi domando è possibile ottenere sempre sullo stesso foglio la Descrizione del prodotto partendo dal codice?

Certo, metti la convalida nella prima colonna e poi con CERCA.VERT ottieni la descrizione.
Ti chiedo due cose:
1. perché usi tutte quelle inutili celle unite
2. quale versione hai realmente? nel profilo dichiari una 2017 che non mi risulta esista.

Ciao.
edit

cosa ti serve la convalida per la descrizione quando con un CERCA.VERT() partendo dal codice puoi estrarla in automatico dalla tabella del foglio2

Perché ora con la convalida recupera la descrizione ed il codice lo ottiene con INDICE+CONFRONTA

 

[ClementeSan Felice]

avete ragione ho Office 2016
le celle unite le ho usate per la stampa
più ottimale

ora provo
ma io in A14 ho già una formula

[riuniti i messaggi]​

 

[alfrimpa]

ora provo

Se ti riferisci alla mia risposta sul CERCA.VERT (che ho cancellato) non puoi perchè scgliendo la descrizione in convalida hai il codice.

Ma perchè alleghi una cartella di lavoro protetta quindi non modificabile?

Qual è la password?

 

[Terio]

Io ho usato il CERCA.VERT() sul codice in colonna A cosa c'è che non va?

Non so come hai fatto, ma se la colonna A (che in realtà sono A B e C) contiene una formula che punta alla F, come è possibile che ti funzioni senza avere un riferimento circolare?

edit
Gentilmente evitate i messaggi a raffica, sono disponibili 30 minuti per integrarli e/o correggerli, per cui li ho riuniti

 

[alfrimpa]

come è possibile che ti funzioni senza avere un riferimento circolare?

Mah io il CERCA.VERT() l'ho messo in AD14 per provare probabilmente è per quello che non dà riferimento circolare

 

[ClementeSan Felice]

appunto penso non sia possibile fare le due cose
cioè
dalla descrizione ricavare il codice
e
dal codice ricavare la descrizione
dei dati in foglio 2!
devo chiudere buoona serata a tutti e grazie ancora a domani

 

[alfrimpa]

appunto penso non sia possibile fare le due cose

Per me la cosa si può fare ma occorre usare il VBA.

Sei interessato?

 

[Terio]

l'ho messo in AD14 per provare probabilmente è per quello che non dà riferimento circolare

Ebbene si, è proprio per quello.

penso non sia possibile fare le due cose

Non con le formule, ti serve del codice VBA, ma presumo tu non abbia molta dimestichezza con il codice.

Ciao.

 

[alfrimpa]

ma presumo tu non abbia molta dimestichezza con il codice.

Il problema non è tanto quello noi siamo sempre disponibili a spiegare quello che c'è da spiegare.

Il problema sono le celle unite.

 

[Terio]

Il problema sono le celle unite

Nemmeno troppo:

Sub Worksheet_Change(ByVal Target As Range)
Dim lngRow As Long, strRange As String, lngCol As Long, varVL, rngFrom As Range, rngTo As Range, lngLast As Long, strResult As String

    If Not Intersect(Target, Range("A14:A28", "F14:F28")) Is Nothing Then
        Application.EnableEvents = False
        lngRow = Target.Cells(1, 1).Row
        lngCol = Target.Cells(1, 1).Column
        lngLast = Worksheets("Foglio2").Cells(Rows.Count, 1).End(xlUp).Row
        If lngCol = 1 Then
            strRange = "F" & lngRow & ":Z" & lngRow
            Set rngFrom = Worksheets("Foglio2").Range("A2:A" & lngLast)
            Set rngTo = Worksheets("Foglio2").Range("B2:B" & lngLast)
        Else
            strRange = "A" & lngRow & ":C" & lngRow
            Set rngFrom = Worksheets("Foglio2").Range("B2:B" & lngLast)
            Set rngTo = Worksheets("Foglio2").Range("A2:A" & lngLast)
        End If
        If Target.Cells(1, 1).Value = "" Then
            Range(strRange).ClearContents
        Else
            varVL = Application.Match(Target.Cells(1, 1).Value, rngFrom, 0)
            If IsError(varVL) Then
                strResult = "non trovato"
            Else
                strResult = Application.Index(rngTo, varVL)
            End If
            Range(strRange).Value = strResult
        End If
        Application.EnableEvents = True
    End If
End Sub

Il codice è solo una traccia, da mettere nel modulo del foglio, come puoi leggere qui:

Inserire/scrivere una macro nel modulo del foglio di lavoro

Ciao a tutti. Atteso che accade spesso che, qualora nella risposta ad una discussione venga detto di "inserire la macro ne modulo del foglio interessato" l'utente che ha aperto la discussione chieda come fare. Cerco di illustrare il procedimento. Innanzitutto va detto che nei moduli di classe...

www.forumexcel.it

ed alla variazione di codice o descrizione, aggiorna l'altro, mentre se cancelli la cella li pulisce.

siamo sempre disponibili a spiegare quello che c'è da spiegare

Certo, basta chiedere e le spiegazioni arrivano sempre,
ciao.

 

[ClementeSan Felice]

Buongiorno a tutti
riprendendo il discorso di ieri
Il problema in parte l'abbiamo risolto
però quando vado ad inserire la quantità
vanno via i codici mi dice "non trovato"
E' anche vero che con il VBA non sono pratico e sto seguendo anche delle lezioni cercando su you tube

questo è il file
grazie

 

[Terio]

E' anche vero che con il VBA non sono pratico

Il file è senza macro, per cui lo rimuovo.
Cortesemente allega quello corretto, ma prima prova questa modifica:

Sub Worksheet_Change(ByVal Target As Range)
Dim lngRow As Long, strRange As String, lngCol As Long, varVL, rngFrom As Range, rngTo As Range, lngLast As Long, strResult As String

    If Not Intersect(Target, Range("A14:F28")) Is Nothing Then
        lngCol = Target.Cells(1, 1).Column
        If lngCol <> 4 Then
            Application.EnableEvents = False
            lngRow = Target.Cells(1, 1).Row
            lngLast = Worksheets("Foglio2").Cells(Rows.Count, 1).End(xlUp).Row
            If lngCol = 1 Then
                strRange = "F" & lngRow & ":Z" & lngRow
                Set rngFrom = Worksheets("Foglio2").Range("A2:A" & lngLast)
                Set rngTo = Worksheets("Foglio2").Range("B2:B" & lngLast)
            Else
                strRange = "A" & lngRow & ":C" & lngRow
                Set rngFrom = Worksheets("Foglio2").Range("B2:B" & lngLast)
                Set rngTo = Worksheets("Foglio2").Range("A2:A" & lngLast)
            End If
            If Target.Cells(1, 1).Value = "" Then
                Range(strRange).ClearContents
            Else
                varVL = Application.Match(Target.Cells(1, 1).Value, rngFrom, 0)
                If IsError(varVL) Then
                    strResult = "non trovato"
                Else
                    strResult = Application.Index(rngTo, varVL)
                End If
                Range(strRange).Value = strResult
            End If
            Application.EnableEvents = True
        End If
    End If
End Sub

Intanto sposto nella sezione corretta,
ciao.

 

[ClementeSan Felice]

tutto risolto funziona
grazie mille

 

[Terio]

grazie mille

Grazie a te dei riscontri, se hai bisogno di spiegazioni chiedi pure,
ciao.